対象領域の指定 

INTO 句は、SELECT 句から選択したデータを書き込む対象領域を定義します。適切な対象領域は、データ型が SELECT 句の選択データと互換性があるか変換可能な変数です。

SELECT 句は、以下のように対象領域のデータ型を決定します。

ｷ        SELECT 句での <行> 指定によって、対象領域の範囲、つまりフラット構造かテーブル構造かが決定されます。

ｷ        SELECT 句の <cols> 指定によって、対象領域の構造 ( 行データ型) が決定されます。

単一の行を選択すると、対象領域はフラットになります。複数の行を選択すると、対象領域はテーブル構造またはフラット構造になります。対象領域がフラットの場合は、SELECT ループを使用する必要があります。

すべての列を選択すると、対象領域は構造となるか構造への変換が可能になります。個々の列を選択すると、対象領域は構造のコンポーネントまたは単一の項目になります。 

SELECT 句での選択の基本データ型は ディクショナリのデータ型です。ディクショナリ型は、対象領域の対応する基本コンポーネントの ABAP データ型に変換可能なものでなければなりません。データ型のテーブルについては、ABAP ディクショナリのデータ型 を参照してください。

フラット作業領域の指定

読込元が単一行か複数行かにかかわらず、フラット作業領域を指定することができます。データをフラット作業領域に読み込むには、INTO 句で以下を使用します。

SELECT ...INTO [CORRESPONDING FIELDS OF] <wa> ...

少なくとも読み込まれる行のサイズ以上の対象領域が必要です。ただし、これがデータ型に対する唯一の制限です。データ型の選択は、読み込んだ列が <wa> でアドレス指定されるための SELECT 句の指定にもとづいて行います。

SELECT 句のアスタリスク (*) を指定する ( すべての列を選択する) と、データベーステーブルの構造にしたがって、データは作業領域へ左から右に転送されます。この場合は、<wa> の構造は関係ありません。SELECT 命令の後ろの各列の値をアドレス指定できるようにするためには、作業領域がデータベーステーブルと同じ構造を持つ必要があります。 

SELECT 句で個別の列または集合式を指定すると、作業領域の構造にしたがって、列は作業領域へ左から右に転送されます。

データを <wa> に読み込むと、前の内容が上書きされます。しかし、SELECT 命令の影響を受けない <wa> のコンポーネントは、前の値を保持します。

作業領域が構成されている場合は、CORRESPONDING FIELDS オプションを使用することができます。このオプションでは、データベーステーブルと作業領域で同一名称の項目の内容だけが転送されます。これには、選択において指定したエイリアス列名が含まれます。INTO 句の CORRESPONDING FIELDS オプションを使って作業をしても、データベースから読み込まれるデータの量は制限されず、結果セットから ABAP プログラムに読み込まれるデータの量だけが制限されます。読み込まれる列の数を制限する唯一の方法は SELECT 句にあります。

アスタリスク (*) オプションを使用して、SELECT 句の単一データベーステーブル<dbtab> の列をすべて読み込む場合は、INTO 句が空白になることがあります。そのため、SELECT 命令はデフォルトのデータを、データベーステーブル自体と同じ <dbtab> という名前を付けてテーブル作業領域に書き込みます。このテーブル作業領域は TABLES 命令を使って宣言しなければなりません。リリース 4.0 以前では、このテーブル作業領域がないとデータベーステーブルからデータを読み込むことができなかったため、暗黙の作業領域として頻繁に使用されていました。現在でも、テーブル作業領域はインタフェース作業領域として有効ですが、SELECT 命令の作業領域として使用することはできません。ヘッダ行のない内部テーブルと同様に、ソース領域と対象領域に別々の名前を付けることでプログラムがわかりやすくなりました。

内部テーブルの指定

データベーステーブルの複数の行を読み込むときは、その行を内部テーブルに置くことができます。この場合は、INTO 句で 以下を使用します。

SELECT ...INTO|APPENDING [CORRESPONDING FIELDS OF] TABLE <itab>
                          [PACKAGE SIZE <n>] ...

同じことが、<itab> の行データ型、データベーステーブルの行のデータがテーブル行に割り当てられる方法、およびフラット作業領域に対する CORRESPONDING FIELDS オプションにも適用されます( 上記参照) 。

内部テーブルには、選択したすべての行が書き込まれます。INTO を使用すると、テーブル内のすべての既存行が削除されます。APPENDING を使用すると、既存の内部テーブル <itab> に新しい行が追加されます。APPENDING により、テーブルデータ型に適応して行が内部テーブルに追加されます。選択に影響されない内部テーブル内の項目には、初期値が書き込まれます。 

PACKAGE SIZE オプションを使用すると、選択した行は内部テーブルに一度に書き込まれず、パケット単位で書き込まれます。内部テーブルに 1 つずつ書き込まれる、<n> 行のパケットを定義することができます。INTO を使用すると、各パケットが前のパケットを置換します。APPENDING を使用すると、パケットは 1 つずつ挿入されます。これは、ENDSELECT で終了するループでのみ可能です。SELECT ループの外では、内部テーブルの内容が決定していません。ループ内の選択行を処理する必要があります。

単一項目の指定

