画面処理からの一覧の起動 (SAP ライブラリ - ABAP プログラミング (BC-ABA))

画面処理からの一覧の起動

このセクションでは、画面処理から一覧処理に切り替える方法について説明します。最初に技術的概要を簡単に説明し、次に推奨される手順について説明します。

画面処理と一覧処理の切替

画面処理には、CALL SCREEN またはトランザクションコードを使用して開始する画面順序が常に関係します。画面処理中、ABAP プログラムはダイアログプロセッサによって制御されます。ABAP プログラムで、画面制御ロジックから呼び出された PBO および PAI モジュールが実行されます。

ダイアログプロセッサから一覧プロセッサに制御を渡すには、ダイアログモジュールのいずれかに以下の命令を含める必要があります。

LEAVE TO LIST-PROCESSING [AND RETURN TO SCREEN <nnnn>]

この命令は、PBO イベントまたは PAI イベントに含めることができます。これにより、一覧プロセッサが起動し、現在の画面の PAI 処理後に 基本一覧が表示されます。基本一覧には、その時点までに実行された PBO および PAI モジュールからの一覧出力すべてが含まれます。

ABAP プログラムの該当イベントブロック (AT LINE-SELECTION 、AT USER-COMMAND) で詳細一覧が定義されている場合には、基本一覧でのユーザアクションによって詳細一覧が表示され、その後のインタラクションによってさらなる一覧レベルが表示されます。

一覧処理は、以下の 2 つの方法で終了することができます。

ｷ 前画面 、終了、または取消機能を使用して基本一覧を終了します。

ｷ一覧処理中に以下の命令を使用します。

LEAVE LIST-PROCESSING

どちらの場合も、一覧プロセッサからダイアログプロセッサに制御が戻ります。制御が戻るたびに、 一覧システム全体が初期化されます。その後の PBO および PAI モジュールでの一覧出力命令はすべて、空の基本一覧に適用されます。

デフォルトでは、ダイアログプロセッサは一覧プロセッサが呼び出された画面の PBO 処理に戻ります。オプションで AND RETURN TO SCREEN を追加すると、画面順序内で処理を再開したい PBO イベントのある別の画面を指定することができます。たとえば、以下の命令を使用するとします。

LEAVE TO LIST-PROCESSING AND RETURN TO SCREEN 0

この場合、現在の画面順序を終了して、初めに呼び出された地点に戻ることができます。

推奨手順

画面処理中に一覧を照会するには、呼び出す一覧システムそれぞれに対して個別の画面を登録する必要があります。この画面により、基本一覧の登録と照会が カプセル化されます。そのため、CALL SCREEN を使用してプログラム内の任意の場所から呼び出すことができます。

この画面の実際の画面マスクは、空のままの場合があります。PAI モジュールは不要で、必要なのは 1 つの PBO モジュールだけです。PBO モジュールで、一覧システムの基本一覧を定義し、一覧プロセッサを呼び出します。

...

1. まず、以下の命令を使用します。

LEAVE TO LIST-PROCESSING AND RETURN TO SCREEN 0

この命令により、画面の最後に一覧表示を呼び出し、一覧を終了した後で画面が呼び出された位置に戻ることができます。

2. 次に、デフォルト一覧ステータス SPACE または独自の一覧ステータスなど、一覧の GUI ステータスを設定します。

3. 以下の命令のいずれかを使用して、空の画面が表示されないようにします。

SUPPRESS DIALOG

または

LEAVE SCREEN 一覧が画面の最後に即座に表示されます。

4. 次に、基本一覧全体を定義し、必要なデータを HIDE 領域に指定します。

一覧でのユーザアクションを処理するには、ABAP プログラムで関連するイベントブロックを定義する必要があります。プログラムで複数の独立した一覧システムを呼び出すには、一覧イベント処理でこれらの一覧システムを区別できるようにする必要があります。一覧のコンテナ画面の番号は常に 120 であるため、SY-DYNNR を使用してこの区別を行うことはできません。代わりに、異なる GUI ステータスを各一覧に割り当てて、SY-PFKEY の値を使用して一覧システムを区別するか、または各一覧システムの HIDE 領域にいくつかの一意な情報を含めることができます。

例

REPORT demo_leave_to_list_processing .

TABLES sdyn_conn.

DATA: wa_spfli TYPE spfli,
flightdate TYPE sflight-fldate.

CALL SCREEN 100.

MODULE status_0100 OUTPUT.
SET PF-STATUS 'SCREEN_100'.
ENDMODULE.

MODULE cancel INPUT.
LEAVE PROGRAM.
ENDMODULE.

MODULE user_command_0100.
CALL SCREEN 500.
SET SCREEN 100.
ENDMODULE.

MODULE call_list_500 OUTPUT.
   LEAVE TO LIST-PROCESSING AND RETURN TO SCREEN 0.
  SET PF-STATUS space.
   SUPPRESS DIALOG.
   SELECT  carrid connid cityfrom cityto
    FROM  spfli
    INTO  CORRESPONDING FIELDS OF wa_spfli
    WHERE carrid = sdyn_conn-carrid.
     WRITE: / wa_spfli-carrid, wa_spfli-connid,
             wa_spfli-cityfrom, wa_spfli-cityto.
     HIDE: wa_spfli-carrid, wa_spfli-connid.
   ENDSELECT.
   CLEAR: wa_spfli-carrid.
ENDMODULE.

TOP-OF-PAGE.
WRITE text-001 COLOR COL_HEADING.
ULINE.

TOP-OF-PAGE DURING LINE-SELECTION.
WRITE sy-lisel COLOR COL_HEADING.
ULINE.

AT LINE-SELECTION.
   CHECK not wa_spfli-carrid is initial.
   SELECT  fldate
    FROM  sflight
    INTO  flightdate
    WHERE carrid = wa_spfli-carrid AND
          connid = wa_spfli-connid.
     WRITE / flightdate.
   ENDSELECT.
   CLEAR: wa_spfli-carrid.

この例では、画面 100 の画面処理中に一覧処理に切り替えています。画面 100 には 1 つの入力項目 (ABAP ディクショナリ構造 SDYN_CONN からのコンポーネント CARRID) があります。

これには以下の制御ロジックがあります。

PROCESS BEFORE OUTPUT.
MODULE STATUS_0100.

PROCESS AFTER INPUT.
MODULE CANCEL AT EXIT-COMMAND.
MODULE USER_COMMAND_0100.

PAI モジュール USER_COMMAND_100 により、CALL SCREEN 命令を使用して画面 500 が呼び出されます。この画面は、基本一覧をカプセル化します。これには以下の制御ロジックがあります。

PROCESS BEFORE OUTPUT.
MODULE CALL_LIST_500.

PROCESS AFTER INPUT.

モジュール CALL_LIST_500 により、基本一覧が定義され、一覧処理に切り替えられます。一覧処理後の次の画面が画面 0 であるため、画面 500 は 1 画面の画面チェーンです。一覧処理後、画面 500 が呼び出された USER_COMMAND_100 の位置に制御が戻ります。

ユーザが基本一覧内の 1 行を選択すると、詳細一覧が表示されます。これは、イベントブロック AT LINE-SELECTION を使用してアーカイブされます。プログラムには、 TOP-OF-PAGE および TOP-OF-PAGE DURING LINE-SELECTION 用のイベントブロックも含まれており、基本一覧と詳細一覧のページヘッダの定義に使用します。

このプログラムには 1 つの一覧システムしかないため、一覧イベント内で区別する必要はありません。