ABAP オブジェクトでのイベント - 例 

以下の例では、ABAP オブジェクトでイベントを宣言し、呼び出し、処理する方法を示します。

概要

このオブジェクトは、以下に示されている対話式一覧と連動します。ユーザが対話を行うたびに、ABAP オブジェクトでイベントがトリガされます。この一覧とそのデータは、クラス C_LIST で作成されます。ユーザアクションを処理するための STATUS というクラスがあります。このクラスは、AT USER-COMMAND イベントでイベント BUTTON_CLICKED をトリガします。このイベントは、クラス C_LIST で処理されます。このクラスには、一覧の行ごとに、クラス C_SHIP または C_TRUCK のオブジェクトが含まれています。これらのクラスはどちらも、インタフェース I_VEHICLE を実装しています。いずれかのオブジェクトの速度が変わると、イベント SPEED_CHANGE がトリガされます。クラス C_LIST は、このイベントに反応して一覧を更新します。

制約事項

一覧処理に使用される ABAP 命令は、ABAP オブジェクトでまだ完全に利用可能となっていません。ただし、単純なテスト出力を生成する場合は、以下の命令を使用することができます。

ｷ         WRITE [AT] /<offset>(<length>) <f>

ｷ         ULINE

ｷ         SKIP

ｷ         NEW-LINE

注記: 書式設定と対話式一覧機能の現状の動作は保証されていません。今後のリリースで、互換性のない変更が行われる可能性があります。

宣言

 

この例は、ローカルなインタフェースとクラスを使って実装されます。以下に示すのは、インタフェースとクラスの宣言です。

*****************************************************************
* インタフェースとクラスの宣言 *****************************************************************

INTERFACE I_VEHICLE.

  DATA     MAX_SPEED TYPE I.

   EVENTS SPEED_CHANGE EXPORTING VALUE(NEW_SPEED) TYPE I.

   METHODS: DRIVE,
           STOP.

ENDINTERFACE.

*----------------------------------------------------------------

CLASS C_SHIP DEFINITION.

   PUBLIC SECTION.

   METHODS CONSTRUCTOR.

   INTERFACES I_VEHICLE.

   PRIVATE SECTION.

   ALIASES MAX FOR I_VEHICLE~MAX_SPEED.

   DATA SHIP_SPEED TYPE I.

ENDCLASS.

*----------------------------------------------------------------

CLASS C_TRUCK DEFINITION.

   PUBLIC SECTION.

   METHODS CONSTRUCTOR.

   INTERFACES I_VEHICLE.

   PRIVATE SECTION.

   ALIASES MAX FOR I_VEHICLE~MAX_SPEED.

   DATA TRUCK_SPEED TYPE I.

ENDCLASS.

*----------------------------------------------------------------

CLASS STATUS DEFINITION.

   PUBLIC SECTION.

   CLASS-EVENTS BUTTON_CLICKED EXPORTING VALUE(FCODE) LIKE SY-UCOMM.

   CLASS-METHODS: CLASS_CONSTRUCTOR,
                USER_ACTION.

ENDCLASS.

*----------------------------------------------------------------

CLASS C_LIST DEFINITION.

   PUBLIC SECTION.

   METHODS: FCODE_HANDLER FOR EVENT BUTTON_CLICKED OF STATUS
                             IMPORTING FCODE,
           LIST_CHANGE   FOR EVENT SPEED_CHANGE OF I_VEHICLE
                             IMPORTING NEW_SPEED,
           LIST_OUTPUT.

   PRIVATE SECTION.

   DATA: ID TYPE I,
        REF_SHIP  TYPE REF TO C_SHIP,
        REF_TRUCK TYPE REF TO C_TRUCK,

         BEGIN OF LINE,
          ID TYPE I,
          FLAG,
          IREF  TYPE REF TO I_VEHICLE,
          SPEED TYPE I,
        END OF LINE,
        LIST LIKE SORTED TABLE OF LINE WITH UNIQUE KEY ID.

ENDCLASS.

*****************************************************************

 

この例では以下のイベントが宣言されます。

ｷ        インタフェース I_VEHICLE 内のインスタンスイベント SPEED_CHANGE

ｷ        クラス STATUS 内の静的イベント BUTTON_CLICKED

クラス C_LIST には、両方のイベントに対するイベントハンドラメソッドが含まれています。

クラス STATUS は属性を持たないため、静的なメソッドおよびイベントのみを処理することに注意してください。

実装

以下に示すのは、上記のクラスのメソッドの実装です。

*****************************************************************
* 実装
*****************************************************************

CLASS C_SHIP IMPLEMENTATION.

   METHOD CONSTRUCTOR.
     MAX = 30.
  ENDMETHOD.

   METHOD I_VEHICLE~DRIVE.
     CHECK SHIP_SPEED < MAX.
    SHIP_SPEED = SHIP_SPEED + 10.
     RAISE EVENT I_VEHICLE~SPEED_CHANGE
                EXPORTING NEW_SPEED = SHIP_SPEED.
   ENDMETHOD.

   METHOD I_VEHICLE~STOP.
     CHECK SHIP_SPEED > 0.
    SHIP_SPEED = 0.
     RAISE EVENT I_VEHICLE~SPEED_CHANGE
                EXPORTING NEW_SPEED = SHIP_SPEED.
   ENDMETHOD.

