プログラム内でのカーソルの設定 

プログラム内で、現在の一覧のカーソルを動的に設定することができます。これにより、ユーザは入力項目に値を入力したり、項目や行を選択することができます。一覧内に入力項目がある場合、デフォルトでカーソルが最初の入力項目に置かれます。

カーソルを設定するには、SET CURSOR 命令を使用します。この命令で、カーソルは最新に登録された一覧に置かれます。基本一覧の作成中は、これは常にこの基本一覧になります。詳細一覧の場合、これは前の一覧になります。

SET CURSOR を使用して、カーソルを絶対位置 ( 項目や行) に設定することができます。

カーソルの明示的設定

カーソルを出力ウィンドウの特定の位置に設定するには、以下のように指定します。

SET CURSOR <col> <lin>.

この命令では、カーソルが出力ウィンドウの行 <lin> の列 <col> に設定されます。

カーソルは、画面上に表示されている位置でのみ設定可能です。表示範囲外の位置に設定する命令は無視されます。現在表示されていない一覧の部分にカーソルを設定するには、まず一覧をスクロールしておく必要があります。 

一覧出力が含まれている行にのみカーソルを設定することができます。このような行には、SKIP 命令でスキップされても、アンダーラインがない行が含まれます。<lin> が一覧行の下にある場合、カーソルの位置はその最下行に設定されます。

REPORT demo_list_set_cursor_1 NO STANDARD PAGE HEADING LINE-SIZE 80.

SET PF-STATUS 'SCROLLING'.

NEW-LINE NO-SCROLLING.
WRITE 'Input Fields:'.
NEW-LINE NO-SCROLLING.
WRITE '-------------'.

NEW-LINE.
DO 5 TIMES.
   WRITE:  ' Input', (1) sy-index, '   ' INPUT ON NO-GAP.
ENDDO.

FORMAT INPUT OFF.
SET CURSOR 11 3.

AT USER-COMMAND.
   CASE sy-ucomm.
     WHEN 'LEFT'.
       IF sy-staco > 1.
        SCROLL LIST LEFT BY 12 PLACES.
       ENDIF.
     WHEN 'RGHT'.
       IF sy-staco < 40.
        SCROLL LIST RIGHT BY 12 PLACES.
       ENDIF.
   ENDCASE.
   SET CURSOR 11 3.

このプログラムでは、入力項目が 5 つ含まれる基本一覧が作成されます。カーソルは最初の入力項目に設定されます。ユーザはボタン LEFT と RIGHT を使用して、一覧を左右にスクロールすることができます。それぞれのスクロール移動ごとに、カーソルは再度入力項目に設定されます。

項目へのカーソルの設定

カーソルを表示一覧の行の特定の項目に設定するには、以下のように指定します。

SET CURSOR FIELD <f> LINE <lin> [OFFSET <off>].

この命令では、行 <lin> で名称が <f> に保管されている項目にカーソルが設定されます。項目が行内に複数含まれる場合、最初の項目にカーソルが設定されます。項目が行に含まれない場合、あるいは表示領域外にある場合は、この命令は無視されます。SCROLL 命令を使用して、画面の表示領域内にある行をスクロールすることができます。

<f> に保管されている項目の位置 <off> にカーソルを設定するには、OFFSET オプションを使用します。<off> の値 0 は、最初の位置を表します。

カーソルを設定するときには、一覧のヘッダ行を考慮する必要があります。

REPORT demo_list_set_cursor_2 LINE-SIZE 50.

DATA: input1(5) TYPE c VALUE '*****',
      input2(5) TYPE c VALUE '*****',
      input3(5) TYPE c VALUE '*****'.

SET PF-STATUS 'INPUT'.

WRITE 'Input Fields:'.
WRITE / '-------------'.
SKIP.

WRITE: 'Input 1', input1 INPUT ON,
     / 'Input 2', input2 INPUT ON,
     / 'Input 3', input3 INPUT ON.

AT USER-COMMAND.
   CASE sy-ucomm.
     WHEN 'INP1'.
       SET CURSOR FIELD 'INPUT1' LINE 6 OFFSET 4.
    WHEN 'INP2'.
       SET CURSOR FIELD 'INPUT2' LINE 7 OFFSET 4.
    WHEN 'INP3'.
       SET CURSOR FIELD 'INPUT3' LINE 8 OFFSET 4.
  ENDCASE.

このプログラムでは、入力項目が 3 つ含まれる基本一覧が作成されます。ステータス INPUT で、機能コード INP1 、INP2 、および INP3 が、機能キー F5 、 F6 、 F7 およびアプリケーションツールバーに割り当てられます。これらの機能を 1 つ選択すると、AT USER-COMMAND イベントがトリガされます。これにより、カーソルが対応する入力項目に置かれます。

行へのカーソルの設定

カーソルを出力ウィンドウの特定の行に設定するには、以下のように指定します。

SET CURSOR LINE <lin> [OFFSET <off>].

この命令では、カーソルが行 <lin> に設定されます。行が一覧内に表示されない場合、あるいはウィンドウの表示領域内に表示されない場合、命令は無視されます。SCROLL 命令を使用して、画面の表示領域内にある行をスクロールすることができます。

行 <lin> の列 <off> にカーソルを設定するには、OFFSET オプションを使用します。<off> の値 0 は、最初の列を表します。指定した位置が一覧の表示領域外にある場合、命令は無視されます。

カーソルを設定するときには、一覧のヘッダ行を考慮する必要があります。

REPORT demo_list_set_cursor_3 LINE-SIZE 30
                              NO STANDARD PAGE HEADING.

DATA: inp(2) TYPE c, top(2) TYPE c.

SET PF-STATUS 'LINE_NUMBER'.

DO 50 TIMES.
   WRITE: / 'Line ', (2) sy-index.
ENDDO.

TOP-OF-PAGE.
   WRITE: 'Line number:', inp INPUT ON.
   ULINE.
   SKIP.

AT USER-COMMAND.
   DESCRIBE LIST PAGE 1 TOP-LINES top.
   CASE sy-ucomm.
     WHEN 'LINE'.
       READ LINE 1 FIELD VALUE inp.
       SCROLL LIST TO PAGE 1 LINE inp.
       inp = inp + top.
       SET CURSOR LINE inp OFFSET 6.
  ENDCASE.

このプログラムでは、入力項目が 1 つと複数の行が含まれる基本一覧が作成されます。

ステータス LINE_NUMBER で、機能コード LINE ( テキスト LINE NUMBER) が機能キー F5 とアプリケーションツールバーのボタンに割り当てられます。ユーザが数値を入力項目に入力して LINE NUMBER を選択すると、指定した数値までスクロールされてその位置にカーソルが設定されます。

入力項目の読込には READ LINE が使用されます。カーソルの設定では、ページヘッダのサイズを考慮するために DESCRIBE LIST が使用されます。この例による自動タイプ変換の過剰使用に注意してください。