ABAP オブジェクトのメソッド - 例 

以下の例では、ABAP オブジェクトのメソッドを宣言、実装、使用する方法を示します。

概要

この例では、3 つのクラス C_TEAM 、C_BIKER 、C_BICYCLE を使用します。ユーザ ( プログラム) は、クラス C_TEAM のオブジェクトを登録することができます。選択画面で、クラス C_TEAM から各チームのメンバ数を指定するように指示されます。 

クラス C_TEAM 内の各オブジェクトは、クラスC_BIKER のインスタンスをチーム内のメンバと同じ数だけ登録することができます。クラス C_BIKER の各インスタンスは、クラス C_BICYCLE のインスタンスを登録します。

クラス C_TEAM の各インスタンスは、対話式一覧を介してプログラムユーザと通信することができます。プログラムユーザは、アクションの対象となる個々のチームメンバを選択することができます。クラス C_BIKER のインスタンスによって、プログラムユーザは追加の選択画面でアクションを選択することができます。

制約事項

一覧処理に使用される ABAP 命令は、ABAP オブジェクトでまだ完全に利用可能となっていません。ただし、単純なテスト出力を生成する場合は、以下の命令を使用することができます。

ｷ         WRITE [AT] /<offset>(<length>) <f>

ｷ         ULINE

ｷ         SKIP

ｷ         NEW-LINE

注記: 書式設定と対話式一覧機能の現状の動作は保証されていません。今後のリリースで、互換性のない変更が行われる可能性があります。

宣言

 

この例は、ローカルクラスを使って実装されます。これは、選択画面が ABAP プログラムに属していて、グローバルクラスで定義または呼び出すことができないためです。以下に示すのは、2 つの選択画面と 3 つのクラスの定義です。

*******************************************************************
* グローバル選択画面
*******************************************************************

SELECTION-SCREEN BEGIN OF: SCREEN 100 TITLE TIT1, LINE.
   PARAMETERS MEMBERS TYPE I DEFAULT 10.
SELECTION-SCREEN END OF: LINE, SCREEN 100.

*------------------------------------------------------------------

SELECTION-SCREEN BEGIN OF SCREEN 200 TITLE TIT2.
   PARAMETERS: DRIVE    RADIOBUTTON GROUP ACTN,
              STOP     RADIOBUTTON GROUP ACTN,
              GEARUP   RADIOBUTTON GROUP ACTN,
              GEARDOWN RADIOBUTTON GROUP ACTN.
SELECTION-SCREEN END OF SCREEN 200.

*******************************************************************
* クラス定義
*******************************************************************

CLASS: C_BIKER DEFINITION DEFERRED,
       C_BICYCLE DEFINITION DEFERRED.

*------------------------------------------------------------------

CLASS C_TEAM DEFINITION.

   PUBLIC SECTION.

   TYPES: BIKER_REF TYPE REF TO C_BIKER,
         BIKER_REF_TAB TYPE STANDARD TABLE OF BIKER_REF
                                           WITH DEFAULT KEY,

         BEGIN OF STATUS_LINE_TYPE,
           FLAG(1)  TYPE C,
           TEXT1(5) TYPE C,
           ID       TYPE I,
           TEXT2(7) TYPE C,
           TEXT3(6) TYPE C,
           GEAR     TYPE I,
           TEXT4(7) TYPE C,
           SPEED    TYPE I,
         END OF STATUS_LINE_TYPE.

   CLASS-METHODS: CLASS_CONSTRUCTOR.

   METHODS: CONSTRUCTOR,
           CREATE_TEAM,
           SELECTION,
           EXECUTION.

   PRIVATE SECTION.

   CLASS-DATA: TEAM_MEMBERS TYPE I,
              COUNTER TYPE I.

   DATA: ID TYPE I,
        STATUS_LINE TYPE STATUS_LINE_TYPE,
        STATUS_LIST TYPE SORTED TABLE OF STATUS_LINE_TYPE
                                      WITH UNIQUE KEY ID,

         BIKER_TAB TYPE BIKER_REF_TAB,
        BIKER_SELECTION LIKE BIKER_TAB,
        BIKER LIKE LINE OF BIKER_TAB.

   METHODS: WRITE_LIST.

ENDCLASS.

*------------------------------------------------------------------

