機能モジュールを使用した論理データベースの呼び出し 

リリース 4.5A 以降、論理データベースを ABAP プログラムから独立して呼び出すことが可能になりました。従来、論理データベースを実行可能プログラムにリンクすることだけが可能でした。プログラムでは論理データベースおよびプログラムの処理ブロックは、ABAP 実行時環境により制御されました。

論理データベースを別のプログラムから呼び出すには、機能モジュール LDB_PROCESS を使用します。このため、論理データベースをデータ読み取りルーチンとして使用できます。同一プログラムから論理データベースを 2 個以上呼び出すことができます。また同一プログラムから、同一の論理データベースを 2 回以上呼び出すことができます。従来、同一の論理データベースを 2 回以上使用したり、異なる論理データベースを 2 個以上使用したりするのは、SUBMIT を使用して追加の実行可能プログラムを呼び出すことでのみ可能でした。これらのプログラムは対応する論理データベースにリンクする必要があり、ABAP メモリまたは類似した技術を使用してデータを呼び出してプログラムに渡す必要がありました。

機能モジュール LDB_PROCESS を使用して論理データベースを呼び出す場合、選択画面は表示されません。代わって、汎用モジュールのインタフェースパラメータを使用して選択に入力します。論理データベースは呼び出しプログラムの GET イベントを開始しませんが、データをコールバックルーチンの呼び出し元に戻します。このように LDB_PROCESS を使用した論理データベースの呼び出しは、実際のデータ取得を、先行する選択画面処理やその後のデータ処理から分離します。

次のケースを除いて、LDB_PROCESS で使用するため、論理データベースを調整する 必要はありません。つまり、論理データベースを調整しないと、同一の論理データベースを 2 回以上呼び出す汎用モジュールが使用できない場合は例外です。PAI サブルーチンは、LDB_PROCESS を使用する際は呼び出されません。これは、プログラム済みの選択チェックは実行されないという意味です。サブルーチン LDB_PROCESS_INIT と LDB_PROCESS_CHECK_SELECTIONS をデータベースプログラムに加えることにより、これらの制限に対処できます。 

実行時の動作

論理データベースのサブルーチンは、汎用モジュール LDB_PROCESS を呼び出す際に次の順序で呼び出されます。

...

       1.      LDB_PROCESS_INIT

       2.      INIT

       3.      LDB_PROCESS_CHECK_SELECTIONS

       4.      PUT <node>.

論理データベースを実行可能プログラムにリンクする場合、選択画面の処理に使用されるサブルーチンは呼び出されず、実行時環境は呼び出しプログラムのレポートイベントを開始しません。代わって、論理データベース内の PUT 命令は、呼び出しプログラム内のコールバックルーチンを呼び出す汎用モジュールのアクションを開始します。いいかえると、汎用モジュールはイベントを捕らえます。捕らえなければ、イベントは実行時環境により処理されます。

LDB_PROCESS のパラメータ

この汎用モジュールには、以下のインポートパラメータがあります。

ｷ        LDBNAME

呼び出す論理データベースの名称。

ｷ        VARIANT

論理データベースの選択画面を埋めるバリアントの名称。バリアントは、あらかじめ論理データベースのデータベースプログラムに割り当てられている必要があります。データは、SUBMIT 命令で WITH SELECTION-TABLE 追加を使用する場合と同一の方法で渡されます。

ｷ        EXPRESSIONS

このパラメータでは、動的選択が可能な論理データベースのノードの特別な選択を渡すことができます。パラメータ RSDS_TEXPR のデータ型は、データ型グループ RSDS で定義されます。データは、SUBMIT 命令で WITH FREE SELECTION 追加を使用する場合と同一の方法で渡されます。

ｷ        FIELD_SELECTION

このパラメータを使用して、動的選択の可能な論理データベースのノードの必須項目の一覧を渡すことができます。パラメータのデータ型は、データ型グループ RSFS で定義されたデープ内部テーブルです。コンポーネント TABLENAME にはノードの名称が含まれており、デープコンポーネント FIELDS には読み取る項目名称が含まれています。 

この汎用モジュールには、以下のテーブルパラメータがあります。

ｷ        CALLBACK

このパラメータは、コールバックルーチンをノードおよびイベントの名称に割り当てるために使用します。パラメータは、データが読み取られる論理データベースのノード、データがプログラムに戻された時期、戻されたコールバックルーチンを決定します。

ｷ        SELECTIONS

このパラメータを使用して、論理データベースの選択画面の項目の入力値を渡すことができます。パラメータのデータ型は、ABAP ディクショナリ内の構造 RSPARAMS に対応します。データは、SUBMIT 命令で WITH SELECTION-TABLE 追加を使用する場合と同一の方法で渡されます。

