特殊な出力書式 

WRITE 命令のすべての書式オプションの概要は、書式オプションを参照してください。このトピックでは特殊な書式オプションについて説明します。これらのオプションは、特殊なデータベーステーブルで作成する必要がある特定のエントリにもとづいて、出力の書式を指定します。通常、得意先がこれらのテーブルを更新するのは、アプリケーションをカスタマイジングするときです ( カスタマイジングについては、カスタマイジングを参照してください) 。

国コード固有およびユーザ固有の出力書式

数値項目と日付項目の出力書式は、個々のプログラムユーザのユーザマスタレコードに定義されます。この命令を使用して、各自のプログラム内でこれらの設定を変更することができます。

構文

SET COUNTRY <c>.

<c> に、テーブル T005X または SPACE に定義されている国コードを設定します。

<c> が SPACE ではない場合、ユーザマスタレコードの設定がオフになり、テーブル T005X から国コードが検索されます。国コードが存在する場合、SY-SUBRC が 0 に設定され、後続のすべての WRITE 命令の出力書式が、T005X に定義された設定内容に応じて指定されます。指定した国コードが存在しない場合、SY-SUBRC が 4 に設定され、後続のすべての WRITE 命令の書式が、小数点はピリオド '.' として、日付は MM/DD/YY として指定されます。

<c> が SPACE の場合、テーブル T005X の読み取りは実行されず、ユーザマスタレコードの設定が採用されます。この場合、SY-SUBRC は常にゼロになります。

テーブル T005X の更新はカスタマイジングの一部です。ただし、 システム → サービス → テーブル更新 と選択して、エントリを表示または変更することができます。

REPORT demo_list_set_country LINE-SIZE 40.

DATA: num TYPE p DECIMALS 3 VALUE '123456.789'.

ULINE.
WRITE: / 'INITIAL:'.
WRITE: / num, sy-datum.
ULINE.

SET COUNTRY 'US'.
WRITE: / 'US,      SY-SUBRC:', sy-subrc.
WRITE: / num, sy-datum.
ULINE.

SET COUNTRY 'GB'.
WRITE: / 'GB,      SY-SUBRC:', sy-subrc.
WRITE: / num, sy-datum.
ULINE.

SET COUNTRY 'DE'.
WRITE: / 'DE,      SY-SUBRC:', sy-subrc.
WRITE: / num, sy-datum.
ULINE.

SET COUNTRY 'XYZ'.
WRITE: / 'XYZ,     SY-SUBRC:', sy-subrc.
WRITE: / num, sy-datum.
ULINE.

SET COUNTRY space.
WRITE: / 'SPACE,   SY-SUBRC:', sy-subrc.
WRITE: / num, sy-datum.
ULINE.

このプログラムでは、異なる書式オプションを使用して、パック数値 NUM およびシステム項目 SY-DATUM が出力されます。

最初と最後の出力は、ユーザ固有です。他のすべての出力では、テーブル T005X の読み取りが実行されます。エントリ 'XYZ' が検索されず、出力書式が設定されます。T005X のエントリはユーザ固有です。

通貨固有の出力書式

数値項目の出力書式を特定の通貨に応じて指定するには、WRITE 命令の CURRENCY オプションを使用します。

構文

WRITE <f> CURRENCY <c>.

この命令は、出力の小数点以下桁数を currency <c> に従って指定します。<c> のコンテンツが通貨コード CURRKEY としてテーブル TCURX に存在する場合、TCURX のエントリ CURRDEC に従って小数点以下桁数が設定されます。これが存在しない場合、デフォルト設定である 2 桁の小数点以下桁数が採用されます。したがって、テーブル TCURX には、小数点以下桁数が 2 ではない例外だけが含まれていなければなりません。

通貨の出力書式は、プログラムに存在する可能性のある数値の小数点以下桁数に依存しません。採用されるのは桁の並びだけです。このため、この桁の並びは、使用する通貨の最小単位に指定した金額を表します。たとえば、US ドル (USD) のセント、ベルギーフラン (BEF) のフランなどがあります。このため、ABAP プログラムでの通貨額の処理では、データ型 P を小数点以下桁数なしで使用することをお奨めします。