CLASS C_BIKER DEFINITION.

   PUBLIC SECTION.

   METHODS: CONSTRUCTOR IMPORTING TEAM_ID TYPE I MEMBERS TYPE I,
           SELECT_ACTION,
           STATUS_LINE EXPORTING LINE
                       TYPE C_TEAM=>STATUS_LINE_TYPE.

   PRIVATE SECTION.

   CLASS-DATA COUNTER TYPE I.

   DATA: ID TYPE I,
        BIKE TYPE REF TO C_BICYCLE,
        GEAR_STATUS  TYPE I VALUE 1,
        SPEED_STATUS TYPE I VALUE 0.

   METHODS BIKER_ACTION IMPORTING ACTION TYPE I.

ENDCLASS.

*------------------------------------------------------------------

CLASS C_BICYCLE DEFINITION.

   PUBLIC SECTION.

   METHODS: DRIVE EXPORTING VELOCITY TYPE I,
           STOP  EXPORTING VELOCITY TYPE I,
           CHANGE_GEAR IMPORTING CHANGE TYPE I
                       RETURNING VALUE(GEAR) TYPE I
                       EXCEPTIONS GEAR_MIN GEAR_MAX.

   PRIVATE SECTION.

   DATA: SPEED TYPE I,
        GEAR  TYPE I VALUE 1.

   CONSTANTS: MAX_GEAR TYPE I VALUE 18,
             MIN_GEAR TYPE I VALUE 1.

ENDCLASS.

*******************************************************************

3 つのクラスには、いずれもパブリック属性がないので注意してください。クラスの状態は、それぞれのメソッドによってのみ変更することができます。クラス C_TEAM には、静的コンストラクタ CLASS_CONSTRUCTOR が含まれています。C_TEAM と C_BIKER には、インスタンスコンストラクタが含まれています。

実装

クラスの実装部分には、対応する宣言部分で宣言されたすべてのメソッドの実装が含まれています。メソッドのインタフェースは、すでに宣言で定義されています。実装では、インタフェースパラメータがローカルデータのように動作します。

クラス C_TEAM のメソッド

以下に示すメソッドは、次のセクションで実装されます。

CLASS C_TEAM IMPLEMENTATION.

...

ENDCLASS.

CLASS_CONSTRUCTOR

  METHOD CLASS_CONSTRUCTOR.
     TIT1 = 'Team members ?'.
     CALL SELECTION-SCREEN 100 STARTING AT 5 3.
    IF SY-SUBRC NE 0.
      LEAVE PROGRAM.
     ELSE.
       TEAM_MEMBERS = MEMBERS.
     ENDIF.
   ENDMETHOD.

クラス C_TEAM がプログラムで最初に使用される前に、静的コンストラクタが実行されます。このコンストラクタによって、選択画面 100 が呼び出され、静的属性 TEAM_MEMBERS がプログラムユーザによって入力された値に設定されます。この属性の値は、クラス C_TEAM のすべてのインスタンスで同じです。

 

CONSTRUCTOR

   METHOD CONSTRUCTOR.
     COUNTER = COUNTER + 1.
    ID = COUNTER.
   ENDMETHOD.

クラス C_TEAM のインスタンスが登録されるたびに、インスタンスコンストラクタが実行されます。それを使用して C_TEAM のインスタンスの数が静的属性 COUNTER でカウントされ、対応する数値がクラスの各インスタンスのインスタンス属性 ID に割り当てられます。

CREATE_TEAM

   METHOD CREATE_TEAM.
     DO TEAM_MEMBERS TIMES.
       CREATE OBJECT BIKER EXPORTING TEAM_ID = ID
                                    MEMBERS = TEAM_MEMBERS.
       APPEND BIKER TO BIKER_TAB.
      CALL METHOD BIKER->STATUS_LINE IMPORTING LINE = STATUS_LINE.
       APPEND STATUS_LINE TO STATUS_LIST.
     ENDDO.
   ENDMETHOD.

パブリックインスタンスメソッド CREATE_TEAM は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドは、クラス C_BIKER のインスタンスを登録するために使用され、その際にクラス C_TEAM のプライベート参照変数 BIKER が使用されます。CREATE OBJECT 命令では、クラス C_BIKER のインスタンスコンストラクタの入力パラメータを両方とも渡す必要があります。新たに登録されたインスタンスへの参照は、プライベート内部テーブル BIKER_TAB に挿入されます。メソッドが実行されると、この内部テーブルの各行にクラス C_BIKER のインスタンスへの参照が格納されます。これらの参照は、クラス C_TEAM の中でのみ可視となります。外部ユーザは、クラス C_BIKER のオブジェクトをアドレスすることができません。

