空白行、下線、コメントの指定 

空白行

選択画面に空白行を配置するには、次の構文を使用します。

SELECTION-SCREEN SKIP [<n>].

この文は、<n> 個の空白行を生成します(<n> は 1 から 9 までの値) 。1 つの空白行を生成する場合は、<n> を省略できます。

下線

選択画面に下線を配置するには、次の構文を使用します。

SELECTION-SCREEN ULINE [[/]<pos(len)>] [MODIF ID <key>].

この文は、1 つの下線を生成します。<pos(len)> 追加オプションを使用しない場合は、現在の行の下に下線用の行が新規作成され、行と同じ長さで下線が表示されます。<pos(len)> 追加オプションを使用する場合は、下線は現在の行の <pos> 位置から開始し、<len> 文字の長さで表示されます。1 行に複数の要素が含まれる場合は、<pos> を指定せずに (<len>) を指定することもできます。スラッシュ (/) は、改行を示します。

<pos> には、数値を指定するか、あるいは POS_LOW または POS_HIGH のいずれかの式を指定できます。POS_LOW およびPOS_HIGH は、選択基準の 2 つの入力項目の位置を示します。

MODIF ID <key> 追加オプションは、PARAMETERS 文における機能と同じ機能を持ちます。これを使用すると、選択画面を呼び出す前に下線を修正できます。

コメント

選択画面にコメントを配置するには、次の構文を使用します。

SELECTION-SCREEN COMMENT [/]<pos(len)> <comm> [FOR FIELD <f>]
                                              [MODIF ID <key>].

この文により、選択画面上に <comm> コメントが表示されます。<comm> には、テキストシンボルか、または最大 8 文字の任意の項目名を指定できます。この文字項目は、<len> の長さで自動生成されるので、DATA 文で宣言しないでください。この項目は、選択画面が呼び出される前に指定する必要があります。<pos(len)> 追加オプションは、常に指定する必要があります。1 行に複数の要素が含まれる場合にのみ、<pos> を省略できます。

<comm> テキストは、<pos> 列から開始し、<len> の長さで表示されます。スラッシュ (/) を使用しない場合は、コメントは現在の行に書き込まれます。スラッシュを使用する場合は、新規の行が作成されます。

項目ラベルをコメントに割り当てるには、FOR FIELD <f> を使用します。<f> には、パラメータまたは選択基準の名前を指定できます。この結果、ユーザが選択画面でコメントに対するヘルプを呼び出した場合、割り当てた項目<f> に対するヘルプテキストが表示されます。

MODIF ID <key> 追加オプションは、PARAMETERS 文における機能と同じ機能を持ちます。これを使用すると、選択画面を呼び出す前にコメントを修正できます。

例

REPORT DEMO.

SELECTION-SCREEN COMMENT /2(50) TEXT-001 MODIF ID SC1.

SELECTION-SCREEN SKIP 2.
SELECTION-SCREEN COMMENT /10(30) COMM1.
SELECTION-SCREEN ULINE.

PARAMETERS: R1 RADIOBUTTON GROUP RAD1,
            R2 RADIOBUTTON GROUP RAD1,
            R3 RADIOBUTTON GROUP RAD1.

SELECTION-SCREEN ULINE /1(50).
SELECTION-SCREEN COMMENT /10(30) COMM2.
SELECTION-SCREEN ULINE.

PARAMETERS: S1 RADIOBUTTON GROUP RAD2,
            S2 RADIOBUTTON GROUP RAD2,
            S3 RADIOBUTTON GROUP RAD2.

SELECTION-SCREEN ULINE /1(50).

INITIALIZATION.

COMM1 =' ラジオボタングループ 1'.
COMM2 =' ラジオボタングループ 2'.

LOOP AT SCREEN.
  IF SCREEN-GROUP1 = 'SC1'.
      SCREEN-INTENSIFIED = '1'.
      MODIFY SCREEN.
    ENDIF.
ENDLOOP.

以下の選択画面が表示されます。

テキストシンボル 001 に指定したテキスト、' 空白行、下線、コメントの例' が強調表示されます。このテキストの下に、2 つのラジオボタングループが表示されます。各ラジオボタングループは下線で区切られ、それぞれにコメントが表示されます。ULINE 追加オプションにスラッシュ (/) を使用しないと、各ラジオボタングループの最後の行に下線が上書きされます。