Selektion definieren

DieSELECT -Klausel definiert die Struktur der Ergebnismenge (Selektion), für die von der Datenbank zu lesenden Daten.

Die Selektion kann eine einzelne Zeile also flach sein, oder aus mehreren Zeilen bestehen, also tabellenartig sein. Doppelt vorkommende Zeilen können ausgeschlossen werden. Die SELECT -Klausel bestimmt weiterhin die zu lesenden Spalten und definiert deren Namen. Dabei können die Namen aus der Datenbanktabelle durch alternative Spaltennamen ersetzt werden Auf einzelne Spalten können Aggregatfunktionen angewendet werden.

DieSELECT -Klausel lässt sich in zwei Teile für Zeilen und Spalten unterteilen:

SELECT lines cols ...

Inlines wird angegeben, ob eine einzelne Zeile mit: SELECT SINGLE cols

oder mehrere Zeilen mit: SELECT [DISTINCT] cols gelesen werden.

Ohne Angabe vonDISTINCT (lines ist also leer), werden alle Zeilen in Abhängigkeit von derWHERE -Klausel gelesen. Bei der Angabe vonDISTINCT werden doppelt vorkommende Zeilen ausgeschlossen.

Incols wird die Spaltenauswahl definiert.

Alle Spalten lesen

Um alle Spalten zu lesen schreibt man fürcols :

SELECT lines *...

Es werden alle Spalten der angegebenen Zeilen gelesen. Das Lesen einzelner Spalten kann erheblich performanter sein, als alle Spalten einer Datenbanktabelle zu lesen. Es sollten deshalb immer nur die Spalten gelesen werden, die auch im Programm benötigt werden.

Einzelne Spalten lesen

Um einzelne Spalten zu lesen schreibt man fürcols :

SELECT lines s1 [AS a1] s2 [AS a2] ...

• Hierbei bezeichnen dies ₁ s ₂ … einzelne Spalten. Durch den Zusatz AS kann für jede Spaltes ₁ s ₂ … ein alternativer Spaltenname a ₁ a ₂ …  definiert werden. Der alternative Spaltenname wird in derINTO -Klausel und in derORDER-BY -Klausel statt dem richtigen Spaltennamen verwendet. Beispielsweise kann so erreicht werden, dass bei der VarianteINTO CORRESPONDING FIELDS der INTO -Klausel der Inhalt einer Spalte s ₁ in eine Komponentea ₁ einer Struktur geschrieben wird.

Aggregate einzelner Spalten lesen

Um Aggregate, also zusammengefasste Daten, einzelner Spalten zu lesen, schreibt man fürcols :

SELECT lines agg( [DISTINCT] s1) [AS a1]

             agg( [DISTINCT] s2) [AS a2] ...

Hierbei sind dies ₁ s ₂ … wieder einzelne Spalten. Der Ausdruck agg steht für eine der folgenden Aggregatfunktionen:

• MAX : liefert den Maximalwert der Spalte
• MIN : liefert den Minimalwert der Spalte
• AVG : liefert den Durchschnittswert der Spalte
• SUM : liefert die Summe der Spalte
• COUNT : zählt Werte oder Zeilen wie folgt:

• • COUNT( DISTINCT s ) liefert die Anzahl unterschiedlicher Werte in der Spalte s .

  • COUNT( * ) bzw. count(*) liefert die gesamte Anzahl der Zeilen in der Ergebnismenge

MitDISTINCT können doppelt vorkommende Werte aus der Berechnung ausgeschlossen werden. Mit dem ZusatzAS kann wieder für jeden Aggregatausdruck ein alternativer Spaltennamea ₁ a ₂ … definiert werden.

Dynamische Spaltenangaben

Die Angabecols kann auch dynamisch gemacht werden:

SELECT lines (itab)...

In den Klammern muss der Name einer internen Tabelleitab stehen, die entweder leer ist oder die Angabens ₁ s ₂ … zum Lesen einzelner Spalten bzw. entsprechende Aggregatausdrücke enthält. Ist die interne Tabelle leer, bezeichnet sie alle Spalten.

REPORT demo_select_single.
DATA wa TYPE spfli.
SELECT  SINGLE carrid connid cityfrom cityto
  INTO  CORRESPONDING FIELDS OF wa
  FROM  spfli
  WHERE carrid EQ 'LH' AND connid EQ '0400'.
IF sy-subrc EQ 0.
  WRITE: / wa-carrid, wa-connid, wa-cityfrom, wa-cityto.
ENDIF.

REPORT demo_select_some_columns.
DATA: itab TYPE STANDARD TABLE OF spfli,
      wa LIKE LINE OF itab.
SELECT   carrid connid cityfrom cityto
  INTO   CORRESPONDING FIELDS OF TABLE itab
  FROM   spfli
  WHERE  carrid EQ 'LH'.
IF sy-subrc EQ 0.
  LOOP AT itab INTO wa.
    WRITE: / wa-carrid, wa-connid, wa-cityfrom, wa-cityto.
  ENDLOOP.
ENDIF.

REPORT demo_select_all_columns.
DATA wa TYPE spfli.
SELECT  *
  INTO  CORRESPONDING FIELDS OF wa
  FROM  spfli  
WHERE carrid EQ 'LH'.
  WRITE: / sy-dbcnt,
           wa-carrid, wa-connid, wa-cityfrom, wa-cityto.
ENDSELECT.

DATA RESULT TYPE P DECIMALS 2.
SELECT   agg( [DISTINCT] COL_2)
   INTO   RESULT
   FROM   TEST.
WRITE RESULT.

REPORT demo_select_dynamic_columns.
DATA: itab TYPE STANDARD TABLE OF spfli,
      wa LIKE LINE OF itab.
DATA: line(72) TYPE c,
      list LIKE TABLE OF line(72).
line = ' CITYFROM CITYTO '.
APPEND line TO list.
SELECT DISTINCT (list)
  INTO CORRESPONDING FIELDS OF TABLE itab
  FROM spfli.
IF sy-subrc EQ 0.
  LOOP AT itab INTO wa.
    WRITE: / wa-cityfrom, wa-cityto.
  ENDLOOP.
ENDIF.