Persistenz von Daten durch Server-seitige Cookies

Seitenattribute

In diesem Beispiel geht es um einige interessante Seitenattribute, die persistiert werden sollen. Die Liste der Seitenattribute sieht folgendermaßen aus:

Nicht alle Seitenattribute sollen persistiert werden, sondern nur die Strings, die vom Benutzer hinzugefügt wurden. Sie werden in einer Tabelle auf der Oberfläche ausgegeben. Daher sollen in dieser BSP-Applikation nur LAST_STRING_ADDED und STRINGS persistiert werden.

Eventhandler

In dieser BSP-Applikation sind die folgenden Eventhandler von Interesse:

• OnRequest

  Eventhandler, der immer beim einkommenden Request getriggert wird, um die persistenten Daten wiederherzustellen.

• OnManipulation

  Letzter Eventhandler, bevor die Response gesendet wird. In diesem Eventhandler werden die neuen Werte der Seitenattribute in Form von Server-seitigen Cookies abgelegt.

Im Folgenden werden wir zuerst OnManipulation zeigen, um das Konzept für das Ablegen zu erläutern.

OnManipulation

In diesem Eventhandler werden die spezifischen Seitenattribute bzw. deren Werte in das Server-seitige Cookie geschrieben.

Die beiden Parameter werden auf dem Server aufbewahrt und dann in einem Objekt zusammengefasst. Mit dem ABAP-Sprachelement export werden die Benutzereingaben in die Seitendaten geschrieben.

Die Syntax von export lautet folgendermaßen:

export Objekt1 from F ... Objektn from F to data buffer F.
            

Ein Datencluster wird im Datenpuffer f abgelegt, der vom Typ XSTRING sein muss. Alle Seitenattribute, die hier interessieren, werden in einer Bytefolge variabler Länge ( XSTRING) geschrieben.

Für diese BSP verwenden wir den folgenden Code, um XSTRING zu erhalten:

data: PAGE_DATA type XSTRING.
data: NAME type STRING.
export LAST_STRING_ADDED from LAST_STRING_ADDED
    STRINGS    from STRINGS
    to data buffer PAGE_DATA.
    

            

Als nächstes müssen wir XSTRING als Server-seitiges Cookie persistieren:

NAME = SY-UNAME.
call method CL_BSP_SERVER_SIDE_COOKIE=>SET_SERVER_COOKIE
  exporting
    NAME                  = 'my_page_data'
    APPLICATION_NAME      = RUNTIME->APPLICATION_NAME
    APPLICATION_NAMESPACE = RUNTIME -> APPLICATION_NAMESPACE
    USERNAME              = NAME
    SESSION_ID            = 'same_for_all'
    DATA_NAME             = 'page_data'
    DATA_VALUE            = PAGE_DATA
    EXPIRY_TIME_REL       = 3600.


            

Die Bedeutung der dabei verwendeten Exportparameter ist wie folgt:

OnRequest

In diesem Eventhandler werden die internen Datenstrukturen des Requests wiederhergestellt. Hier werden die Seitenattribute von dem Server-seitigen Cookie wieder zurück persistiert. Dadurch gibt es viele Parallelen zum Eventhandler OnManipulation.

Das Server-seitige Cookie wird über den Aufruf der Methode GET_SERVER_COOKIE der Klasse CL_BSP_SERVER_SIDE_COOKIE geholt. Die Bedeutung der Parameter entspricht im Wesentlichen der Bedeutung der Parameter für den Eventhandler OnManipulation (s.o.), nur dass hier der Wert der Daten ( DATA_VALUE) ein changing-Parameter ist.

data: PAGE_DATA type XSTRING.
data: NAME type STRING.
* Die Benutzerverwaltung kann z.B. den ABAP-Systemnamen verwenden
NAME = SY-UNAME.
* Das Server-seitige Cookie wird geholt
call method CL_BSP_SERVER_SIDE_COOKIE=>GET_SERVER_COOKIE
  exporting
    NAME                  = 'my_page_data'
    APPLICATION_NAME      = RUNTIME->APPLICATION_NAME
    APPLICATION_NAMESPACE = RUNTIME ->APPLICATION_NAMESPACE
    USERNAME              = NAME
    SESSION_ID            = 'same_for_all'
    DATA_NAME             = 'page_data'
  CHANGING
    DATA_VALUE            = PAGE_DATA
  .


            

Solange die Werte der Daten tatsächlich mit Werten belegt und somit nicht leer sind, werden nun die persistierten Seitenattribute vom Server-seitigen Cookie wiederhergestellt. Dies wird über das ABAP-Sprachelement import realisiert.

Die Syntax von import lautet folgendermaßen:

import Objekt1 = F ... Objektn = F from data buffer F.
            

Das Datenobjekt (oder mehrere Datenobjekte) wird aus dem angegebenen Datenpuffer F importiert, der vom Typ XSTRING sein muss. Alle Daten, die über export ... to data buffer (siehe oben) im Datenpuffer F abgelegt wurden und hier aufgelistet werden, werden eingelesen. Das Übereinstimmen der Struktur bei export und import wird geprüft.

In unserem Beispiel lautet der Aufruf für das Wiederherstellen der persistierten Cookies folgendermaßen:

if PAGE_DATA is not initial.
  import LAST_STRING_ADDED = LAST_STRING_ADDED
    STRINGS           = STRINGS
    from data buffer PAGE_DATA.
endif.