SPA/GPA パラメータを使用した第一画面入力 

呼び出したトランザクションの入力項目に呼出元プログラムのデータを入力する場合に、SPA/GPA 機能を使用できます。SPA/GPA パラメータはグローバルなユーザ固有の SAP メモリに保存される値です。SAP メモリを使用して、プログラム間の値の受け渡しを行うことができます。ユーザは 1 つの端末セッションから、SAP メモリに保存された、あらゆる並列セッションに関連する値にアクセスすることができます。それぞれの SPA/GPA パラメータは 20 文字コードによって識別されます。SPA/GPA パラメータは ABAP ワークベンチのリポジトリブラウザで更新できます。SPA/GPA パラメータはユーザ固有の値です。

ABAP プログラムでは、SET PARAMETER 命令および GET PARAMETER 命令を使用してパラメータにアクセスできます。

1 つに入力する場合は以下を使用します。

SET PARAMETER ID <pid> FIELD <f>.

この命令により、ID <pid> にある項目<f> のコンテンツが SAP メモリに保存されます。コード <pid> の長さは 20 文字までです。<pid> にすでに値が保存されている場合は、この命令によってその値が上書きされます。ID <pid> が存在しない場合は、ABAP エディタの <pid> をダブルクリックして新たにパラメータオブジェクトを登録します。

SPA/GPA パラメータを読み込むには、以下を使用します。

GET PARAMETER ID <pid> FIELD <f>.

この命令により、ID <pid> に保存されている値が変数<f> に入力されます。SAP メモリ内に <pid> の値が見つからない場合は、SY-SUBRC が 4 に設定されます。それ以外の場合は 0 に設定されます。

SPA/GPA パラメータを使用してプログラムの第一画面に入力する場合は通常、SET PARAMETER 命令だけが必要です。

関連項目はそれぞれ SPA/GPA パラメータにリンクしている必要があります。

選択画面上で、PARAMETERS またはSELECT-OPTIONS 命令の MEMORY ID オプションを使用して項目をパラメータにリンクさせます。パラメータまたは選択オプションの宣言時に SPA/GPA パラメータ ID を指定すると、対応する入力項目がその入力項目にリンクされます。

画面上で、スクリーンペインタのパラメータに項目をリンクさせます。入力項目の項目属性を定義する際に、SPA/GPA パラメータの名称を画面属性の項目パラメータ ID に入力することができます。SET パラメータおよび GET パラメータのチェックボックスで、PBO イベントの対応する SPA/GPA パラメータを項目に入力するかどうか、また、SPA/GPA パラメータに PAI イベントの画面の値を入力するかどうかを指定することができます。

入力項目が SPA/GPA パラメータにリンクしている場合、その入力項目は画面が表示されるたびにパラメータの現在値で初期化されます。R/3 システムの画面を 2 回以上呼び出した場合に、その項目にすでに値が入力されていることがよくあるのは、このためです。

たとえば、呼び出されたプログラムの第一画面の必須項目に入力する必要がある場合は、プログラムを呼び出すときに追加のプログラミングオーバーヘッドなしに SPA/GPA パラメータを使用することができます。パラメータの値は単純に、呼び出されたプログラムの入力項目に転送されます。

ただし、実際のプログラム呼出の前に SET PARAMETER 命令を使用して、プログラムのパラメータのコンテンツを管理することができます。この機能は、呼び出されるプログラムの第一画面をスキップする場合、またその第一画面に必須項目が含まれている場合に特に有効です。

プログラム呼出の前に SPA/GPA パラメータを設定する場合は、第一画面のどの項目にどのパラメータがリンクされているかを把握している必要があります。この情報を簡単に確認するには、呼び出すプログラムを起動して入力項目の上にカーソルを置き、 技術情報の前の F1 を選択します。対応する SPA/GPA パラメータの名称が項目パラメータ ID に含まれています。あるいは、スクリーンペインタの画面定義を参照して確認することもできます。

 

予約トランザクション TCG2 の最初の入力項目に関する技術情報は、以下のようになっています。

入力項目会社の SPA/GPA パラメータは ID CAR です。この方法を使用して、他の入力項目の ID CON 、DAY 、BOK を検索します。

以下の実行可能プログラムは論理データベース F1S に接続されていて、更新トランザクションを呼び出します。

REPORT BOOKINGS NO STANDARD PAGE HEADING.

TABLES SBOOK.

START-OF-SELECTION.
  WRITE: 'Select a booking',
       / '----------------'.
  SKIP.

GET SBOOK.
  WRITE: SBOOK-CARRID, SBOOK-CONNID,
         SBOOK-FLDATE, SBOOK-BOOKID.
  HIDE:   SBOOK-CARRID, SBOOK-CONNID,
         SBOOK-FLDATE, SBOOK-BOOKID.

AT LINE-SELECTION.
  SET PARAMETER ID: 'CAR' FIELD SBOOK-CARRID,
                    'CON' FIELD SBOOK-CONNID,
                    'DAY' FIELD SBOOK-FLDATE,
                    'BOK' FIELD SBOOK-BOOKID.
  CALL TRANSACTION 'BOOK'.

プログラムの基本一覧は、選択画面のユーザエントリに従ってデータベーステーブル SBOOK の項目を表示します。これらのデータは各行の HIDE 領域にも保存されています。

予約データの行をダブルクリックして選択した場合は、AT LINE-SELECTION イベントがトリガされて HIDE 領域に保存されたデータが取り込まれ、トランザクションの第一画面の SPA/GPA パラメータに入力されます。その後、トランザクションが呼び出されます。AND SKIP FIRST SCREEN を使用して第一画面を非表示にしていないため、次のように第一画面が表示されます。

CALL TRANSACTION 命令の AND SKIP FIRST SCREEN オプションを使用する場合は、第一画面のすべての必須項目が入力されているため、即座に第二画面が表示されます。