コンテンツフレーム起動

このグラフィックは添付のテキストに説明されています  オブジェクト参照へのバインド ( インスタンス ) 文書を SAP ライブラリストラクチャに組み込む

ABAP オブジェクト参照は JavaScript では、定義済みプロキシクラス SAPAbapOrefClass のプロキシオブジェクトとしてマップされます。JavaScript 参照には、BIND メソッドの NAME_PROP パラメータを使用して大文字小文字を区別する名称を指定できます。

プロキシオブジェクトのコンポーネントを次に示します。

ｷ        定義済みプロパティ ‘Class’ 。プロキシクラス SAPAbapCrefClass に基いており、黙示的にそのオブジェクトクラスにバインドされています。このため、クラスへのバインドで説明したようにオブジェクトの静的コンポーネントにアクセスできます。

ｷ        プロパティとして参照された ABAP オブジェクトのパブリックインスタンス属性 ( 小文字) 。

ｷ        定義済みメソッド ‘invoke’ 。参照された ABAP オブジェクトのパブリックインスタンスメソッドを呼び出すことができます。

ｷ        入力パラメータを持たず論理値を返す定義済みメソッド ‘notInitial’ 。ABAP オブジェクト参照がインスタンスをポイントする場合、戻り値は真です。ABAP オブジェクト参照が空白の場合は偽です。

JavaScript 内では、他のプロパティまたはメソッドをプロキシオブジェクトに追加できません。JavaScript の中でバインドされたオブジェクト参照に ABAP オブジェクト参照を割り当てる場合、または JavaScript の中で存在しない ABAP オブジェクトの属性にアクセスしようとする場合 (ABAP の参照変数が空白) 、JavaScript は処理を停止します。

インスタンス属性へのアクセス

JavaScript オブジェクトを ABAP のオブジェクト参照変数に割り当てる場合、また JavaScript は ABAP オブジェクトの属性も使用します。割当後のオブジェクト参照変数は、ABAP オブジェクトをポイントします。JavaScript 内の変数は ABAP 内のオブジェクト参照変数にバインドされており、ABAP オブジェクトにバインドされていません ( 参照: BIND_INSTANCE) 。

JavaScript オブジェクトは、静的タイプのオブジェクト参照変数にリンクされます。ABAP 内での割当を使用して縮小キャストが実行される場合、JavaScript オブジェクトは独自のデータ型を維持しており、動的タイプの追加された属性にアクセスできません。同様に、拡大キャストを実行して ABAP の中だけでチェックさせることができます。このため JavaScript では、参照されたオブジェクトで存在しない属性にアクセスするといった問題は生じません。

JavaScript の中でバインドされたオブジェクト参照変数のプロパティを他の変数に割り当てる場合、注意してください。関連するオブジェクトが ABAP の中でガーベッジコレクタにより削除されてから、対象の変数を使用しようとすると、実行時エラーが発生します。

例

report DEMO_JAVA_SCRIPT_BIND_ATTRIBUT.

class C1 definition.
  public section.
    data ATTR type STRING.
    methods CONSTRUCTOR.
endclass.

class C1 implementation.
  method CONSTRUCTOR.
    ATTR = 'Hello '.
  endmethod.
endclass.

data OREF type ref to C1.

data RETURN_VALUE type STRING.

data SOURCE type STRING.

data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.

start-of-selection.

  JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

  JS_PROCESSOR->BIND(  EXPORTING
                        NAME_OBJ  = 'abap'
                        NAME_PROP = 'Ref'
                       CHANGING
                         DATA      = OREF ).

  create object OREF.

concatenate  'if ( abap.Dref.notInitial() )  '
             '{ abap.Ref.attr += " World!"; }'
             INTO source.

  JS_PROCESSOR->EVALUATE( JAVA_SCRIPT = SOURCE ).
  write OREF->ATTR..

この例では、JavaScript は属性 OREF->ATTR を 'Hello' から 'Hello World!' に変更します。CREATE OBJECT の割当の前に JavaScript が 'oref.attr' にアクセスしようとすると、処理は終了します。

インスタンスメソッドの呼び出し

ABAP 内の参照オブジェクトのパブリックインスタンスメソッドを JavaScript から呼び出すには、関連する JavaScript オブジェクトの ‘invoke’ メソッドを使用します。

‘invoke’ メソッドは、最初の引数として ABAP インスタンスメソッドの小文字の名称、その後にパラメータが渡されると期待しています。ABAP インスタンスメソッドのオプションでないインタフェースパラメータのそれぞれについて、パラメータ名および実際のパラメータをコンマで区切ったペアで指定する必要があります。これらのペアは任意の順序で指定できます。オプションのパラメータ、または通常の ABAP の追加 EXPORTING 、IMPORTING 、CHANGING 、RETURNING を指定する必要はありません。