CREATE_TEAM は、新たに登録されたオブジェクトごとにメソッド STATUS_LINE を呼び出し、作業領域STATUS_LINE を使用してその出力パラメータ LINE をプライベート内部テーブルSTATUS_LIST にアペンドします。

SELECTION

   METHOD SELECTION.
     CLEAR BIKER_SELECTION.
     DO.
      READ LINE SY-INDEX.
       IF SY-SUBRC <> 0. EXIT. ENDIF.
      IF SY-LISEL+0(1) = 'X'.
         READ TABLE BIKER_TAB INTO BIKER INDEX SY-INDEX.
         APPEND BIKER TO BIKER_SELECTION.
       ENDIF.
     ENDDO.
     CALL METHOD WRITE_LIST.
   ENDMETHOD.

パブリックインスタンスメソッド SELECTION は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドによって、現在の一覧で 1 列目のチェックボックスが選択されているすべての行が選択されます。これらの行については、対応する参照変数がテーブルBIKER_TAB から追加のプライベート内部テーブル BIKER_SELECTION にコピーされます。そのあとに、一覧を表示するプライベートメソッド WRITE_LIST が SELECTION によって呼び出されます。 

EXECUTION

   METHOD EXECUTION.
     CHECK NOT BIKER_SELECTION IS INITIAL.
     LOOP AT BIKER_SELECTION INTO BIKER.
       CALL METHOD BIKER->SELECT_ACTION.
       CALL METHOD BIKER->STATUS_LINE IMPORTING LINE = STATUS_LINE.
       MODIFY TABLE STATUS_LIST FROM STATUS_LINE.
     ENDLOOP.
     CALL METHOD WRITE_LIST.
   ENDMETHOD.

パブリックインスタンスメソッド EXECUTION は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドは、テーブルBIKER_SELECTION に参照が存在するクラス C_BIKER のインスタンスごとに、2 つのメソッド SELECT_ACTION と STATUS_LINE を呼び出します。作業領域 STATUS_LINE のコンポーネント ID と同じキーを持つテーブルSTATUS_LIST の行が、プライベートメソッド WRITE_LIST によって上書きされ、表示されます。

WRITE_LIST

   METHOD WRITE_LIST.
     SET TITLEBAR 'TIT'.
     SY-LSIND = 0.
    SKIP TO LINE 1.
    POSITION 1.
    LOOP AT STATUS_LIST INTO STATUS_LINE.
       WRITE: / STATUS_LINE-FLAG AS CHECKBOX,
               STATUS_LINE-TEXT1,
               STATUS_LINE-ID,
               STATUS_LINE-TEXT2,
               STATUS_LINE-TEXT3,
               STATUS_LINE-GEAR,
               STATUS_LINE-TEXT4,
               STATUS_LINE-SPEED.
     ENDLOOP.
   ENDMETHOD.

プライベートインスタンスメソッド WRITE_LIST は、クラス C_TEAM のメソッドからしか呼び出すことができません。このメソッドは、プログラムの基本一覧(SY_LSIND = 0) 上にプライベート内部テーブル STATUS_LIST を表示するために使用されます。

クラス C_BIKER のメソッド

以下に示すメソッドは、次のセクション内で実装されます。

CLASS C_BIKER IMPLEMENTATION.

...

ENDCLASS.

CONSTRUCTOR

   METHOD CONSTRUCTOR.
     COUNTER = COUNTER + 1.
    ID = COUNTER - MEMBERS * ( TEAM_ID - 1).
     CREATE OBJECT BIKE.
   ENDMETHOD.

クラス C_BIKER のインスタンスが登録されるたびに、インスタンスコンストラクタが実行されます。それを使用して、C_BIKER のインスタンスの数が静的属性 COUNTER でカウントされ、対応する数値がクラスの各インスタンスのインスタンス属性 ID に割り当てられます。このコンストラクタには、2 つの入力パラメータ TEAM_ID および MEMBERS があります。これらのパラメータは、C_BIKER のインスタンスを登録する際に CREATE OBJECT 命令で渡す必要があります。

また、このインスタンスコンストラクタによって、クラス C_BIKER の新しいインスタンスごとに、クラスC_BICYCLE のインスタンスが登録されます。C_BIKER の各インスタンスのプライベート参照変数 BIKE に設定されている参照は、対応するクラスC_BICYCLE のインスタンスを指しています。外部ユーザは、クラス C_BICYCLE のこれらのインスタンスをアドレスすることができません。

