静的クラスコンポーネントへのバインド 

JavaScript で静的タイプのクラスを持つオブジェクト参照変数 ( オブジェクト参照へのバインド (インスタンス)) にバインドすると、ABAP クラスの静的コンポーネントへのアクセスのみ可能となります。ただし、ABAP では必ずしもこのクラスのインスタンスを作成する必要はありません。

ABAP クラスの静的コンポーネントは、JavaScript 内では定義済みプロキシクラス SAPAbapCrefClass のプロキシオブジェクトとしてマップされます。それらをオブジェクト参照変数にバインドする際は、関連するプロキシオブジェクト ( プロキシ) はSAPAbapCrefClass に基いて ‘Class’ プロパティを有します。

プロキシオブジェクト ‘proxy.Class’ のコンポーネントを次に示します。

ｷ        クラスのパブリック静的属性 ( 小文字) 。

ｷ        定義済みメソッド ‘invoke’ 。そのクラスのパブリック静的メソッドを呼び出すことができます ( オブジェクト参照へのバインド (インスタンス)を参照) 。

ｷ        入力パラメータを持たず論理値を返す定義済みメソッド ‘isActive’ 。ABAP プログラムでクラスがロードされれば、戻り値は真です ( つまり静的コンストラクタが実行された場合) 。クラスがロードされなかった場合は偽です。ロードされていないクラスの静的コンポーネントには、アクセスできません。現在、クラスがJavaScript の中ではなく ABAP の中で使用されることにより、ロードのみ可能です。

JavaScript 内では、他のプロパティまたはメソッドをプロキシオブジェクト‘proxy.Class’ に追加できません。JavaScript 内で ‘proxy.Class’ に割り当てたり、ロードされていないクラスのコンポーネントをアクセスしようとすると、JavaScript は終了します。

report DEMO_JAVA_SCRIPT_BIND_DREF.

class C1 definition.
  public section.
    class-data A1 type STRING value 'Hello'.
    class-methods M1.
  protected section.
    class-data A2 type STRING value 'Hello'.
endclass.

class C1 implementation.
  method M1.
    concatenate A1 '!' into A1.
  endmethod.
endclass.

data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.

data OREF type ref to C1.

data SOURCE type STRING.

start-of-selection.

  JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

  JS_PROCESSOR->BIND( exporting NAME_OBJ  = 'abap'
                               NAME_PROP = 'Oref'
                      changing  DATA      =  OREF ).

  concatenate  ' if ( abap.Oref.Class.isActive() )'
               '{ abap.Oref.Class.a1 += " World";   '
               '  abap.Oref.Class.invoke("m1");  }'
               into SOURCE.

  JS_PROCESSOR->EVALUATE( JAVA_SCRIPT = SOURCE ).

  write / C1=>A1.

この例では、JavaScript は属性 C1=>A1 を 'Hello' から 'Hello World!' に変更します。プログラムは、静的属性'Oref.Class.a1' にアクセスすることにより、‘World’ を属性値に追加します。'Oref.Class.invoke' を使用してメソッド C1=>M1 を呼び出して、‘!’ を追加します。