Anfang des Inhaltsbereichs

Drucktasten in der Drucktastenleiste Dokument im Navigationsbaum lokalisieren

In der Drucktastenleiste des Standard-GUI-Status des Selektionsbilds sind fünf Drucktasten mit den Funktionscodes FC01 bis FC05 vordefiniert, aber standardmäßig inaktiv. Sie können wie folgt während der Definition des Selektionsbilds aktiviert werden:

SELECTION-SCREEN FUNCTION KEY <i>.

Die Numerierung <i> muß zwischen 1 und 5 liegen. Die einzelnen Funktionstexte müssen vor dem Aufruf des Selektionsbilds den Komponenten FUNCTXT_0<i> der Struktur SSCRFIELDS zugewiesen werden. Diese Struktur muß mit der TABLES-Anweisung als Schnittstellen-Arbeitsbereich deklariert werden.

Wählt der Benutzer eine dieser Taste aus, löst die Laufzeitumgebung das Ereignis AT SELECTION-SCREEN aus und der Funktionscode FC0<i> wird in die Komponente UCOMM der Struktur SSCRFIELDS gestellt.

Nach Bearbeitung des Ereignisblocks zu AT SELECTION-SCREEN kehrt das System zur Anzeige des Selektionsbilds zurück. Um die Selektionsbildverarbeitung zu verlassen und mit der Programmausführung fortzufahren, kann nur Ausführen (F8) ausgewählt werden. Die Drucktasten in der Drucktastenleiste können daher eher für dynamische Modifikationen des Selektionsbilds als zur Programmsteuerung eingesetzt werden.

Beispiel

REPORT demo_sel_screen_function_key.

TABLES sscrfields.

PARAMETERS: p_carrid TYPE s_carr_id,
            p_cityfr TYPE s_from_cit.

SELECTION-SCREEN: FUNCTION KEY 1,
                  FUNCTION KEY 2.

INITIALIZATION.
  sscrfields-functxt_01 = 'LH'.
  sscrfields-functxt_02 = 'UA'.

AT SELECTION-SCREEN.
  CASE sscrfields-ucomm.
      WHEN'FC01'.
      p_carrid = 'LH'.
      p_cityfr = 'Frankfurt'.
    WHEN 'FC02'.
      p_carrid = 'UA'.
      p_cityfr = 'Chicago'.
  ENDCASE.

START-OF-SELECTION.
  WRITE / 'START-OF-SELECTION'.

Es wird ein Standardselektionsbild mit zwei Parametern definiert. In der Drucktastenleiste werden zwei Drucktasten mit den Texten LH und UA versehen und aktiviert.

Wenn der Benutzer eine der Tasten anklickt, wird das Ereignis AT SELECTION-SCREEN ausgelöst und dort die Eingabefelder entsprechend vorbelegt.

 

 

Ende des Inhaltsbereichs