STEP 

機能

現在のコンテキストのデバッグモードにあるスクリプトのシングルステップ実行。STEP は行の関数呼び出しを実行します。そのため ABAP デバッガの実行 (F6) と同一の効果があります。

リターンパラメータ

RESULT (Type STRING)

スクリプト内で実行された最後の命令の値。したがって STEP の結果は、最後の命令に到達した場合だけ得られます。

例

report DEMO_JAVA_SCRIPT_STEP.

data SOURCE type STRING.
data get_VALUE type STRING.

data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.

JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).

concatenate
  'var string = "Hello World,";   '
  'function Set_String()          '
  '  { string += " this";         '
  '    string += " is";           '
  '    string += " JavaScript!";} '
  'Set_String();                  '
  'string;                        '
   into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.

JS_PROCESSOR->COMPILE(
              exporting
                SCRIPT_NAME = 'HELLO_WORLD.JS'
                SCRIPT      = SOURCE ).

JS_PROCESSOR->SET_BREAKPOINT(
              exporting
                SCRIPT_NAME = 'HELLO_WORLD.JS'
                LINE_NUMBER = 1 ).

JS_PROCESSOR->EXECUTE(
              exporting SCRIPT_NAME = 'HELLO_WORLD.JS').

while JS_PROCESSOR->LAST_CONDITION_CODE =
                   CL_JAVA_SCRIPT=>CC_BREAKPOINT.

  get_value = JS_PROCESSOR->get( NAME = 'string').
  write: / JS_PROCESSOR->BREAKPOINT_LINE_NUMBER, get_VALUE.

  JS_PROCESSOR->STEP( ).

endwhile.

行 1 のブレークポイントおよび EXECUTE によるスクリプトの実行は、HELLO_WORLD.JS スクリプトをデバッグモードに切り替えます。次にスクリプトは、終了するまでステップごとに実行されます。Set_String 関数の実行は解決されません (STEP_INTO と比較) 。STEP メソッドは、WHILE ループを制御する LAST_CONDITION_CODE 属性を設定します。