REPORT demo_list_write_currency LINE-SIZE 40.

DATA: num1 TYPE p  DECIMALS 4 VALUE '12.3456',
      num2 TYPE p  DECIMALS 0 VALUE '123456'.

SET COUNTRY 'US'.

WRITE: 'USD', num1 CURRENCY 'USD', num2 CURRENCY 'USD',
     / 'BEF', num1 CURRENCY 'BEF', num2 CURRENCY 'BEF',
     / 'KUD', num1 CURRENCY 'KUD', num2 CURRENCY 'KUD'.

このプログラムでは、桁の並びは同一で小数点以下桁数が異なる 2 つのパック数値 NUM1 と NUM2 が定義されます。複数の通貨によるこれらの数値の出力は以下のようになります。

各通貨とも、桁の並びだけを参照しているため、NUM1 と NUM2 の出力書式が同一です。通貨 US ドル (USD) は、1 ドルの百分の一である 1 セントが最小単位であるため、デフォルト設定である 2 桁の小数点以下桁数で表示されています。ベルギーフラン (BEF) の場合、ベルギーフランには最小単位がないため、TCURX の CURRDEC が 0 に設定されています。クウェートのディナール (KUD) には千の単位があるため、3 桁の小数点以下桁数 (CURRDEC の値 3) が設定されています。

単位固有の出力書式

データ型 P の項目の書式を特定の単位に従って指定することができます。たとえば、数量に小数点以下桁数を含めず、重量に 3 桁の小数点以下桁数を含めるようにすることなどが可能です。これを指定するために、WRITE 命令の UNIT オプションを使用することができます。

構文

WRITE <f> UNIT <u>.

この命令は、小数点以下桁数を unit <u> に従って設定します。<u> のコンテンツは、データベーステーブル T006 の列 MSEHI のエントリでなければなりません。列 DECAN のエントリによって、表示する項目<f> の小数点以下桁数が決定されます。エントリ <u> がテーブル T006 から検索できなかった場合、このオプションは無視されます。

この操作に対して以下の制限が適用されます。

ｷ         <f> はパック数値 ( データ型 P) でなければなりません。

ｷ         <f> の小数点以下桁数が unit <u> の小数点以下桁数より小さい場合、このオプションは無視されます。

ｷ         <f> の小数点以下桁数が unit <u> の小数点以下桁数より大きい場合、0 以外の桁数を切り捨てる操作がなければ、このオプションだけが適用されます。

REPORT demo_list_write_unit LINE-SIZE 40.

DATA: num1 TYPE p DECIMALS 1 VALUE 1,
      num2 TYPE p DECIMALS 4 VALUE '2.5'.

SET COUNTRY 'US'.

WRITE: 'KG', num1 UNIT 'KG', num2 UNIT 'KG',
     / 'PC', num1 UNIT 'PC', num2 UNIT 'PC'.

このプログラムでは、小数点以下桁数が 1 桁であるパック数値 NUM1 、および小数点以下桁数が 4 桁であるパック数値 NUM2 が定義されます。テーブル T006 で単位 'KG' ( キログラム) の小数点以下桁数が 3 桁であり、単位 'PC' ( 個) の小数点以下桁数がゼロ桁である場合、出力は以下のようになります。

NUM1 のオプション UNIT 'KG' は無視されます。これは、NUM1 の小数点以下桁数が 3 桁を下回っているためです。UNIT 'PC' オプションは、NUM1 の小数点以下桁数の出力をゼロ桁に短縮します。UNIT 'PC' オプションは、NUM1 の小数点以下桁数の出力をゼロ桁に短縮します。NUM2 の場合、オプション UNIT 'PC' は無視されます。これは、ゼロ桁以外の小数点以下桁数は切り捨てられてしまうためです。