SELECT_ACTION

   METHOD SELECT_ACTION.
     DATA ACTIVITY TYPE I.
    TIT2 = 'Select action for BIKE'.
     TIT2+24(3) = ID.
    CALL SELECTION-SCREEN 200 STARTING AT 5 15.
    CHECK NOT SY-SUBRC GT 0.
    IF GEARUP = 'X' OR GEARDOWN = 'X'.
       IF GEARUP = 'X'.
         ACTIVITY = 1.
      ELSEIF GEARDOWN = 'X'.
         ACTIVITY = -1.
      ENDIF.
     ELSEIF DRIVE = 'X'.
       ACTIVITY = 2.
    ELSEIF STOP = 'X'.
       ACTIVITY = 3.
    ENDIF.
     CALL METHOD BIKER_ACTION( ACTIVITY).
   ENDMETHOD.

パブリックインスタンスメソッド SELECT_ACTION は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドは、選択画面 200 を呼び出し、ユーザの入力を分析します。そのあとに、同じクラスのプライベートメソッド BIKER_ACTION を呼び出します。このメソッドの呼出では、短い形式を使って実パラメータ ACTIVITY が仮パラメータ ACTION に渡されます。

BIKER_ACTION

   METHOD BIKER_ACTION.
     CASE ACTION.
       WHEN -1 OR 1.
        CALL METHOD BIKE->CHANGE_GEAR
                          EXPORTING CHANGE = ACTION
                          RECEIVING GEAR = GEAR_STATUS
                          EXCEPTIONS GEAR_MAX = 1
                                     GEAR_MIN = 2.
        CASE SY-SUBRC.
           WHEN 1.
            MESSAGE I315(AT) WITH 'BIKE' ID
                                  ' is already at maximal gear!'.
           WHEN 2.
            MESSAGE I315(AT) WITH 'BIKE' ID
                                  ' is already at minimal gear!'.
         ENDCASE.
       WHEN 2.
        CALL METHOD BIKE->DRIVE IMPORTING VELOCITY = SPEED_STATUS.
       WHEN 3.
        CALL METHOD BIKE->STOP IMPORTING VELOCITY = SPEED_STATUS.
     ENDCASE.
   ENDMETHOD.

プライベートインスタンスメソッド BIKER_ACTION は、クラスC_BIKER のメソッドからしか呼び出すことができません。このメソッドは、参照変数 BIKE 内の参照が指しているクラス C_BICYCLE のインスタンス内で、入力パラメータ ACTION の値に従って他のメソッドを呼び出します。 

STATUS_LINE

  METHOD STATUS_LINE.
    LINE-FLAG = SPACE.
     LINE-TEXT1 = 'Biker'.
     LINE-ID = ID.
    LINE-TEXT2 = 'Status:'.
     LINE-TEXT3 = 'Gear = '.
     LINE-GEAR  = GEAR_STATUS.
     LINE-TEXT4 = 'Speed = '.
     LINE-SPEED = SPEED_STATUS.
   ENDMETHOD.

パブリックインスタンスメソッド STATUS_LINE は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドは、構造化された出力パラメータ LINE に、対応するインスタンスの現在の属性値を書き込みます。

クラスC_BICYCLE のメソッド

以下に示すメソッドは、次のセクションで実装されます。

CLASS C_BICYCLE IMPLEMENTATION.

...

ENDCLASS.

DRIVE

   METHOD DRIVE.
     SPEED = SPEED  + GEAR * 10.
    VELOCITY = SPEED.
   ENDMETHOD.

パブリックインスタンスメソッド DRIVE は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドは、プライベート属性 SPEED の値を変更し、出力パラメータ VELOCITY を使ってその値を呼出元に渡します。

STOP

   METHOD STOP.
     SPEED = 0.
    VELOCITY = SPEED.
   ENDMETHOD.

パブリックインスタンスメソッド STOP は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドは、プライベート属性 SPEED の値を変更し、出力パラメータ VELOCITY を使ってその値を呼出元に渡します。