制限事項

ｷ        呼び出された ABAP メソッドのインタフェースの中で渡された全パラメータは、名称を短縮しないで指定する必要があります。ANY または STANDARD TABLE などの汎用タイプは使用できません。

ｷ        呼び出されたメソッドは、バックグラウンド処理が有効である必要があります。つまり、ユーザとのインタラクションを予想する必要があります。

ｷ        呼び出されたメソッドは、最大で 32 個のパラメータを受け付けできます。これは‘invoke’ メソッドの 65 個の引数に対応しています。

ｷ        メソッド呼び出しはシステムフィールド SY-SUBRC 、SY-MSGV1 to SY-MSGV4 に反映されるので、メソッド自身の中でこれらのフィールドにアクセスしたり、スクリプトの実行後にアクセスしても意味はありません。

ｷ        メソッドのインタフェースで RAISING を使用して伝達されたクラスベースの例外は JavaScript では処理できず、スクリプトを終了させます。ただし、これらは ABAP の中の TRY ブロックでは処理できます。JavaScript では、標準的例外を処理できます。

RETURNING パラメータを使用して値を渡す

‘invoke’ の戻り値は、呼び出されたメソッドの RETURNING パラメータで自動的に入力されます。RETURNING パラメータのタイプが基本データ型の場合、これが ABAP メソッドの実際の戻り値になります。したがってこの場合、必ずしも RETURNING パラメータの引数を指定する必要はありません。RETURNING パラメータのタイプが複合データ型か、RETURNING パラメータがない場合、'invoke' の戻り値は jsval_void に設定されます。そのため複合 RETURNING パラメータを指定する場合は、引数を指定する必要があります。

例

report DEMO_JAVA_SCRIPT_BIND_METH_RET.

class COUNTER definition.
  public section.
    methods: SET importing VALUE(SET_VALUE) type I,
             INCREMENT,
             GET returning VALUE(GET_VALUE) type I.
  private section.
    data COUNT type I.
endclass.

class COUNTER implementation.
  method SET.
    COUNT = SET_VALUE.
  endmethod.
  method INCREMENT.
    COUNT = COUNT + 1.
  endmethod.
  method GET.
    GET_VALUE = COUNT.
  endmethod.
endclass.

data OREF type ref to COUNTER.
data RESULT type I.

data SOURCE type STRING.
data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.

data GET_VALUE type STRING.

start-of-selection.

  JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

  JS_PROCESSOR->BIND( exporting NAME_OBJ  = 'abap'
                                NAME_PROP = 'Ref'
                      changing  DATA      = OREF ).

  create object OREF.

  concatenate
  'var start_value = 10;                                   '
  'var result = 0;                                         '
  'abap.Ref.invoke("set", "set_value", start_value );       '
  'for (var i = 0; i < 5; i++)                              '
  '  {                                                     '
  '  abap.Ref.invoke("increment");                        '
  '  }                                                     '
  'result=abap.Ref.invoke("get"  );                        '
* 'result=abap.Ref.invoke("get", "get_value", result );     '
   into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.

  JS_PROCESSOR->COMPILE(
                exporting
                  SCRIPT_NAME = 'COUNT.JS'
                  SCRIPT      = SOURCE ).

  JS_PROCESSOR->EXECUTE(
                exporting SCRIPT_NAME = 'COUNT.JS').

  GET_VALUE = JS_PROCESSOR->GET( NAME = 'result').

  RESULT = OREF->GET( ).

  write / GET_VALUE.
  write / RESULT.

この例では、ローカルクラス COUNTER のABAP オブジェクトは、JavaScript オブジェクト abap.Ref に OREF 参照変数を使用してバインドされます。JavaScript は ABAP メソッド SET 、INCREMENT (5 回) 、および GET を ‘invoke’ メソッドを使用して呼び出します。ABAP の GET メソッドを呼び出す場合、RESULTING パラメータ GET_VALUE はグローバル変数結果に戻り値として渡されます。引数を指定するコメントされた行も、同一の効果です。ただし、ABAP メソッドの RETURNING パラメータのため、引数リストは余分です。

result は JavaScript コンテキストから読み取られて、ABAP 変数 GET_VALUE にクラス CL_JAVA_SCRIPT の GET メソッドを使用して渡されます。さらに、プログラムは ABAP の中で ABAP メソッド GET を呼び出して ABAP 変数 RESULT に入力します。JavaScript の結果の値と ABAP の RESULT は同一です。

引数を使用した値の受け渡し

