呼び出されたプログラムを終了するプログラム命令 

通常、SUBMIT ... AND RETURN を使用して呼び出されたプログラムを終了させるには、呼び出されたレポートの一覧レベル 0 で F3 または F15 を選択します。

ただし、呼出元プログラムに戻る前にさらに命令を実行する必要がある場合は (EXPORT 命令を使用して ABAP メモリにデータを保存するなど) 、呼び出されたプログラムのユーザインタフェースを変更する必要があります。たとえば、ユーザ固有の 前画面機能の機能コードを定義し、それを AT USER-COMMAND イベントで処理することができます。追加の命令を書き込んだ後、呼び出されたプログラムを LEAVE 命令を使用して終了できます。

その後、コントロールはプログラムの呼出元に戻ります。

 

REPORT REP1 NO STANDARD PAGE HEADING.

DATA: ITAB TYPE I OCCURS 10,
      NUM TYPE I.

SUBMIT REP2 AND RETURN.

IMPORT ITAB FROM MEMORY ID 'HK'.

LOOP AT ITAB INTO NUM.
  WRITE / NUM.
ENDLOOP.

TOP-OF-PAGE.
WRITE 'Report 1'.
ULINE.

このプログラムで次の実行可能プログラム ( レポート) が呼び出されます。

REPORT REP2 NO STANDARD PAGE HEADING.

DATA: NUMBER TYPE I,
      ITAB TYPE I OCCURS 10.

SET PF-STATUS 'MYBACK'.

DO 5 TIMES.
  NUMBER = SY-INDEX.
  APPEND NUMBER TO ITAB.
  WRITE / NUMBER.
ENDDO.

TOP-OF-PAGE.
WRITE 'Report 2'.
ULINE.

AT USER-COMMAND.
  CASE SY-UCOMM.
    WHEN 'MBCK'.
      EXPORT ITAB TO MEMORY ID 'HK'.
      LEAVE.
  ENDCASE.

ステータス MYBACK では、機能コード MBCK が機能キー F3 と F15 に割り当てられています。

インタフェース MYBACK で前画面を選択すると、テーブル ITAB が ABAP メモリに転送され、SAPMZTS1 を終了します。SAPMZTST では、テーブル ITAB が再度読み込まれます。