GET (SAP Library - ABAP Programming (BC-ABA))

GET

Function

Reads a global variable of the JavaScript context. The global variable may have been created previously either with the SET method or by executing a script of the context. The properties of an object cannot be accessed. The global variable must be a property of the root object.

Importing Parameter

NAME (Type STRING)

Name of the variables to be read.

Returning Parameter

VALUE (Type STRING)

Value of the variables read. _f

Example

Example

report  DEMO_JAVA_SCRIPT_GET.
data GET_VALUE type STRING.
data JS_PROCESSOR type ref to CL_JAVA_SCRIPT.
data SOURCE type STRING.
concatenate
  ' function test_class( )                             '
  ' {this.value = "----> Class property <----"};       '
  ' var object = new test_class( );              '
  ' var field = object.value;            '
  into SOURCE separated by CL_ABAP_CHAR_UTILITIES=>CR_LF.
JS_PROCESSOR = CL_JAVA_SCRIPT=>CREATE( ).
JS_PROCESSOR->COMPILE( SCRIPT_NAME = 'TEST_GET.JS'
                       SCRIPT      = SOURCE ).
if JS_PROCESSOR->LAST_CONDITION_CODE <> 0.
  write: / 'Error in COMPILE',
           JS_PROCESSOR->LAST_ERROR_MESSAGE.
else.
  write / 'JavaScript was compiled'.
endif.
skip.
JS_PROCESSOR->EXECUTE(
              exporting SCRIPT_NAME = 'TEST_GET.JS' ).
if JS_PROCESSOR->LAST_CONDITION_CODE <> 0.
  write: / 'Error in EXECUTE',
           JS_PROCESSOR->LAST_ERROR_MESSAGE.
else.
  write / 'JavaScript was executed'.
endif.
skip.
GET_VALUE = JS_PROCESSOR->GET( NAME = 'object' ).
if JS_PROCESSOR->LAST_CONDITION_CODE <> 0.
  write: / 'Error in GET for object',
           JS_PROCESSOR->LAST_ERROR_MESSAGE.
else.
  write: / 'Result of GET for object:', GET_VALUE.
endif.
skip.
GET_VALUE = JS_PROCESSOR->GET( NAME = 'object.value' ).
if JS_PROCESSOR->LAST_CONDITION_CODE <> 0.
  write: / 'Error in GET for object.value',
           JS_PROCESSOR->LAST_ERROR_MESSAGE.
else.
  write: / 'Result of GET for object.value:', GET_VALUE.
endif.
skip.
GET_VALUE = JS_PROCESSOR->GET( NAME = 'field' ).
if JS_PROCESSOR->LAST_CONDITION_CODE <> 0.
  write: / 'Error in GET for field',
           JS_PROCESSOR->LAST_ERROR_MESSAGE.
else.
  write: / 'Result of GET for field:', GET_VALUE.
endif.

An object called object and a global variable called field are created in JavaScript TEST_GET.JS. GET only allows access to object as an entire object and field. object.value cannot be accessed and results in an error message.