スクロールするページの部分の設定 

ユーザがスクロールバーでページを横方向にスクロールするページの領域をプログラムで限定することができます以下の 2 つのオプションを組み合わせることもできます。

横スクロールにおける行の除外

横スクロールから行 ( ヘッダまたはコメント行) を除外するには、以下のようにその行の改行を定義します。

構文

NEW-LINE NO-SCROLLING.

この命令の後の行は横にスクロールすることができません。ただし、縦のスクロールは可能です。

この命令を取り消すには以下のように指定します。

構文

NEW-LINE SCROLLING.

この命令は、NEW-LINE NO-SCROLLING の後に行が出力されない場合にのみ効果があります。

REPORT sapmztst NO STANDARD PAGE HEADING
                LINE-COUNT 3 LINE-SIZE 140.

START-OF-SELECTION.

   DO 3 TIMES.
   WRITE: / 'SY-INDEX:'.
   DO 10 TIMES.
     WRITE sy-index.
   ENDDO.
   ENDDO.

NEW-LINE NO-SCROLLING.
ULINE AT 20(20).
NEW-LINE NO-SCROLLING.
WRITE AT 20 '| **** Fixed!**** |'.
NEW-LINE NO-SCROLLING.
ULINE AT 20(20).

   DO 3 TIMES.
   WRITE: / 'SY-INDEX:'.
   DO 10 TIMES.
     WRITE sy-index.
   ENDDO.
   ENDDO.

このプログラムでは、3 行から成るページが 3 ページ、ページヘッダもフッタもなしで生成されます。2 ページ目の 3 行は、NEW-LINE NO-SCROLLING があるためスクロールできません。プログラムの出力は以下のようになります。

ユーザが右にスクロールすると、出力は以下のようになります。

最初のページと 3 ページ目の行のスクロールは固定行を通過します。

横スクロールの左境界

横スクロール領域の左境界を指定するには、以下のように指定します。

構文

SET LEFT SCROLL-BOUNDARY [COLUMN <col>].

COLUMN オプションを使用しないと、現在のページのスクロール可能領域の左境界が、現在の出力位置に設定されます。COLUMN オプションを使用すると、左境界は位置 <col> に設定されます。この時点では、この領域の右の一部だけが横スクロール可能になっています。

上記の命令は、現在のページ全体に適用され、このページだけに限定されます。新しいページごとに命令を繰り返す必要があります。命令を使用しないと、デフォルト値 ( 左一覧マージン) が採用されます。

一覧のすべてのページに同じスクロール可能領域を設定するには、命令を、たとえば TOP-OF-PAGE イベントで実行します。

REPORT sapmztst NO STANDARD PAGE HEADING
                LINE-COUNT 3 LINE-SIZE 140.

START-OF-SELECTION.

   DO 3 TIMES.
   WRITE: /10 'SY-INDEX:'.
   DO 10 TIMES.
     WRITE sy-index.
   ENDDO.
   ENDDO.

SET LEFT SCROLL-BOUNDARY COLUMN 20.

   DO 3 TIMES.
   WRITE: / 'SY-INDEX:'.
   DO 10 TIMES.
     WRITE sy-index.
   ENDDO.
   ENDDO.

SET LEFT SCROLL-BOUNDARY COLUMN 10.

このプログラムでは、3 行から成るページが 2 ページ、ページヘッダもフッタもなしで生成されます。最初の SET 命令で最初のページが影響を受けます。これは、自動改ページが、2 つ目の DO ループの最初の WRITE 命令まで発生しないためです。2 つ目の SET 命令は 2 ページ目に影響を与えます。プログラムの出力は以下のようになります。

ユーザが右にスクロールすると、出力は以下のようになります。

最初のページのスクロール可能領域は、2 ページ目のスクロール可能領域とは異なる位置で、左マージンの固定領域の下に消えます。