Anfang des Inhaltsbereichs

Ausführen und Drucken Dokument im Navigationsbaum lokalisieren

Die einfachste Methode, eine Liste während der Erstellung zu drucken, besteht darin, daß der Benutzer auf dem Selektionsbild des ausführbaren Programms (Report) Ausführen und Drucken wählt. Der Benutzer hat also die Wahl sich die Liste auf dem Bildschirm anzeigen zu lassen (Auswahl von Ausführen) oder sie direkt ohne Anzeige zu drucken (Auswahl von Ausführen und Drucken).

Wenn der Benutzer Ausführen und Drucken auf dem Selektionsbild des ausführbaren Programms (Report) wählt, erscheint vor der Erstellung der Liste das Druckparameter-Dialogfenster. Dort trägt der Benutzer die Druckparameter ein. Mit dem Funktionsbaustein SET_PRINT_PARAMETERS können Sie Vorgabewerte für dieses Dialogfenster setzen.

Als Konsequenz müssen Sie die Liste so programmieren, daß sie sowohl für die Ausgabe auf dem Bildschirm als auch für die Ausgabe auf den Drucker geeignet ist. Geben Sie deshalb keine Seitenbreiten größer als 132 durch den Zusatz LINE-SIZE und am besten überhaupt keine Seitenlänge durch den Zusatz LINE-COUNT der REPORT-Anweisung an.

Über Ausführen und Drucken ist nur die Grundliste des ausführbaren Programms (Report) druckbar. Verzweigungslisten, die während interaktiver Ereignisse auf der angezeigten Liste erstellt werden, müssen Sie über NEW-PAGE PRINT ON drucken (siehe Programmgesteuertes Drucken).

Beispiel

REPORT demo_list_print_1 NO STANDARD PAGE HEADING LINE-COUNT 0(2).

PARAMETERS p TYPE i.

INITIALIZATION.

  CALL FUNCTION 'SET_PRINT_PARAMETERS'
       EXPORTING
            archive_mode   = '3'
            copies         = '5'
            department     = 'BASIS'
            destination    = 'LT50'
            expiration     = '0'
            immediately    = 'X'
            layout         = 'X_65_132'
            line_count     = 54
            line_size      = 20
            list_name      = 'Test'
            list_text      = 'Test for User''s Guide'
            new_list_id    = 'X'
            receiver       = 'KELLERH'
            release        = ' '
            sap_cover_page = 'X'.

START-OF-SELECTION.

  DO p TIMES.
    WRITE / sy-index.
  ENDDO.

TOP-OF-PAGE.

  WRITE: 'Page', sy-pagno.
  ULINE.

END-OF-PAGE.
  ULINE.
  WRITE: 'End of', sy-pagno.

Nach dem Start dieses Programms kann der Benutzer den Parameter P auf dem Selektionsbild eingeben (z.B. 100) und Ausführen und Drucken wählen. Danach erscheint folgendes Dialogfenster:

Diese Grafik wird im zugehörigen Text erklärt

Der Funktionsbaustein SET_PRINT_PARAMETERS füllt die Eingabefelder mit Vorgabewerten. Durch den Gebrauch des Funktionsbausteins ist das Feld Zeilen eingabebereit, obwohl der Zusatz LINE-COUNT in der REPORT-Anweisung verwendet wird. Dieser Zusatz dient hier nur zur Reservierung von Platz für zwei Fußzeilen.

Nach der Auswahl Drucken auf dem Druckparameter-Dialogfenster erscheint das Dialogfenster Archiv-Parameter, da über den Importparameter ARCHIV_MODE der Archivierungsmodus auf Drucken und Archivieren gesetzt wird.

Falls der Benutzer auf dem Selektionsbild für den Parameter P die Zahl 100 eingibt, erzeugt das System ein SAP-Deckblatt und zwei Druckseiten, die wie folgt aussehen.

Erste Seite:

Page     1
--------------------
         1
         2
         3

   .....

        49
        50
--------------------
End of     1

Zweite Seite:

Page     2
--------------------
        58
        59
        60

   .....

        99
       100
--------------------
End of     2

Auf jeder Seite können inklusive Seitenkopf und -fuß bis zu 54 Zeilen ausgegeben werden. Beachten Sie, daß der Seitenvorschub und der Aufbau von Seitenkopf und -fuß genauso erfolgt, wie unter Komplexe Listen erstellen beschrieben.

Wählt der Benutzer auf dem Selektionsbild Ausführen statt Ausführen und Drucken, wird die Liste einseitig und ohne Seitenfuß auf dem Ausgabebild dargestellt.

 

 

Ende des Inhaltsbereichs