抽出によるデータ書式設定 

抽出内の各レコードは異なる構造を持つことができるため、複数のデータベーステーブルのエントリを 1 つの抽出に格納することができます。

 

以下のプログラムは、論理データベース F1S にリンクしているものと仮定します。

REPORT DEMO.

NODES: SPFLI, SFLIGHT, SBOOK.

FIELD-GROUPS: HEADER, FLIGHT_INFO, FLIGHT_BOOKING.

INSERT:
  SPFLI-CITYFROM SPFLI-CITYTO
  SPFLI-CONNID SFLIGHT-FLDATE
  SBOOK-CLASS SBOOK-SMOKER SBOOK-BOOKID INTO HEADER,
  SPFLI-CARRID                          INTO FLIGHT_INFO,
  SBOOK-LUGGWEIGHT SBOOK-WUNIT          INTO FLIGHT_BOOKING.

START-OF-SELECTION.

GET SPFLI.
  EXTRACT FLIGHT_INFO.

GET SFLIGHT.

GET SBOOK.
  EXTRACT FLIGHT_BOOKING.

END-OF-SELECTION.

  SORT.

  LOOP.
    AT FLIGHT_INFO.
      SKIP.
      WRITE: / SPFLI-CARRID,
               SPFLI-CONNID,
               'from', (15) SPFLI-CITYFROM,
               'to',   (15) SPFLI-CITYTO.
      ULINE.
    ENDAT.
    AT NEW SFLIGHT-FLDATE.
        SKIP.
        WRITE: / 'Date:', SFLIGHT-FLDATE.
        WRITE: 20 'Book-ID', 40 'Smoker', 50 'Class'.
        ULINE.
    ENDAT.
    AT FLIGHT_BOOKING.
        WRITE: / SBOOK-BOOKID UNDER 'Book-ID',
                 SBOOK-SMOKER UNDER 'Smoker',
                 SBOOK-CLASS  UNDER 'Class'.
    ENDAT.
    AT END OF SFLIGHT-FLDATE.
      ULINE.
      WRITE: 'Number of bookings:   ', (3) CNT(SBOOK-BOOKID),
           / 'Total luggage weight:',
              SUM(SBOOK-LUGGWEIGHT), SBOOK-WUNIT.
    ENDAT.
  ENDLOOP.

このプログラムでは、書式設定データの例の場合と同じ一覧が作成されます。

3 つの項目グループが登録され、複数の項目が書き込まれます。次に、GET イベントの EXTRACT 命令によって抽出の書込が行われます。GET SFLIGHT には EXTRACT 命令がありません。必須項目SFLIGHT_FLDATE は HEADER 項目グループの一部であり、下位イベント GET SBOOK の毎実行時に自動的に抽出されるからです。

データの読込後、SORT 命令が実行されるとデータセットの登録が終了し、HEADER ソートキーによってデータセットがソートされます。LOOP-ENDLOOP ブロックでは、各種の AT ... ENDAT ブロックと項目 CNT(...) および SUM(...) によって、ソートされた抽出データセットが出力一覧に書き込まれます。