Programmierung von Methoden mit Parametern (BOR)

Importparameter der Methode werden mit den Makros SWC_GET_ELEMENT (bei einzeiligen Elementen) und SWC_GET_TABLE (bei mehrzeiligen Elementen) im Programm des Objekttyps aus dem Container CONTAINER gelesen und an den Funktionsbaustein bzw. an die Verarbeitungsparameter ("SET/GET-Parameter") einer Transaktion weitergeben.
Exportparameter werden innerhalb der Methodenimplementierung im Programm des Objekttyps in den Container CONTAINER eingestellt. Dazu werden der Makrobefehl SWC_SET_ELEMENT bei einzeiligem Exportparameter bzw. der Makrobefehl SWC_SET_TABLE bei mehrzeiligem Exportparametern verwendet.

Beispiel

Implementierung der Methode GetInternalNumber (Vergabe neuer interner Nummern).

Die Methode operiert auf einem Objekt des Objekttyps BUS1001 (Material). Dieser Objekttyp hat das Schlüsselfeld Material (Materialnummer). Die Methode hat folgende Parameter:

Parameter	Beschreibung	Typ
`MaterialType`	Materialart	Import
`IndustrySector`	Branche	Import
`RequiredNumbers`	Anzahl der benötigten Materialnummern	Import
Return	Return-Parameter	Export
MaterialNumber	vergebene Materialnummern	Im-/Export

Sie implementieren die Methode, indem Sie die API-Funktion BAPI_MATERIAL_GETINTNUMBER aufrufen.

Syntax Syntax

BEGIN_METHOD GETINTERNALNUMBER CHANGING CONTAINER.
DATA:
       MATERIALTYPE LIKE BAPIMATDOA-MATL_TYPE,
       INDUSTRYSECTOR LIKE BAPIMATDOA-IND_SECTOR,
       REQUIREDNUMBERS LIKE BAPIMATALL-REQ_NUMBERS,
       RETURN LIKE BAPIRETURN1,
       MATERIALNUMBER LIKE BAPIMATINR OCCURS 0.
   SWC_GET_ELEMENT CONTAINER 'MaterialType' MATERIALTYPE.
   SWC_GET_ELEMENT CONTAINER 'IndustrySector' INDUSTRYSECTOR.
   IF SY-SUBRC <> 0.
     MOVE SPACE TO INDUSTRYSECTOR.
   ENDIF.   SWC_GET_ELEMENT CONTAINER 'RequiredNumbers' REQUIREDNUMBERS.
   IF SY-SUBRC <> 0.
     MOVE 1 TO REQUIREDNUMBERS.
   ENDIF.
   CALL FUNCTION 'BAPI_MATERIAL_GETINTNUMBER'
     EXPORTING
       REQUIRED_NUMBERS = REQUIREDNUMBERS
       INDUSTRY_SECTOR = INDUSTRYSECTOR
       MATERIAL_TYPE = MATERIALTYPE
     IMPORTING
       RETURN = RETURN
     TABLES
       MATERIAL_NUMBER = MATERIALNUMBER
     EXCEPTIONS
       OTHERS = 01.
   CASE SY-SUBRC.
     WHEN 0.            " OK
     WHEN OTHERS.       " to be implemented
 ENDCASE.
   SWC_SET_ELEMENT CONTAINER 'Return' RETURN.
   SWC_SET_TABLE CONTAINER 'MaterialNumber' MATERIALNUMBER.
 END_METHOD.

Ende des Codes