カーソル位置の設定 

画面が表示されると、カーソルは入力可能な最初の項目に自動的に置かれます。ただし、カーソルが表示される Dynpro エレメントをプログラムで定義することもできます。この Dynpro エレメントは入力項目でなくてもかまいません。カーソルの位置を指定することで、アプリケーションをよりユーザフレンドリにすることができます。

カーソル位置は、スクリーンペインタで静的に設定することも、ABAP プログラムで動的に設定することもできます。

静的なカーソル位置

カーソル位置を静的に定義するには、スクリーンペインタでカーソル位置 Dynpro 属性 に必要な Dynpro エレメントの名称を入力します。 

動的なカーソル位置

カーソル位置を動的に設定するには、ABAP ダイアログモジュールのPBO イベントで次の命令を使用します。

SET CURSOR FIELD <f> [OFFSET <off>].

<f> は、Dynpro エレメントの名称を含むリテラルまたは変数です。OFFSET オプションを使用して、入出力項目内の特定の位置にカーソルを配置することができます。

 

カーソル位置の指定

REPORT DEMO_DYNPRO_SET_CURSOR.

DATA: FIELD1(14), FIELD2(14), FIELD3(14),
      NAME(10).

SELECTION-SCREEN BEGIN OF BLOCK BLOC WITH FRAME.
  PARAMETERS: DEF RADIOBUTTON GROUP RAD,
              TXT RADIOBUTTON GROUP RAD,
              F1  RADIOBUTTON GROUP RAD,
              F2  RADIOBUTTON GROUP RAD,
              F3  RADIOBUTTON GROUP RAD.
SELECTION-SCREEN END OF BLOCK BLOC.

PARAMETERS POS TYPE I.

IF TXT = 'X'.
  NAME = 'TEXT'.
ELSEIF F1 = 'X'.
  NAME = 'FIELD1'.
ELSEIF F2 = 'X'.
  NAME = 'FIELD2'.
ELSEIF F3 = 'X'.
  NAME = 'FIELD3'.
ENDIF.

CALL SCREEN 100.

MODULE CURSOR OUTPUT.
  IF DEF NE 'X'.
    SET CURSOR FIELD NAME OFFSET POS.
  ENDIF.
  SET PF-STATUS 'SCREEN_100'.
ENDMODULE.

MODULE BACK INPUT.
  LEAVE SCREEN.
ENDMODULE.

プログラムの開始時に、選択画面が表示され、カーソル位置を選択することができます。 

続いて、Dynpro 100 が呼び出されます。Dynpro 100 の次画面 ( 静的に定義) はそれ自体です。この Dynpro のレイアウトは次のとおりです。

入出力項目は、ABAP プログラムの項目 FIELD1 から FIELD3 に割り当てられています。ヘッダはテキスト項目 TEXT 、押ボタンは Dynpro エレメント PUSH です。

Dynpro 属性の静的なカーソル位置は PUSH に設定されています。

Dynpro 制御ロジックは次のとおりです。

PROCESS BEFORE OUTPUT.
  MODULE CURSOR.

PROCESS AFTER INPUT.
  MODULE BACK AT EXIT-COMMAND.

PBO イベント時に、Dynpro 100 が表示される前に、選択画面におけるユーザの選択に従ってカーソルが設定されます。ユーザが静的な初期値を選択すると、カーソルは押ボタンに置かれます。それ以外の場合は、ヘッダまたは入力項目のいずれかに置かれます。位置 POS は、入力項目についてのみ考慮されます。