2 個以上のインタフェースパラメータを使用して選択を渡す場合、SELECTIONS と EXPRESSIONS で渡された値は、VARIANT の同一項目の値を上書きします。

深度とコールバックルーチンの読み取り

論理データベースを実行可能プログラムとリンクする場合、GET 命令は論理データベースを読み取る深度を決定します。汎用モジュール LDB_PROCESS を呼び出す場合、CALLBACK パラメータでノード名を指定することにより深度を決定します。データを要求したそれぞれのノードについて、コールバックルーチンは 2 個所で実行できます。これらは、実行可能プログラムの GET イベントと GET LATE イベントに対応します。テーブルパラメータ CALLBACK では、コールバックルーチンの名称および必要な実行ポイントを指定します。コールバックルーチンは、呼び出しプログラムまたは、必須ポイントで実行される別のプログラムのサブルーチンです。

GET イベントではコールバックルーチンは、ノードからデータが読み取られた直後で、下位ノードが処理される前に実行されます。GET_LATE イベントについては、コールバックルーチンは下位ノードが処理された後に処理されます。

ｷ        テーブルパラメータCALLBACK の行タイプは、ABAP ディクショナリのフラット構造 LDBCB です。それには次のコンポーネント LDBNODE があります。

読み取られる論理データベースのノードの名称。

ｷ        GET

GET イベントで対応するコールバックルーチンを呼び出すためのフラグ (コンテンツ X または SPACE)。

ｷ        GET_LATE

GET LATE イベントで対応するコールバックルーチンを呼び出すためのフラグ (コンテンツ X または SPACE)。

ｷ        CB_PROG

コールバックルーチンが定義されている ABAP プログラムの名称。

ｷ        CB_FORM

コールバックルーチンの名称

内部テーブルを CALLBACK パラメータに渡す場合、少なくとも GET か GET_LATE 列の 1 つを、各ノードの X (また X を記入してもよい) を記入する必要があります。 

コールバックルーチンは、次のパラメータインタフェースで定義する必要のあるサブルーチンです。

FORM <subr> USING <node> LIKE LDBCB-LDBNODE
                  <wa>   [TYPE <t>]
                  <evt>
                  <check>.

ｷ        パラメータは、汎用モジュールLDB_PROCESS により埋められます。これは、<node> にノード名が含まれているという意味です。

ｷ        <wa> は、ノードから読み取ったデータの作業領域です。汎用モジュール LDB_PROCESS およびコールバックルーチンを含むプログラムを呼び出すプログラムは、NODES か TABLES を使用してインタフェース作業領域を宣言する必要がありません。コールバックルーチンは、1 つのノードに対してのみ使用された場合、ABAP ディクショナリ内のノードのデータ型を参照するため、TYPE 参照を使用できます。その後は、構造化されたノードの個々のコンポーネントにサブルーチンの中で直接アドレスできます。2 個以上のノードにコールバックルーチンを使用するときは、TYPE 参照を使用できません。この場合、構造化されたノードを項目シンボルに 1 つずつ割り当てる ことにより、ノードのコンポーネントにアドレスする必要があります。

ｷ        <evt> には G または L が入りますが、それぞれ GET または GET LATE を表わします。これは、サブルーチンが <evt> の内容を使用してプログラムフローを指定できるという意味です。 

ｷ        <check> によりコールバックルーチンは、プログラムが処理される方法に影響を与えることができます (ただし <evt> の値が G の場合のみ)。値 X は、サブルーチンが呼び出される際にパラメータに割り当てられます。サブルーチンが終了する際にパラメータの値が SPACE の場合、これは論理データベースの下位ノードが汎用モジュール LDB_PROCESS の中で処理されないように指定します。これは、実行可能プログラムの中で CHECK を使用して GET イベントブロックを放置する のと同じです。これにより不要なデータが読み取られなければ、プログラムのパフォーマンスが改善されます。

LDB_PROCESS の例外

ｷ        LDB_ALREADY_RUNNING

論理データベースは、まだ前の呼び出しを処理している間は、呼び出されません。それでも呼び出しが発生すると、例外 LDB_ALREADY_RUNNING が開始されます。 

ｷ        LDB_NOT_REENTRANT

論理データベースは、データベースプログラムにサブルーチン LDB_PROCESS_INIT がある場合のみ、繰り返し呼び出されます。それ以外の場合は、この例外が開始されます。

ｷ        LDB_SELECTIONS_NOT_ACCEPTED

データベースプログラムのサブルーチン LDB_PROCESS_CHECK_SELECTIONS のエラー処理では、この例外を開始できます。エラーメッセージは、通常のシステム項目 SY-MSG... に格納されます。

例外についての追加情報は、汎用モジュールビルダの中の汎用モジュール文書を参照してください。

例

 

