Printing from within the Program
To start the printing process from within the program while creating a list, use the NEW-PAGE statement with the PRINT ON option:
Syntax
NEW-PAGE PRINT ON [NEW-SECTION]
[<params> | PARAMETERS <pripar>]
[ARCHIVE PARAMETERS <arcpar>]
[NO DIALOG].
This statement causes all subsequent output to be placed on a new page and the system interprets any output statements following NEW-PAGE PRINT ON as print statements.
If you use the NEW-SECTION option, you reset pagination (SY-PAGNO system field) to 1. The other options determine the print parameters (see below).
If the list created by this point is a screen list, it is buffered. Starting from NEW-PAGE PRINT ON, the system no longer creates the list for display but for the spool system.
If the system is already creating a list for the spool system, and the NEW-SECTION addition is not used, no new spool request is created: The specified print parameters only apply for the subsequent spool request.
If the system is already creating a list for the spool system, and the NEW-SECTION addition is used, there are two possibilities:
A statement block started with NEW-PAGE PRINT ON should be finished with the PRINT OFF addition to the NEW-PAGE statement.
Syntax
NEW-PAGE PRINT OFF.
This statement creates a page break and sends the last page to the spool system.
If the preceding list was a screen list, it is retrieved from the buffer and the following output statements are reinserted.
If the preceding list was a print list, a new spool request is created and the following output statements are reinserted into the print list. If print parameters were specified for NEW-PAGE PRINT ON without the NEW-SECTION addition, these parameters apply.
The statement blocks NEW-PAGE PRINT ON - NEW-PAGE PRINT OFF must not be nested and should be completed within a processing block.
Setting the Print Parameters
To determine the print parameters for printed output following the NEW- PAGE PRINT ON statement, use the options of the statement.
You can use several options <params> to specify each print parameter (for example DESTINATION <dest>). The keyword documentation explains each option. Use the NO DIALOG option to tell the system whether to display or suppress the Print List Output dialog box. This method of setting print parameters has its disadvantages, since the system does not check whether the parameters specified are complete. Incomplete print parameters are detected only if you use the Print List Output dialog box. However this is not possible for background jobs. If the print parameters are incomplete and you use the NO DIALOG option, the system sends a warning after the syntax check, but it does not stop processing. This may cause unpredictable results when executing the program.
SAP, therefore, recommends not to use the <params> options. Use the PARAMETERS option instead, and the ARCHIVE PARAMETERS option if necessary. To create the corresponding arguments <pripar> and <arcpar>, use the export parameters of the function module GET_PRINT_PARAMETERS. This is the only method that guarantees a complete set of print parameters and an executable print request. Since the function module GET_PRINT_PARAMETERS has its own user dialog, always use the NO DIALOG option in the NEW-PAGE PRINT ON statement.
REPORT demo_list_new_page_print_on NO STANDARD PAGE HEADING.
DATA: val(1) TYPE c,
pripar TYPE pri_params,
arcpar TYPE arc_params,
lay TYPE pri_params-paart,
lines TYPE pri_params-linct,
rows TYPE pri_params-linsz.
CALL FUNCTION 'GET_PRINT_PARAMETERS'
IMPORTING
out_parameters = pripar
out_archive_parameters = arcpar
valid = val
EXCEPTIONS
archive_info_not_found = 1
invalid_print_params = 2
invalid_archive_params = 3
OTHERS = 4.
IF val <> space AND sy-subrc = 0.
SET PF-STATUS 'PRINT'.
WRITE ' Select a format!'.
ENDIF.
TOP-OF-PAGE DURING LINE-SELECTION.
WRITE: 'Page', sy-pagno.
ULINE.
AT USER-COMMAND.
CASE sy-ucomm.
WHEN 'PORT'.
lay = 'X_65_80'.
lines = 60.
rows = 55.
PERFORM format.
WHEN 'LAND'.
lay = 'X_65_132'.
lines = 60.
rows = 110.
PERFORM format.
ENDCASE.
FORM format.
CALL FUNCTION 'GET_PRINT_PARAMETERS'
EXPORTING
in_archive_parameters = arcpar
in_parameters = pripar
layout = lay
line_count = lines
line_size = rows
no_dialog = 'X'
IMPORTING
out_archive_parameters = arcpar
out_parameters = pripar
valid = val
EXCEPTIONS
archive_info_not_found = 1
invalid_print_params = 2
invalid_archive_params = 3
OTHERS = 4.
IF val <> space AND sy-subrc = 0.
PERFORM list.
ENDIF.
ENDFORM.
FORM list.
NEW-PAGE PRINT ON
NEW-SECTION
PARAMETERS pripar
ARCHIVE PARAMETERS arcpar
NO DIALOG.
DO 440 TIMES.
WRITE (3) sy-index.
ENDDO.
NEW-PAGE PRINT OFF.
ENDFORM.
This program immediately calls the function module GET_PRINT_PARAMETERS without passing import parameters. No import parameters are transferred. In the Print List Output dialog box, the user can enter the print and archiving parameters for this program. The system passes these parameters, using the export parameters of the function module, to the structures PRIPAR and ARCPAR. To guarantee that the parameters are complete and consistent, the program runs the user dialog and checks the return value of VALID.
After completing the dialog, the system displays the following basic list:
In the status PRINT of the basic list, the function codes PORT and LAND are assigned to the function keys
F5 and F6, and to two pushbuttons of the application toolbar. If the user chooses one of these functions, the AT USER-COMMAND event occurs, assigning to the variables LAY, LINES, and ROWS the values for portrait or landscape output format and calling the subroutine FORMAT.The subroutine FORMAT calls the function module GET_PRINT_PARAMETERS. When it does so, it passes the parameters PRIPAR and ARCPAR as import parameters. The values from LAY, LINES, and ROWS are assigned to the import parameters LAYOUT, LINE_COUNT and LINE_SIZE respectively. There is no user dialog. The system returns the parameters to the structures PRIPAR and ARCPAR. The function of the subroutine call is to set the components PAART, LINCT, and LINSZ of the structure PRIPAR with new values.
After checking the parameters for completeness and consistency, the program calls the subroutine LIST. This subroutine sends a list to the spool system using NEW-PAGE PRINT ON, thereby determining the print and archiving parameters using PRIPAR and ARCPAR. A user dialog is not necessary, since all settings required were made by GET_PRINT_PARAMETERS.
To view the stored spool requests, the user can choose System
® Services ® Print requests. After choosing PORTRAIT, the spool request may look like this:
After choosing LANDSCAPE, however, the spool request looks like this:
