CHECK の使用によるイベントブロックの終了 

( ループ内ではない) イベントブロック内で CHECK <expr> 命令を使用し、条件 <expr> が満たされない場合には、処理ブロックが即時に停止されます。 

<expr> は、任意の論理式または選択テーブルの名称です。選択テーブルを指定して、対応するテーブル作業領域の内容が選択テーブルの条件を満たさない場合には、論理式が誤っているのと同じです。

ABAP 実行時環境では、以下の図にしたがって次のイベントがトリガされます。

指定順序での次のイベントが必ず呼び出されます。 

CHECK 命令が DO 、WHILE 、または LOOP を使用するループで発生した場合には、処理ブロックではなく、ループが終了します。

GET イベントブロック内では、これは同じ階層レベルにおける次の GET イベントを意味します。 イベントブロックを終了すると、論理データベースは現在のノードの次の行、またはすでに階層レベルの最後まで到達した場合には次に高いノードを読み込みます。論理データベースの階層構造のさらに下位にあるノードは、処理されません。 

GET イベント内では、CHECK 命令の追加バリアントを使用することができます。

CHECK SELECT-OPTIONS.

この命令は、現在のノードのテーブル作業領域の内容を、そのノードにリンクされたすべての選択テーブルに照らし合わせてチェックします。 

GET イベントでデータベース内容をチェックする CHECK 命令は、論理データベースからデータが読み込まれたあとにのみ、処理されることに注意します。したがって、パフォーマンス上の理由により、この種のチェックの使用は避けるようにしてください。代わりに、動的選択を使用するなどして、データを読み込む前にチェックするようにしてください。 

以下のプログラムは、論理データベース F1S に接続されています。

REPORT EVENT_DEMO.

NODES: SPFLI, SFLIGHT, SBOOK.

START-OF-SELECTION.
  CHECK CITY_FR NE ' '.
  WRITE: / 'Selected City-From:', CITY_FR.
  ULINE.
  CHECK CITY_TO NE ' '.
  WRITE: / ' Selected City-To:', CITY_TO.
  ULINE.

GET SFLIGHT.
  WRITE: / 'Connid:', SFLIGHT-CONNID,
           'Carrid:', SFLIGHT-CARRID,
           'Fldate:', SFLIGHT-FLDATE.

CITY_FR に “Frankfurt” を入力し、CITY_TO には何も入力しない場合、一覧の最初はたとえば以下のようになります。

2 番目の CHECK 命令の後、START-OF-SELECTION ブロックが終了され、イベント GET SFLIGHT がトリガされます。

 

以下のプログラムは、論理データベース F1S に接続されています。

REPORT EVENT_DEMO.

NODES: SPFLI, SFLIGHT, SBOOK.

GET SFLIGHT.
  CHECK SFLIGHT-CARRID EQ 'LH'.
  WRITE: / 'Connid:', SFLIGHT-CONNID,
           'Carrid:', SFLIGHT-CARRID,
           'Fldate:', SFLIGHT-FLDATE.

GET SBOOK.
  CHECK SBOOK-BOOKID LT 00000320.
  WRITE: / 'Bookid:', SBOOK-BOOKID.

GET SFLIGHT LATE.
  ULINE.

これにより、出力一覧は以下のようになります。

上の例では、ノード SFLIGHT のすべての行、そして SFLIGHT-CARRID が"LH" の場合には、ノード SBOOK のすべての行が読み込まれる必要があります。パフォーマンス上の理由により、上のようなプログラミング選択は避けてください。代わりに、論理データベースの選択を使用します。