Entering content frame

Table types Locate the document in its SAP Library structure

This section describes how to define internal tables locally in a program. You can also define internal tables globally as data types in the ABAP Dictionary.

Like all local data types in programs , you define internal tables using the TYPES statement. If you do not refer to an existing table type using the TYPE or LIKE addition, you can use the TYPES statement to construct a new local internal table in your program.

TYPES type TYPE|LIKE tabkind OF linetype [WITH key]
          [INITIAL SIZE n].

After TYPE or LIKE, there is no reference to an existing data type. Instead, the type constructor occurs:

tabkind OF linetype [WITH key]

The type constructor defines the table type tabkind, the line type linetype, and the key key of the internal table type.

You can, if you wish, allocate an initial amount of memory to the internal table using the INITIAL SIZE addition.

Table type

You can specify the table type tabkind as follows:

This graphic is explained in the accompanying text

Generic table types

INDEX TABLE

For creating a generic table type with index access.

ANY TABLE

For creating a fully-generic table type.

Data types defined using generic types can currently only be used for field symbols and for interface parameters in procedures . The generic type INDEX TABLEincludes standard tables and sorted tables. These are the two table types for which index access is allowed. You cannot pass hashed tables to field symbols or interface parameters defined in this way. The generic type ANY TABLE can represent any table. You can pass tables of all three types to field symbols and interface parameters defined in this way. However, these field symbols and parameters will then only allow operations that are possible for all tables, that is, index operations are not allowed.

Fully-Specified Table Types

STANDARD TABLE or TABLE

For creating standard tables.

SORTED TABLE

For creating sorted tables.

HASHED TABLE

For creating hashed tables.

Fully-specified table types determine how the system will access the entries in the table in key operations. It uses a linear search for standard tables, a binary search for sorted tables, and a search using a hash algorithm for hashed tables.

Line Type

For the line type linetype, you can specify:

        Any data type if you are using the TYPE addition. This can be a predefined ABAP type, a local type in the program, or a data type from the ABAP Dictionary. If you specify any of the generic elementary types c, n, p and x , any attributes that you fail to specify (field length, number of decimal places) are automatically filled with the default values. You cannot specify any other generic types.

        Any data object  recognized within the program at that point if you are using the LIKE addition. The line type adopts the fully-specified data type of the data object to which you refer. Except for within classes, you can still use the LIKE addition to refer to database tables and structures in the ABAP Dictionary (for compatibility reasons).

All of the lines in the internal table have the fully-specified technical attributes of the specified data type.

Key

You can specify the key key of an internal table as follows:

[UNIQUE|NON-UNIQUE] KEY col1 ... coln

In tables with a structured line type, all of the components col1 coln belong to the key as long as they are not internal tables or references, and do not contain internal tables or references. Key fields can be nested structures. The substructures are expanded component by component when you access the table using the key. The system follows the sequence of the key fields.

[UNIQUE|NON-UNIQUE] KEY table_line

If a table has an elementary line type (c, d, f, i, n, p, t, x), you can define the entire line as the key. If you try this for a table whose line type is itself a table, a syntax error occurs. If a table has a structured line type, it is possible to specify the entire line as the key. However, you should remember that this is often not suitable.

[UNIQUE|NON-UNIQUE] DEFAULT KEY

This declares the fields of the default key as the key fields. If you have a structured line type, the standard key is build from all columns of the internal table that have a character-type type (c, d, t, n, x, string, xstring). Internal tables with a nested row structure have a standard key built by linearization of the row structure. At elementary row types, the standard key is the row itself. Elementary tables with an internal table as row type have an empty standard key.

Specifying a key is optional. If you do not specify a key, the system defines a table type with an arbitrary key. You can only use this to define the types of field symbols  and the interface parameters of procedures . For exceptions, refer to Special Features of Standard Tables).

The optional additions UNIQUE or NON-UNIQUE determine whether the key is to be unique or non-unique, that is, whether the table can accept duplicate entries. If you do not specify UNIQUE or NON-UNIQUE for the key, the table type is generic in this respect. As such, it can only be used for specifying types. When you specify the table type simultaneously, you must note the following restrictions:

        You cannot use the UNIQUE addition for standard tables. The system always generates the NON-UNIQUE addition automatically.

        You must always specify the UNIQUE option when you create a hashed table.

Initial Memory Requirement

You can specify the initial amount of main memory assigned to an internal table object when you define the data type using the following addition:

INITIAL SIZE n

. This size does not belong to the data type of the internal table, and does not affect the type check. You can use the above addition to reserve memory space for n table lines when you declare the table object.

When this initial area is full, the system makes twice as much extra space available up to a limit of 8KB. Further memory areas of 12KB each are then allocated.

You can usually leave it to the system to work out the initial memory requirement. The first time you fill the table, little memory is used. The space occupied, depending on the line width, is 16 <= n<= 100.

It only makes sense to specify a concrete value of nif you can specify a precise number of table entries when you create the table and need to allocate exactly that amount of memory (exception: Appending table lines to ranked lists). This can be particularly important for deep-structured internal tables where the inner table only has a few entries (less than 5, for example).

To avoid excessive memory requests, large values for nare treated as follows: The possible maximum value for n results from 8 kilobyte divided by the row length. If you specify a larger value of n, the system calculates a new value so that ntimes the line width is around 12KB.

Example

TYPES: BEGIN OF line,
         column1 TYPE i,
         column2 TYPE i,
         column3 TYPE i,
       END OF LINE.

TYPES itab TYPE SORTED TABLE OF line WITH UNIQUE KEY column1.

The program defines a table type itab. It is a sorted table, with line type of the structure line and a unique key of the component column1.

Example

TYPES vector TYPE HASHED TABLE OF i WITH UNIQUE KEY table_line.

TYPES: BEGIN OF line,
         column1 TYPE i,
         column2 TYPE i,
         column3 TYPE i,
       END OF line.

TYPES itab TYPE SORTED TABLE OF line WITH UNIQUE KEY column1.

TYPES: BEGIN OF deepline,
         field  TYPE c,
         table1 TYPE vector,
         table2 TYPE itab,
       END OF deepline.

TYPES deeptable TYPE STANDARD TABLE OF deepline
                WITH DEFAULT KEY.

The program defines a table type vector with type hashed table, the elementary line type i and a unique key of the entire table line. The second table type is the same as in the previous example. The structure deepline contains the internal table as a component. The table type deeptable has the row type deepline. Therefore, the elements of this internal table are themselves internal tables. The key is the default key - in this case the column field. The key is non-unique, since the table is a standard table.

 

 

 

Leaving content frame