内部テーブルへのバインド 

ABAP 標準内部テーブルは JavaScript では、定義済みプロキシクラス SAPAbapItabClass のプロキシオブジェクトとしてマップされます。プロキシクラスは、配列を実装します。JavaScript 参照には、BIND メソッドの NAME_PROP パラメータを使用して大文字小文字を区別する名称を指定できます。配列エレメントのカウントは、インデックス 0 から始まります。

インデックス ‘index’ を有する内部テーブルの行に ‘proxy[index]’ を使用してアクセスできます。

プロキシオブジェクトが有するプロパティ、メソッドを次に示します。

ｷ        現在の内部テーブルの行番号を収容するプロパティ ‘length’ 。

ｷ        内部テーブルに空白行の追加を可能にするメソッド ‘appendLine’ 。

ｷ        行 ‘idx’ から ‘count’ 行の削除を可能にするメソッド ‘deleteLines(idx,count)’ 。

内部テーブルの行タイプが構造体の場合、構造体のコンポーネントはプロキシオブジェクトのプロパティを形成し、そのため ABAP 名は小文字で渡されます。

JavaScript では、利用可能でないエントリをアドレスすることにより配列エレメントを新規作成することはできません。JavaScript の通例として、配列エレメントのカウントは 0 から始まりますJavaScript 内では、他のプロパティまたはメソッドをプロキシオブジェクトに追加できません。構造体として、JavaScript 内では内部テーブル全体を変更できません。一意キーのあるテーブルのキーフィールドを JavaScript 内で変更してキーの一意性に違反すると、実行時エラーが発生します。

report DEMO_JAVA_SCRIPT_BIND_ITAB.

data: begin of LINE,
        COMP type I,
      end of LINE.

data ITAB like standard table of LINE.

data SOURCE type STRING.
data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.

JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

JS_PROCESSOR->BIND( exporting NAME_OBJ  = 'abap'
                              NAME_PROP = 'Itab'
                    changing  DATA      = ITAB ).

do 5 times.
  LINE-COMP = SY-INDEX.
  append LINE to ITAB.
enddo.

concatenate 'var len = abap.Itab.length;           '
            'var sum = 0;                          '
            'for (var i = 0; i < len; i++)         '
            '{                                     '
            '  sum += Number(abap.Itab[i].comp)    '
            '}                                     '
            'abap.Itab.appendLine();                '
            'len++;                                '
            'abap.Itab.appendLine();                '
            'len++;                                '
            'abap.Itab[len-1].comp=sum;             '
   into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.

JS_PROCESSOR->EVALUATE( JAVA_SCRIPT = SOURCE ).

loop at ITAB into LINE.
  write / LINE-COMP.
endloop.

この例は、JavaScript 内の構造体の内部テーブルにアクセスする方法を明らかにします。またここでは、ABAP 基本データ型によって内部テーブルにアクセスでき、そのため ‘comp’ 仕様は JavaScript では単に無視されます。JavaScript プログラムはエントリを合計して、2 行の空白行を内部テーブルに追加してから、最後のエントリにこの合計を記入します。EVALUATE メソッドが呼び出された後、ABAP プログラムの内部テーブルには 7 行あります。また ABAP プログラムの内部テーブルは、メソッドが呼び出された後にデータが入力されます。JavaScript は、常に ABAP で最新のデータを使用します。

JavaScript の配列オブジェクトの基本プロパティを他の JavaScript 変数に割り当てる場合、注意してください。ABAP の内部テーブルが再組織されると、JavaScript および ABAP 内のこれらの参照しているバインドは失われて、例外が発生します。例:

report DEMO_JAVA_SCRIPT_BIND_ITAB.

data: begin of LINE,
        COMP type I,
      end of LINE.

data ITAB like standard table of LINE.

data SOURCE type STRING.
data RETURN_VALUE type STRING.

data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.
JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

JS_PROCESSOR->BIND( DATA      = ITAB
                    NAME_OBJ  = 'abap'
                    NAME_PROP = 'Itab').

do 5 times.
  LINE-COMP = SY-INDEX.
  append LINE to ITAB.
enddo.

concatenate 'var pointer = abap.Itab[4];          '
            'pointer.comp;                        '
  into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.

RETURN_VALUE = JS_PROCESSOR->EVALUATE( JAVA_SCRIPT = SOURCE ).
message return_value TYPE 'I'.

clear ITAB.

do 5 times.
  LINE-COMP = SY-INDEX ** 2.
  append LINE to ITAB.
enddo.

SOURCE = 'pointer.comp;'.

RETURN_VALUE = JS_PROCESSOR->EVALUATE( JAVA_SCRIPT = SOURCE ).

初めてメソッドが呼び出されると、メソッドは '5' の値を返します。ただし 2 回めには、処理不能の例外を引き起こします。この例外には、実行時エラーSYSTEM_DATA_ALREADY_FREE が付属します。JavaScript 参照 ‘pointer’ が定義されていないメモリ領域をポイントするからです。