CHANGE_GEAR

   METHOD CHANGE_GEAR.
     GEAR = ME->GEAR.
     GEAR = GEAR + CHANGE.
     IF GEAR GT MAX_GEAR.
       GEAR = MAX_GEAR.
       RAISE GEAR_MAX.
    ELSEIF GEAR LT MIN_GEAR.
       GEAR = MIN_GEAR.
       RAISE GEAR_MIN.
    ENDIF.
     ME->GEAR = GEAR.
   ENDMETHOD.

パブリックインスタンスメソッド CHANGE_GEAR は、クラスのインスタンスへの参照が設定された参照変数を含んでいるクラスのすべてのユーザが呼び出すことができます。このメソッドは、プライベート属性 GEAR の値を変更します。同じ名称の仮パラメータによってメソッド内の属性が不明瞭化されるため、属性は自己参照 ME->GEAR を使ってアドレスする必要があります。

 

プログラムでのクラスの使用

次のプログラムは、上記のクラスがプログラムでどのように使用されるかを示しています。このプログラムには、選択画面とローカルクラスの宣言、およびメソッドの実装も組み込む必要があります。 

REPORT OO_METHODS_DEMO NO STANDARD PAGE HEADING.

*******************************************************************
* 宣言と実装
*******************************************************************

...

*******************************************************************
* グローバルプログラムデータ
*******************************************************************

TYPES TEAM TYPE REF TO C_TEAM.

DATA: TEAM_BLUE  TYPE TEAM,
      TEAM_GREEN TYPE TEAM,
      TEAM_RED   TYPE TEAM.

DATA  COLOR(5).

*******************************************************************
* プログラムイベント
*******************************************************************

START-OF-SELECTION.

  CREATE OBJECT: TEAM_BLUE,
                 TEAM_GREEN,
                 TEAM_RED.

   CALL METHOD: TEAM_BLUE->CREATE_TEAM,
               TEAM_GREEN->CREATE_TEAM,
               TEAM_RED->CREATE_TEAM.

   SET PF-STATUS 'TEAMLIST'.

   WRITE '                   Select a team!             ' COLOR = 2.

*------------------------------------------------------------------

AT USER-COMMAND.
   CASE SY-UCOMM.
     WHEN 'TEAM_BLUE'.
       COLOR = 'BLUE '.
       FORMAT COLOR = 1 INTENSIFIED ON INVERSE ON.
       CALL METHOD TEAM_BLUE->SELECTION.
     WHEN 'TEAM_GREEN'.
       COLOR = 'GREEN'.
       FORMAT COLOR = 5 INTENSIFIED ON INVERSE ON.
       CALL METHOD TEAM_GREEN->SELECTION.
     WHEN 'TEAM_RED'.
       COLOR = 'RED '.
       FORMAT COLOR = 6 INTENSIFIED ON INVERSE ON.
       CALL METHOD TEAM_RED->SELECTION.
     WHEN 'EXECUTION'.
       CASE COLOR.
         WHEN 'BLUE '.
           FORMAT COLOR = 1 INTENSIFIED ON INVERSE ON.
           CALL METHOD TEAM_BLUE->SELECTION.
           CALL METHOD TEAM_BLUE->EXECUTION.
         WHEN 'GREEN'.
           FORMAT COLOR = 5 INTENSIFIED ON INVERSE ON.
           CALL METHOD TEAM_GREEN->SELECTION.
           CALL METHOD TEAM_GREEN->EXECUTION.
         WHEN 'RED '.
           FORMAT COLOR = 6 INTENSIFIED ON INVERSE ON.
           CALL METHOD TEAM_RED->SELECTION.
           CALL METHOD TEAM_RED->EXECUTION.
       ENDCASE.
   ENDCASE.

*******************************************************************

プログラムでは、クラス C_TEAM を参照する 3 つのクラス参照変数が使用されています。このプログラムによってクラスから 3 つのオブジェクトが登録され、それらのオブジェクトを参照変数内の参照が指すようになります。各オブジェクトで、メソッドCREATE_TEAM が呼び出されます。最初のオブジェクトが登録される前に、クラス C_TEAM のメソッド CLASS_CONSTRUCTOR が実行されます。基本一覧のステータスTEAMLIST によって、ユーザは次の 4 つの機能から 1 つを選択することができます。

ユーザが機能を選択すると、その選択に応じて C_TEAM の 3 つのインスタンスのいずれかでイベントAT USER-COMMAND がトリガされ、パブリックメソッドが呼び出されます。ユーザは、ステータス一覧の対応する行を選択することで、オブジェクトの状態を変更することができます。