Pushbuttons in the Application Toolbar Locate the document in its SAP Library structure

In the application toolbar of the standard GUI status of the selection screen, five pushbuttons are predefined with the function codes FC01 to FC05, but are inactive by default. You can activate them during the definition of the selection screen as follows:

SELECTION-SCREEN FUNCTION KEY <i>.

The numbering <i> must be between 1 and 5. The individual function texts must be assigned to the FUNCTXT_0<i> components of structure SSCRFIELDS before the selection screen is called. You must declare this structure as an interface work area using the TABLES statement.

If the user chooses one of these buttons, the runtime environment triggers the AT SELECTION-SCREEN event and the function code FC0<i> is placed into the component UCOMM of the structure SSCRFIELDS.

After the AT SELECTION-SCREEN event has been processed, the system displays the selection screen again. The only way to exit the selection screen and carry on processing the program is to choose Execute (F8). Consequently, the pushbuttons on the application toolbar are more suitable for controlling dynamic modifications of the selection screen than for controlling the program flow.

Example

REPORT demo_sel_screen_function_key.

TABLES sscrfields.

PARAMETERS: p_carrid TYPE s_carr_id,
            p_cityfr TYPE s_from_cit.

SELECTION-SCREEN: FUNCTION KEY 1,
                  FUNCTION KEY 2.

INITIALIZATION.
  sscrfields-functxt_01 = 'LH'.
  sscrfields-functxt_02 = 'UA'.

AT SELECTION-SCREEN.
  CASE sscrfields-ucomm.
      WHEN'FC01'.
      p_carrid = 'LH'.
      p_cityfr = 'Frankfurt'.
    WHEN 'FC02'.
      p_carrid = 'UA'.
      p_cityfr = 'Chicago'.
  ENDCASE.

START-OF-SELECTION.
  WRITE / 'START-OF-SELECTION'.

This defines a standard selection screen with two parameters. In the application toolbar, two pushbuttons are assigned the texts LH and UA and activated.

When the user clicks one of the buttons, the AT SELECTION-SCREEN event is triggered and there the input fields are preassigned correspondingly.

 

 

 

Leaving content frame