一時的サブルーチンの登録と実行 (SAP ライブラリ

一時的サブルーチンの登録と実行

別のトピックで、動的プログラムが R/3 リポジトリに登録されることを説明しました。このトピックでは、メインメモリにおける動的サブルーチンの登録とコールの方法について説明します。

新しいプログラムの動的登録で説明したように、サブルーチンのソースコードを内部テーブルに書き込みます。プログラムを生成するためには、次の命令を指定してください。

構文

GENERATE SUBROUTINE POOL < 内部テーブル > NAME < プログラム > [< オプション >].

いわゆるサブルーチンプールが、この命令により実行プログラムのメインメモリ領域に登録されます。サブルーチンプールのソースコードを内部テーブル < 内部テーブル > に渡します。この命令により、生成されたサブルーチンプールの名称が項目 < プログラム > に返されます。この名称は長さが８でデータ型が C でなければなりません。実行時のサブルーチン名の指定で説明のように、 < 内部テーブル > で定義されたサブルーチンを動的サブルーチンコールで呼び出すには、 < プログラム > での名称を使用します。

サブルーチンプールが存在するのは、生成プログラムの実行中だけで、このプログラム内からのみコールが可能です。サブルーチンプールは、１プログラムに対して 36 種類まで登録できます。

生成中にエラーが発生すると、 SY-SUBRC に８が設定されます。エラーが発生しなければ、０に設定されます。

GENERATE SUBROUTINE POOL 命令には、次の < オプション > を追加して使用できます。

MESSAGE < メッセージ >

構文にエラーがあれば、 < メッセージ > 項目にエラーメッセージが格納されます。

INCLUDE < インクルード >

構文にエラーがあれば、 < インクルード > 項目にエラーの発生したインクルードプログラム名が格納されます。

LINE < 行 >

構文にエラーがあれば、 < 行 > 項目にエラー行の数が格納されます。

WORD < 単語 >

構文にエラーがあれば、 < 単語 > 項目にエラー語が格納されます。

OFFSET < オフセット >

構文にエラーがあれば、 < オフセット > 項目に行の中のエラー語のオフセットが格納されます。

TRACE-FILE < トレースファイル >

このオプションを使用すると、トレースモードがオンになり、 < トレースファイル > 項目にトレース出力が設定されます。

INSERT REPORT と比較すると、 GENERATE SUBROUTINE POOL 命令の方がパフォーマンスは向上しています。また、 GENERATE SUBROUTINE POOL 命令を使用する際に、命名規則や修正に関する制限を考慮したり、システムを転送する必要はありません。

REPORT SAPMZTST.

DATA: CODE(72) OCCURS 10,
PROG(8), MSG(120), LIN(3), WRD(10), OFF(3).

APPEND 'PROGRAM SUBPOOL.'
        TO CODE.
APPEND 'FORM DYN1.'
        TO CODE.
APPEND
'WRITE / ''Hello, I am the temporary subroutine DYN1!''.'
        TO CODE.
APPEND 'ENDFORM.'
        TO CODE.
APPEND 'FORM DYN2.'
        TO CODE.
APPEND
'WRIT / ''Hello, I am the temporary subroutine DYN2!''.'
        TO CODE.
APPEND 'ENDFORM.'
        TO CODE.

GENERATE SUBROUTINE POOL CODE NAME PROG
MESSAGE MSG
LINE LIN
WORD WRD
OFFSET OFF.

IF SY-SUBRC <> 0.
WRITE: / 'Error during generation in line', LIN,
/ MSG,
/ 'Word:', WRD, 'at offset', OFF.
ELSE.
  WRITE: / 'The name of the subroutine pool is', PROG.
  SKIP 2.
PERFORM DYN1 IN PROGRAM (PROG).
  SKIP 2.
PERFORM DYN1 IN PROGRAM (PROG).
ENDIF.

このプログラムでは、２種類のサブルーチンをもつサブルーチンプールが、 CODE テーブルに書き込まれます。一時的なプログラムには、 REPORT 命令または PROGRAM 命令を指定する必要があることに注意してください。 GENERATE SUBROUTINE POOL 命令により一時的なプログラムが生成されます。出力は以下のようになります。

このグラフィックは添付のテキストに説明されています

２番目のサブルーチン DYN2 の WRITE 命令が誤っているため、生成中にエラーが発生します。該当する行を次に示すように修正します。

APPEND
'WRITE / ''Hello, I am the temporary subroutine DYN2!''.'
TO CODE.

修正後、次のように出力されます。

このグラフィックは添付のテキストに説明されています

生成は完了しました。内部プログラム名が表示されます。その後、サブルーチンプール内のサブルーチンがコールされます。サブルーチンのコールのためにプログラム名を明確に知っておく必要はないということに注意してください。