Mehrere Elemente in einer Zeile
Um mehrere Parameter oder Kommentare in einer einzelne Zeile eines Selektionsbilds auszugeben, müssen die Elemente in einem Block zwischen den beiden folgenden Anweisungen deklariert werden:
SELECTION-SCREEN BEGIN OF LINE.
...
SELECTION-SCREEN END OF LINE.
Der Selektionstext wird bei dieser Option nicht angezeigt. Um die Elemente zu beschreiben, muß der Zusatz COMMENT der Anweisung SELECTION-SCREEN verwendet werden.
In der Formatierungsoption <pos(len)> der Anweisung SELECTION-SCREEN kann innerhalb obiger Anweisungen die Positionsangabe <pos> entfallen. Das entsprechende Element wird an die aktuelle Position innerhalb der Zeile gestellt. Innerhalb obiger Anweisungen darf der Schrägstrich (/) in der Formatierungsoption <pos(len)> nicht verwendet werden.
Um die POSITION eines Elements innerhalb einer Zeile festzulegen, verwendet man:
SELECTION-SCREEN POSITION <pos>.
Für <pos> kann eine Zahl, oder einer der Ausdrücke POS_LOW oder POS_HIGH angegeben werden. POS_LOW und POS_HIGH bezeichnen die Positionen der Eingabefelder eines Selektionskriteriums. Der Zusatz POSITION darf nur zwischen BEGIN OF LINE und END OF LINE verwendet werden.
Beispiele
REPORT demo_sel_screen_beg_of_line_1 .
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(10) text-001.
PARAMETERS: p1(3) TYPE c, p2(5) TYPE c, p3(1) TYPE c.
SELECTION-SCREEN END OF LINE.
Es erscheint folgendes Selektionsbild:
Die Zeile beginnt mit dem Inhalt 'Title' von Textsymbol 001, gefolgt von den Eingabefeldern für die Parameter P1, P2 und P3.
REPORT demo_sel_screen_beg_of_line_2 .
DATA wa_spfli TYPE spfli.
SELECT-OPTIONS airline FOR wa_spfli-carrid.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN POSITION pos_high.
PARAMETERS field(5) TYPE c.
SELECTION-SCREEN END OF LINE.
Es erscheint folgendes Selektionsbild:
Das Eingabefeld für den Parameter FIELD erscheint unter dem zweiten Feld des Selektionskriteriums AIRLINE. Für FIELD wird kein Selektionstext angezeigt.