基本 RETURNING パラメータ以外のパラメータ、つまり複合 RETURNING パラメータまたは IMPORTING EXPORTING パラメータ、CHANGING パラメータを受け渡しする場合、適切な引数を指定する必要があります。

Note:

ｷ        実際のパラメータおよび形式的パラメータのタイプは、互換性がある必要があります。

ｷ        数値、リテラル ( 文字列) 、または単純な数値か文字列の含まれている JavaScript 変数を実際のパラメータとして指定する場合、それは値で渡されて、定数のように扱われます。これらのパラメータは、ABAP メソッドの EXPORTING 、CHANGING 、RETURNING パラメータに影響されません。これは、JavaScript からの ABAP メソッド呼び出しの特性ではありません。これはまた、JavaScript 関数の呼び出しにも適用されます ( 後述の例DEMO_JAVA_SCRIPT_BIND_METH_VAL を参照) 。ABAP 変数が単純な値を持つ JavaScript 変数にバインドされていると、同じことが適用されます。

ｷ        JavaScript 変数に参照により値を渡すには、複合 JavaScript 変数、つまりクラスプロパティを使用する必要があります。

CL_JAVA_SCRIPT クラスにより作成されたコンテキストには、定義済みクラス SAPAbapMethParam があります。このため、これには正確に 1 つの基本属性 ( 文字列タイプ) があります。この属性のどれも呼び出しすることができますが、名前 ‘value’ をお奨めします。このクラスのオブジェクトの作成後は、基本値を渡すためにその単一属性を使用できます(DEMO_JAVA_SCRIPT_BIND_METH_REF の例を参照) 。この使用は ABAP メソッド呼び出しに制限されません。JavaScript 機能にも適用できます ( 例DEMO_JAVA_SCRIPT_BIND_METH_VAL を参照) 。

また参照を渡すため、バインドされた複合 ABAP データオブジェクトのJavaScript 等価のプロパティを使用できます。この場合、値を渡す際にタイプに互換性があることをふたたび確認する必要があります。

例

report DEMO_JAVA_SCRIPT_BIND_METH_VAL.

class C_ABAP definition.
  public section.
    methods SET_VALUE exporting P_ABAP type I.
endclass.

class C_ABAP implementation.
  method SET_VALUE.
    P_ABAP = 111.
  endmethod.
endclass.

data OREF type ref to C_ABAP.
data RESULT type I.

data SOURCE type STRING.
data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.

data GET_VALUE type STRING.

start-of-selection.

  JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

  JS_PROCESSOR->BIND( exporting NAME_OBJ  = 'abap'
                                NAME_PROP = 'Ref'
                      changing  DATA      = OREF ).

  create object OREF.

  concatenate
  'var result_abap_val  =  0;                                '
  'var result_js_val    =  0;                                '
  'var result_abap_ref   = new SAPAbapMethParam(0);          '
  'var result_js_ref     = new SAPAbapMethParam(0);          '
  'var result_abap_ref_prop   = 0                            '
  'var result_js_ref_prop     = 0                            '
  'function set_value_val(p_js) { p_js = 666 };              '
  'function set_value_ref(p_js) { p_js.value = 666 };        '
  'abap.Ref.invoke("set_value", "p_abap", result_abap_val );'
  'set_value_val(result_js_val);                             '
  'abap.Ref.invoke("set_value", "p_abap", result_abap_ref );'
  'set_value_ref(result_js_ref);                             '
  'result_abap_ref_prop   = result_abap_ref.value;       '
  'result_js_ref_prop     = result_js_ref.value;         '
   into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.

  JS_PROCESSOR->COMPILE(
                exporting
                  SCRIPT_NAME = 'VALUES.JS'
                  SCRIPT      = SOURCE ).

  JS_PROCESSOR->EXECUTE(
                exporting SCRIPT_NAME = 'VALUES.JS').

  GET_VALUE = JS_PROCESSOR->GET( NAME = 'result_abap_val').
  write: /  'result_abap_val' , 40 GET_VALUE.

  GET_VALUE = JS_PROCESSOR->GET( NAME = 'result_js_val').
  write: /  'result_js_val' , 40 GET_VALUE.

  GET_VALUE = JS_PROCESSOR->GET(
                            NAME = 'result_abap_ref_prop').
  write: /  'result_abap_ref.value' , 40 GET_VALUE.

  GET_VALUE = JS_PROCESSOR->GET(
                            NAME = 'result_js_ref_prop').
  write: /  'result_js_ref.value' , 40 GET_VALUE.

