---

SAP NetWeaver AS ABAP Release 752, ©Copyright 2017 SAP AG. Alle Rechte vorbehalten.

ABAP - Schlüsselwortdokumentation →  ABAP - Referenz →  Programmablaufsteuerung →  Bedingte Ausdrücke → 

COND - Konditionaloperator

Syntax

... COND type( [let_exp]
               WHEN log_exp1 THEN [ let_exp] result1
             [ WHEN log_exp2 THEN [ let_exp] result2 ]
             ...
             [ ELSE [ let_exp] resultn ] ) ...

Wirkung

Ein bedingter Ausdruck mit dem Konditionaloperator COND hat ein von logischen Ausdrücken abhängiges Resultat result. Es wird entweder ein Wert des mit type angegebenen Datentyps erzeugt oder eine klassenbasierte Ausnahme ausgelöst. Für type kann angegeben werden:

• Ein nicht-generischer Datentyp dtype.

• Das Zeichen # als Symbol für den Operandentyp.

• Wenn der an einer Operandenposition benötigte Datentyp eindeutig und vollständig erkennbar ist, wird dieser verwendet.

• Wenn der Operandentyp nicht vollständig erkennbar ist, muss außer bei Übergabe des Konstruktorausdrucks an einen Aktualparameter mit generisch typisiertem Formalparameter hinter dem ersten THEN ein Operand mit statisch erkennbarem Typ aufgeführt sein und es wird dieser Typ verwendet. Insbesondere kann dann hinter dem ersten THEN kein THROW aufgeführt sein.

• Wenn der Konstruktorausdruck an einen Aktualparameter mit generisch typisierten Formalparameter übergeben wird, wird der Operandentyp nach speziellen Regeln abgeleitet.

• Andernfalls kann das Zeichen # nicht angegeben werden.

Alle hinter THEN angegebenen Operanden müssen in den durch type bestimmten Datentyp konvertierbar sein. Bei Referenzvariablen muss ein Up Cast möglich sein.

In den Klammern muss mindestens eine Angabe WHEN mit einem beliebigen logischen Ausdruck log_exp angegeben werden. Es können beliebig viele Angaben WHEN mit weiteren logischen Ausdrücken folgen. Abschließend kann ein ELSE angegeben werden. Der Ausdruck wertet die logischen Ausdrücke der Reihe nach aus und wählt die Angabe result hinter THEN des ersten logischen Ausdrucks aus, dessen Ergebnis wahr ist . Das ausgewählte result bestimmt das Resultat des bedingten Ausdrucks. Wenn kein logischer Ausdruck wahr ist, wird die Angabe result hinter ELSE ausgewählt. Wenn kein ELSE angegeben ist, ist das Resultat dann der Initialwert des Datentyps type.

Optional kann vor dem ersten WHEN, hinter jedem THEN und hinter ELSE ein LET-Ausdruck zur Definition lokaler Hilfsfelder aufgeführt werden.

Hinweise

• Die Regeln für die Ableitung des Typs bei Angabe von # für Aktualparameter, die an generisch typisierte Formalparameter übergeben werden, können Syntaxfehler in einem Programm verhindern, das eine Prozedur aufruft, bei der die vollständige Typisierung eines Formalparametertyps nachträglich durch Umstellung auf einen generischen Typ verallgemeinert wurde.

• Bei Formalparametern der generischen Typen c, n und x kann kein passender vollständiger Typ abgeleitet werden.

Beispiel

Verwandlung einer Uhrzeitangabe in das 12-Stunden-Format über einen bedingten Ausdruck an einer Operandenposition.. Der Typ des Resultats wird vom Operand hinter der ersten THEN-Angabe übernommen und ist deshalb string.

CLASS cx_cant_be DEFINITION INHERITING FROM cx_no_check.
ENDCLASS.

cl_demo_output=>display(
  COND #( LET t = '120000' IN
          WHEN sy-timlo < t THEN
            |{ sy-timlo TIME = ISO } AM|
          WHEN sy-timlo > t AND sy-timlo < '240000' THEN
            |{ CONV t( sy-timlo - 12 * 3600 ) TIME = ISO } PM|
          WHEN sy-timlo = t THEN
            |High Noon|
          ELSE
            THROW cx_cant_be( ) ) ).