TABLES SPFLI.
SELECT-OPTIONS S_CARR FOR SPFLI-CARRID.

TYPE-POOLS: RSDS, RSFS.

DATA: CALLBACK TYPE TABLE OF LDBCB,
      CALLBACK_WA LIKE LINE OF CALLBACK.

DATA: SELTAB TYPE TABLE OF RSPARAMS,
      SELTAB_WA LIKE LINE OF SELTAB.

DATA: TEXPR TYPE RSDS_TEXPR,
      FSEL  TYPE RSFS_FIELDS.

CALLBACK_WA-LDBNODE     = 'SPFLI'.
CALLBACK_WA-GET         = 'X'.
CALLBACK_WA-GET_LATE    = 'X'.
CALLBACK_WA-CB_PROG     = SY-REPID.
CALLBACK_WA-CB_FORM     = 'CALLBACK_SPFLI'.
APPEND CALLBACK_WA TO CALLBACK.

CLEAR CALLBACK_WA.
CALLBACK_WA-LDBNODE     = 'SFLIGHT'.
CALLBACK_WA-GET         = 'X'.
CALLBACK_WA-CB_PROG     = SY-REPID.
CALLBACK_WA-CB_FORM     = 'CALLBACK_SFLIGHT'.
APPEND CALLBACK_WA TO CALLBACK.

SELTAB_WA-KIND = 'S'.
SELTAB_WA-SELNAME = 'CARRID'.

LOOP AT S_CARR.
  MOVE-CORRESPONDING S_CARR TO SELTAB_WA.
  APPEND SELTAB_WA TO SELTAB.
ENDLOOP.

CALL FUNCTION 'LDB_PROCESS'
     EXPORTING
          LDBNAME                     = 'F1S'
          VARIANT                     = ' '
          EXPRESSIONS                 = TEXPR
          FIELD_SELECTION             = FSEL
     TABLES
          CALLBACK                    = CALLBACK
          SELECTIONS                  = SELTAB
     EXCEPTIONS
          LDB_NOT_REENTRANT           = 1
          LDB_INCORRECT               = 2
          LDB_ALREADY_RUNNING         = 3
          LDB_ERROR                   = 4
          LDB_SELECTIONS_ERROR        = 5
          LDB_SELECTIONS_NOT_ACCEPTED = 6
          VARIANT_NOT_EXISTENT        = 7
          VARIANT_OBSOLETE            = 8
          VARIANT_ERROR               = 9
          FREE_SELECTIONS_ERROR       = 10
          CALLBACK_NO_EVENT           = 11
          CALLBACK_NODE_DUPLICATE     = 12
          OTHERS                      = 13.

IF SY-SUBRC <> 0.
  WRITE: 'Exception with SY-SUBRC', SY-SUBRC.
ENDIF.

FORM CALLBACK_SPFLI USING NAME  TYPE LDBN-LDBNODE
                          WA    TYPE SPFLI
                          EVT   TYPE C
                          CHECK TYPE C.
  CASE EVT.
   WHEN 'G'.
      WRITE: / WA-CARRID, WA-CONNID, WA-CITYFROM, WA-CITYTO.
      ULINE.
    WHEN 'L'.
      ULINE.
  ENDCASE.
ENDFORM.

FORM CALLBACK_SFLIGHT USING NAME  TYPE LDBN-LDBNODE
                            WA    TYPE SFLIGHT
                            EVT   TYPE C
                            CHECK TYPE C.
  WRITE: / WA-FLDATE, WA-SEATSOCC, WA-SEATSMAX.
ENDFORM.

プログラムは、論理データベース F1S を使用してデータを読み取ります。F1S の構成は、以下のとおりです。

プログラムに基づく選択画面がプログラムの最初で定義されます。これには TABLES 命令が必要です。次に必須変数がインタフェース向けに定義されます。 

内部テーブル CALLBACK にデータが埋められることで、様々なコールバックルーチンが 2 つのノード SPFLI と SFLIGHT のプログラムの中で呼び出されます。SPFLI については GET と GET_LATE のルーチンで呼び出されますが、SFLIGHT については GET イベントでのみ呼び出されます。

内部テーブル SELTAB は、プログラムに基づく選択画面の選択テーブル S_CARR のノード SPFLI の値で埋められます。

その後プログラムは、これらのパラメータを指定して汎用モジュール LDB_PROCESS を呼び出します。

サブルーチン CALLBACK_SPFLI と CALLBACK_SFLIGHT は、コールバックルーチンとして機能します。インタフェースパラメータ WA がきちんと指定されていると、作業領域の個々のコンポーネントにアドレスできます。イベント GET と GET LATE は、CALLBACK_SPFLI では異なる処理が行われます。

一覧出力の最初の部分は、以下のようになります。