SELECT 句のデータベーステーブルの単一列または集合式を指定する場合は、SELECT ループの個別エントリまたは複数エントリの単一項目にデータを読み込むことができます。データを単一項目に読み込むには、INTO 句で以下を使用します。

SELECT ...INTO (<f₁>, <f₂>, ...). ...

SELECT 句の項目一覧で指定されたのと同数の個別項目 <f_i> を指定する必要があります。SELECT 句の項目は、INTO 句の一覧内の項目に左から右へ割り当てられます。

SELECT 句で個別項目を指定する場合は、INTO 句の項目一覧を使用する必要はありません。代わりにCORRESPONDING FIELDS オプションを使用して、データをフラット作業領域または内部テーブルに読み込むこともできます。その場合、対象領域は、SELECT 句の一覧と同数のエレメントを含む必要はありません。

例

対象領域としてのフラット構造

DATA WA TYPE SPFLI.

SELECT *
INTO   WA
FROM   SPFLI.

   WRITE: / WA-CARRID ...

ENDSELECT.

この例では、SELECT ループの対象領域のように、データベーステーブル SPFLI と同じデータ型のフラット構造を使用しています。ループ内では、個別の列の内容をアドレス指定することができます。

DATA SPFLI TYPE SPFLI.

SELECT *
FROM   SPFLI.

   WRITE: / SPFLI-CARRID ...

ENDSELECT.

この例では、構造 SPFLI を、読み込むデータベーステーブルと同じ名前で宣言しています。この構造は、SELECT ループの対象領域として黙示的に使用されています。同じ名称のため、ここではデータベーステーブル自体ではなく ABAP データオブジェクトで作業しているという事実を見過ごしてしまいがちです。

 

対象領域としての内部テーブル

DATA: BEGIN OF WA,
         CARRID   TYPE SPFLI-CARRID,
         CONNID   TYPE SPFLI-CONNID,
         CITYFROM TYPE SPFLI-CITYFROM,
         CITYTO   TYPE SPFLI-CITYTO,
      END OF WA,
      ITAB LIKE SORTED TABLE OF WA
                WITH NON-UNIQUE KEY CITYFROM CITYTO.

SELECT CARRID CONNID CITYFROM CITYTO
INTO   CORRESPONDING FIELDS OF TABLE ITAB
FROM   SPFLI.

IF SY-SUBRC EQ 0.
  WRITE: / SY-DBCNT, 'Connections'.
   SKIP.
   LOOP AT ITAB INTO WA.
     WRITE: / WA-CARRID, WA-CONNID, WA-CITYFROM, WA-CITYTO.
   ENDLOOP.
ENDIF.

出力結果:

対象領域は、データベーステーブル SPFLI と同じ名称およびデータ型の 4 つの項目を含むソートテーブル ITAB です。プログラムは CORRESPONDING FIELDS オプションを使用して、SELECT 句からの列を内部テーブルの該当項目に置きます。ITAB はソートテーブルのため、データは ITAB のテーブルキーでソートされたテーブルに挿入されます。

 

パケットの内部テーブルへの読込

DATA: WA   TYPE SPFLI,
      ITAB TYPE SORTED TABLE OF SPFLI
                WITH UNIQUE KEY CARRID CONNID.

SELECT CARRID CONNID
FROM   SPFLI
INTO   CORRESPONDING FIELDS OF TABLE ITAB
       PACKAGE SIZE 3.

   LOOP AT ITAB INTO WA.
     WRITE: / WA-CARRID, WA-CONNID.
   ENDLOOP.

   SKIP 1.

ENDSELECT.

出力結果:

例では、3 行のパケットをそれぞれソートテーブル ITAB に読み込みます。SELECT ループの各パスでは、内部テーブルに異なるソート内容があります。

INTO ではなく APPENDING を使用する場合は、一覧は以下のようになります。

各ループパスでは、新しいパケットが内部テーブルにソートされます。

 

対象領域としての単一項目

DATA:   AVERAGE TYPE P DECIMALS 2,
        SUM     TYPE P DECIMALS 2.

SELECT AVG( LUGGWEIGHT ) SUM( LUGGWEIGHT )
INTO   (AVERAGE, SUM)
FROM   SBOOK.

WRITE: / 'Average:', AVERAGE,
       / 'Sum    :', SUM.

出力結果:

SELECT 句には、データベーステーブル SBOOK の項目 LUGGWEIGHT の平均および合計を計算するための 2 つの集合式が含まれます。対象項目は、AVERAGE および SUM と呼ばれます。

 

エイリアスの使用:

DATA: BEGIN OF LUGGAGE,
        AVERAGE TYPE P DECIMALS 2,
        SUM     TYPE P DECIMALS 2,
      END OF LUGGAGE.

SELECT AVG( LUGGWEIGHT ) AS AVERAGE SUM( LUGGWEIGHT ) AS SUM
INTO   CORRESPONDING FIELDS OF LUGGAGE
FROM   SBOOK.

WRITE: / 'Average:', LUGGAGE-AVERAGE,
       / 'Sum    :', LUGGAGE-SUM.

出力結果:

この例は前の例と同じ効果があります。唯一の違いは、構造が個別項目ではなく対象領域として使用され、構造コンポーネントの名称がエイリアスとして SELECT 句で使用されている点です。