ENDCLASS.

*----------------------------------------------------------------

CLASS C_TRUCK IMPLEMENTATION.

   METHOD CONSTRUCTOR.
     MAX = 150.
  ENDMETHOD.

   METHOD I_VEHICLE~DRIVE.
     CHECK TRUCK_SPEED < MAX.
    TRUCK_SPEED = TRUCK_SPEED + 50.
     RAISE EVENT I_VEHICLE~SPEED_CHANGE
                EXPORTING NEW_SPEED = TRUCK_SPEED.
   ENDMETHOD.

   METHOD I_VEHICLE~STOP.
     CHECK TRUCK_SPEED > 0.
    TRUCK_SPEED = 0.
     RAISE EVENT I_VEHICLE~SPEED_CHANGE
                EXPORTING NEW_SPEED = TRUCK_SPEED.
   ENDMETHOD.

ENDCLASS.

*----------------------------------------------------------------

CLASS STATUS IMPLEMENTATION.

  METHOD CLASS_CONSTRUCTOR.
    SET PF-STATUS 'VEHICLE'.
     WRITE 'Click a button!'.
  ENDMETHOD.

   METHOD USER_ACTION.
     RAISE EVENT BUTTON_CLICKED EXPORTING FCODE = SY-UCOMM.
   ENDMETHOD.

ENDCLASS.

*----------------------------------------------------------------

CLASS C_LIST IMPLEMENTATION.

   METHOD FCODE_HANDLER.
     CLEAR LINE.
     CASE FCODE.
       WHEN 'CREA_SHIP'.
         ID = ID + 1.
        CREATE OBJECT REF_SHIP.
         LINE-ID = ID.
        LINE-FLAG = 'C'.
         LINE-IREF = REF_SHIP.
         APPEND LINE TO LIST.
       WHEN 'CREA_TRUCK'.
         ID = ID + 1.
        CREATE OBJECT REF_TRUCK.
         LINE-ID = ID.
        LINE-FLAG = 'T'.
         LINE-IREF = REF_TRUCK.
         APPEND LINE TO LIST.
       WHEN 'DRIVE'.
         CHECK SY-LILLI > 0.
        READ TABLE LIST INDEX SY-LILLI INTO LINE.
         CALL METHOD LINE-IREF->DRIVE.
       WHEN 'STOP'.
         LOOP AT LIST INTO LINE.
           CALL METHOD LINE-IREF->STOP.
         ENDLOOP.
       WHEN 'CANCEL'.
         LEAVE PROGRAM.
     ENDCASE.
     CALL METHOD LIST_OUTPUT.
   ENDMETHOD.

   METHOD LIST_CHANGE.
     LINE-SPEED = NEW_SPEED.
     MODIFY TABLE LIST FROM LINE.
   ENDMETHOD.

   METHOD LIST_OUTPUT.
     SY-LSIND = 0.
    SET TITLEBAR 'TIT'.
     LOOP AT LIST INTO LINE.
       IF LINE-FLAG = 'C'.
         WRITE / ICON_WS_SHIP AS ICON.
       ELSEIF LINE-FLAG = 'T'.
         WRITE / ICON_WS_TRUCK AS ICON.
       ENDIF.
       WRITE: 'Speed = ', LINE-SPEED.
    ENDLOOP.
  ENDMETHOD.

ENDCLASS.

*****************************************************************

 

クラス STATUS の静的メソッドUSER_ACTION によって、静的イベント BUTTON_CLICKED がトリガされます。インスタンスメソッド I_VEHICLE~DRIVE およびI_VEHICLE~STOP によって、クラス C_SHIP および C_TRUCK 内のインスタンスメソッドI_VEHICLE~SPEED_CHANGE がトリガされます。

プログラムでのクラスの使用

以下のプログラムでは、上記のクラスが使用されます。

REPORT OO_EVENTS_DEMO NO STANDARD PAGE HEADING.

*****************************************************************
* プログラムのグローバルデータ
*****************************************************************

DATA LIST TYPE REF TO C_LIST.

*****************************************************************
* イベントのプログラミング
*****************************************************************

START-OF-SELECTION.

  CREATE OBJECT LIST.

  SET HANDLER: LIST->FCODE_HANDLER,
              LIST->LIST_CHANGE FOR ALL INSTANCES.

*----------------------------------------------------------------

AT USER-COMMAND.

   CALL METHOD STATUS=>USER_ACTION.

*****************************************************************

このプログラムによって、クラス C_LIST のオブジェクトが登録され、そのオブジェクトのイベントハンドラメソッド FCODE_HANDLER がクラスイベント BUTTON_CLICKED に対して登録されます。また、インタフェース I_VEHICLE を実装するすべてのインスタンスのイベント SPEED_CHANGE に対してイベントハンドラメソッド LIST_CHANGE が登録されます。