Leerzeilen, Linien und Kommentare 

Leerzeilen

Um Leerzeilen auf dem Selektionsbild auszugeben verwendet man:

SELECTION-SCREEN SKIP [n].

Diese Anweisung erzeugt n Leerzeilen, wobei n einen Wert zwischen 1 und 9 haben kann. Um eine einzelne Leerzeile zu erzeugen, kann man n auch weglassen.

Linien

Um Linien auf dem Selektionsbild auszugeben verwendet man:

SELECTION-SCREEN ULINE [[/]pos(len)] [MODIF ID key].

Diese Anweisung erzeugt eine Linie. Ohne Zusatz pos(len), wird für die Linie eine neue Zeile unter der aktuellen Zeile erzeugt und die Linie ist so lang wie die Zeile. Mit dem Zusatz pos(len), beginnt die Linie an der Stelle pos in der aktuellen Zeile und die Länge beträgt len Zeichen. Bei mehreren Elementen in einer Zeile kann (len) auch ohne pos angegeben werden. Der Schrägstrich (/) erzeugt einen Zeilenvorschub.

Für pos kann eine Zahl, oder einer der Ausdrücke pos_low oder pos_high angegeben werden. pos_low und pos_high sind die Positionen der beiden Eingabefelder eines Selektionskriteriums.

Der Zusatz MODIF ID key hat die gleiche Funktion wie bei der Anweisung PARAMETERS. Dadurch kann die Linie vor dem Aufruf des Selektionsbilds modifiziert werden.

Kommentare

Um Kommentare auf dem Selektionsbild auszugeben verwendet man:

SELECTION-SCREEN COMMENT [/]pos(len) comm [FOR FIELD f]
                                          [MODIF ID key].

Diese Anweisung schreibt den Kommentar comm auf das Selektionsbild. Für comm kann ein Textsymbol angegeben werden oder ein Feldnamen mit einer Länge von maximal acht Zeichen. Dieses Character-Feld darf nicht mit der Anweisung DATA deklariert werden, sondern wird automatisch in der Länge len generiert. Das Feld muss vor dem Aufruf des Selektionsbilds gefüllt werden. Der Zusatz pos(len) muss immer angegeben werden. Nur bei mehreren Elementen in einer Zeile kann pos weggelassen werden.

Der Text comm wird ab Spalte pos mit der Länge len angezeigt. Ohne Schrägstrich (/), wird der Kommentar in die aktuelle Zeile geschrieben, ansonsten wird eine neue Zeile erzeugt.

Mit FOR FIELD f wird dem Kommentar ein sogenannter Feldbezeichner zugeordnet. Dabei kann f der Name eines Parameters oder eines Selektionskriteriums sein. Fordert der Benutzer Hilfe zu dem Kommentar auf dem Selektionsbild an, wird dann der Hilfetext für des zugeordneten Felds f angezeigt.

Der Zusatz MODIF ID key hat die gleiche Funktion wie bei der Anweisung PARAMETERS. Dadurch kann der Kommentar vor dem Aufruf des Selektionsbilds modifiziert werden.

Beispiel

REPORT demo_sel_screen_select_comment.

SELECTION-SCREEN COMMENT /2(50) text-001 MODIF ID sc1.

SELECTION-SCREEN SKIP 2.
SELECTION-SCREEN COMMENT /10(30) comm1.
SELECTION-SCREEN ULINE.

PARAMETERS: r1 RADIOBUTTON GROUP rad1,
            r2 RADIOBUTTON GROUP rad1,
            r3 RADIOBUTTON GROUP rad1.

SELECTION-SCREEN ULINE /1(50).
SELECTION-SCREEN COMMENT /10(30) comm2.
SELECTION-SCREEN ULINE.

PARAMETERS: s1 RADIOBUTTON GROUP rad2,
            s2 RADIOBUTTON GROUP rad2,
            s3 RADIOBUTTON GROUP rad2.

SELECTION-SCREEN ULINE /1(50).

INITIALIZATION.

  comm1 ='Auswahlknopfgruppe 1'.
  comm2 ='Auswahlknopfgruppe 2'.

  LOOP AT SCREEN.
    IF screen-group1 = 'SC1'.
      screen-intensified = '1'.
      MODIFY SCREEN.
    ENDIF.
  ENDLOOP.

Es erscheint folgendes Selektionsbild:

Der im Textsymbol 001 angegebene Text 'Beispiel für Leerzeilen, Linien, Kommentare' wird optisch hervorgehoben. Zwei Gruppen von Auswahlknöpfen erscheinen unterhalb des Texts. Sie sind durch Linien getrennt und durch Kommentare erläutert. Ohne die Schrägstriche (/) bei den ULINE-Zusätzen, würden die entsprechenden Linien jeweils die letzte Zeile jeder Gruppe überschreiben.