この例では、ローカルクラス C_ABAP のABAP オブジェクトは、JavaScript オブジェクト abap.Ref に OREF 参照変数を使用してバインドされます。JavaScript では、result_abap_val と js_abap_val という 2 個の単純変数が定義されており、同時にクラスSAPAbapMethParam の 2 個のオブジェクトresult_abap_ref と result_js_ref が定義されています。さらに、set_value_val と set_value_ref という 2 個の JavaScript 関数も定義されています。

ABAP メソッド SET_VALUE および JavaScript 関数は、別の引数を付けて呼び出されます。引数に渡された値は、ABAP プログラムの GET メソッドを使用してチェックされます。GET はオブジェクトの属性にアクセスできないため、SAPAbapMethParam クラスのオブジェクトの ‘value’ プロパティは、補助変数に割り当てられます。

プログラムは、result_abap_val と js_abap_val がメソッドまたは関数の呼び出しに影響されないことを示しており、SAPAbapMethParam クラスの ‘value‘ 属性に値を渡すのが可能なことを示します。

標準的例外の処理

メソッド定義で EXCEPTIONS を使用して宣言され、JavaScript で RAISE を使用してメソッド内で引き起こされた標準的例外を処理することができます。そのときJavaScript は終了しません。この方法で例外を処理するため、オプションのパラメータEXCEPTION ( 大文字にして引用符で囲む) と実際のパラメータを指定する必要があります。これは、定義済みクラスSAPAbapMethParam のインスタンスです。

例

report DEMO_JAVA_SCRIPT_BIND_METH_EXC.

class C1 definition.
  public section.
    methods TEST exceptions EXC.
endclass.

class C1 implementation.
  method TEST.
    raise exc.
  endmethod.
endclass.

data OREF type ref to C1.

data SOURCE type STRING.
data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.

data RESULT type STRING.

start-of-selection.

  JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

  JS_PROCESSOR->BIND( exporting NAME_OBJ  = 'abap'
                                NAME_PROP = 'Ref'
                      changing  DATA      = OREF ).

  create object OREF.

  concatenate
  'var except = new SAPAbapMethParam();           '
  'abap.Ref.invoke("test", "EXCEPTION", except );'
  'except.value;                                  '
  into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.

  JS_PROCESSOR->COMPILE(
                exporting
                  SCRIPT_NAME = 'TEST.JS'
                  SCRIPT      = SOURCE ).

  RESULT = JS_PROCESSOR->EXECUTE('TEST.JS').
  write / result.

この例では、ローカルクラス C1 のABAP オブジェクトは、JavaScript オブジェクト abap.Ref に OREF 参照変数を使用してバインドされます。JavaScript では、クラス SAPAbapMethParam のオブジェクト ‘except’ が定義されています。

ABAP メソッドの TEST は JavaScript の中で呼び出され、例外 EXC が処理されます。メソッド呼び出しの後、except.value プロパティは EXC の値になります。

クラスベースの例外処理

メソッド定義で RAISING を使用して宣言され、JavaScript で RAISE EXCEPTION を使用してメソッド内で引き起こされたクラスベースの例外は処理できません。それは、LAST_CONDITION_CODE および LAST_ERROR_MESSAGE 属性に値を入力しないで JavaScript を終了させます。代わりに、スクリプトを TRY ブロックで実行することで、CATCH を使用して例外を処理できます。

例

report DEMO_JAVA_SCRIPT_BIND_METH_CX.

class C1 definition.
  public section.
    data    ATTR type STRING.
    methods TEST raising CX_SY_ZERODIVIDE.
endclass.

class C1 implementation.
  method TEST.
    raise  exception type CX_SY_ZERODIVIDE.
    ATTR = 'Hello World!'.
  endmethod.
endclass.

data OREF type ref to C1.
data SOURCE type STRING.
data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.
data RESULT type STRING.

data EXCREF type ref to CX_ROOT.
data TEXT   type STRING.

start-of-selection.

  JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

  JS_PROCESSOR->BIND( exporting NAME_OBJ  = 'abap'
                                NAME_PROP = 'Ref'
                      changing  DATA      = OREF ).

  create object OREF.

  concatenate
  'abap.Ref.invoke("test");'
  'abap.Ref.attr;            '
  into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.

  JS_PROCESSOR->COMPILE(
                exporting
                  SCRIPT_NAME = 'TEST.JS'
                  SCRIPT      = SOURCE ).

  try.
      RESULT = JS_PROCESSOR->EXECUTE('TEST.JS').
      write / JS_PROCESSOR->LAST_ERROR_MESSAGE.
      write / RESULT.
    catch CX_ROOT into EXCREF.
      TEXT = EXCREF->GET_TEXT( ).
      message TEXT type 'I'.
  endtry.

例外が発生すると JavaScript は終了し、例外は CATCH ブロック内で処理されます。

 

 

 

 

コンテンツフレーム終了