SELECT - ABAP-Schlüsselwortdokumentation

ABAP - Schlüsselwortdokumentation → ABAP - Referenz → Externe Daten verarbeiten → ABAP-Datenbankzugriffe → Open SQL → Open SQL - Lesende Zugriffe →

SELECT

Kurzreferenz

Syntax

SELECT mainquery_clauses
  [UNION ...]
  INTO|APPENDING target
  [UP TO ...] [OFFSET ...]
  [abap_options].
  ...
[ENDSELECT].

Wirkung

Verwendung der Open-SQL-Anweisung SELECT als eigenständige Anweisung. Diese Anweisung liest Daten aus einer oder mehreren Datenbanktabellen, klassischen Views oder CDS-Entitäten und erzeugt daraus entweder eine mehrzeilige oder eine einzeilige Ergebnismenge und weist diese an geeignete ABAP-Datenobjekte zu.

Die Zusätze mainquery_clauses definieren, welche Daten in welcher Form von der Datenbank gelesen werden. Um die Ergebnismengen mehrerer Queries zu kombinieren, kann das Sprachelement UNION verwendet werden. Dabei gelten spezielle Regeln query_clauses für die Angabe der Klauseln. Abschließend werden folgende Eigenschaften definiert:

ABAP-Zielobjekte

In der INTO-Klausel werden hinter INTO oder APPENDING die Datenobjekte target angegeben, denen die Ergebnismenge zeilenweise oder paketweise zugewiesen wird.

Begrenzung der Ergebnismenge

Die Zusätze UP TO, OFFSET bestimmen die Anzahl der zu lesenden Zeilen.

ABAP-spezifische Zusätze

Optionale Zusätze abap_options legen fest, ob die Tabellenpufferung umgangen wird und definieren die Datenbankverbindung.

In den folgenden Fällen öffnet die Anweisung SELECT eine Schleife, die durch ENDSELECT abgeschlossen werden muss:

Bei der Zuweisung an einen nicht-tabellenartigen Zielbereich, d.h. bei einer SELECT-Anweisung ohne den Zusatz INTO|APPENDING ... TABLE, tritt eine mit ENDSELECT abzuschließende Schleife immer auf, außer wenn:

hinter SELECT der Zusatz SINGLE zum Auslesen genau einer Zeile angegeben ist

die Spalten der Ergebnismenge in der SELECT-Liste statisch angegeben sind, in ihr ausschließlich Aggregatfunktionen auftreten und weder der Zusatz GROUP BY noch UNION angegeben sind.

Bei der Zuweisung an einen tabellenartigen Zielbereich d.h. bei einer SELECT-Anweisung mit dem Zusatz INTO|APPENDING ... TABLE, tritt eine mit ENDSELECT abzuschließende Schleife genau dann auf, wenn der Zusatz PACKAGE SIZE verwendet wird.

Bei jedem Schleifendurchgang weist die SELECT-Anweisung eine Zeile bzw. ein Paket von Zeilen den in target angegebenen Datenobjekten zu. Wenn die letzte Zeile zugewiesen wurde oder die Ergebnismenge leer ist, verzweigt SELECT zu ENDSELECT. Für die Verarbeitung einer SELECT-Schleife wird implizit ein Datenbank-Cursor geöffnet und bei Beendigung der Schleife wieder geschlossen. In einem Programm dürfen Über die Open-SQL-Schnittstelle maximal 17 Datenbank-Cursor gleichzeitig geöffnet sein. Beim Versuch, mehr als 17 Datenbank-Cursor zu öffnen, kommt es zum Laufzeitfehler DBSQL_TOO_MANY_OPEN_CURSOR. Eine SELECT-Schleife kann mit den Anweisungen aus dem Abschnitt Schleifen verlassen beendet werden. Wenn die Ergebnismenge den Datenobjekten komplett in einem Schritt übergeben wird, wird keine Schleife geöffnet und die Anweisung ENDSELECT darf nicht angegeben werden.

Systemfelder

Die Anweisung SELECT setzt die Werte der Systemfelder sy-subrc und sy-dbcnt.

sy-subrc	Bedeutung
0	Die Anweisung SELECT setzt sy-subrc bei jeder Wertübergabe an ein ABAP-Datenobjekt auf 0. Außerdem setzt SELECT sy-subrc vor dem Verlassen einer SELECT-Schleife über ENDSELECT auf 0, wenn in der Schleife mindestens eine Zeile übergeben wurde.
4	Die Anweisung SELECT setzt sy-subrc auf 4, wenn die Ergebnismenge leer ist. D.h. in der Regel, dass keine Daten auf der Datenbank gefunden wurden. Sonderregeln gelten bei der ausschließlichen Verwendung von Aggregatausdrücken als Spaltenangaben in der SELECT-Liste der SELECT-Klausel.
8	Die Anweisung SELECT setzt sy-subrc auf 8, wenn der Zusatz FOR UPDATE in result verwendet wird, ohne dass der Primärschlüssel vollständig hinter WHERE spezifiziert wird.

Die Anweisung SELECT setzt sy-dbcnt nach jeder Wertübergabe an ein ABAP-Datenobjekt auf die Anzahl der bis dahin übergebenen Zeilen. Wenn dabei ein Überlauf eintritt, weil die Anzahl der Zeilen größer als 2.147.483.647 ist, wird sy-dbcnt auf -1 gesetzt. Wenn die Ergebnismenge leer ist, wird sy-dbcnt auf 0 gesetzt. Wie bei sy-subrc gelten Sonderregeln bei der ausschließlichen Verwendung von Aggregatausdrücken als Spaltenangaben in der SELECT-Liste der SELECT-Klausel.

Hinweise

Die in der SELECT-Anweisung formulierte Query wird in der Datenbankschnittstelle für die Programmierschnittstelle des Datenbanksystems umgesetzt und an dieses übergeben. Die Daten werden paketweise von der Datenbank gelesen und vom Datenbankserver zum aktuellen Applikationsserver transportiert. Auf dem Applikationsserver werden die Daten gemäß den Angaben im Zusatz INTO oder APPENDING an die Datenobjekte des ABAP-Programms übergeben.
SELECT-Schleifen sind schachtelbar. Aus Gründen der Performance sollte aber geprüft werden, ob ein Join oder eine Subquery nicht effizienter sind.
Neben den expliziten Open-SQL-Zugriffen über SELECT-Schleifen und mit OPEN CURSOR, öffnet die Open-SQL-Schnittstelle in bestimmten Situationen, wie z.B. beim Laden gepufferter Tabellen, auch implizit Datenbank-Cursor. Um den Laufzeitfehler DBSQL_TOO_MANY_OPEN_CURSOR zu verhindern, sollte deshalb die maximale Zahl geöffneter Datenbank-Cursor nicht durch explizite Zugriffe ausgenutzt werden.
Innerhalb einer SELECT-Schleife dürfen keine Anweisungen ausgeführt werden, die zu einem Datenbank-Commit oder Datenbank-Rollback und dadurch zum Schließen des zugehörigen Datenbank-Cursors führen.
Wenn innerhalb einer SELECT-Schleife ändernde Zugriffe auf in der Schleife ausgelesenen Datenquellen durchgeführt werden, ist das Verhalten datenbankabhängig und undefiniert. Solche Zugriffe sollten deshalb vermieden werden.
Die Anweisung ENDSELECT schließt alle mit der SELECT-Schleife verknüpften Leseströme.
Ob eine SELECT-Anweisung nur auf durch einen Datenbank-Commit freigegebene Daten oder bereits auf noch nicht freigegebene Daten einer anderen Datenbank-LUW zugreift wird durch die aktuelle Isolationsebene festgelegt.
Die mit INTO|APPENDING eingeleitete INTO-Klausel sollte als letzte Klausel der SELECT-Anweisung aufgeführt werden. In diesem Fall müssen die optionalen Zusätze UP TO, OFFSET und abap_options hinter der INTO-Klausel stehen. Aus Kompatiblitätsgründen kann die INTO-Klausel auch noch vor oder hinter der FROM-Klausel stehen. Dann können die Zusätze UP TO, OFFSET undabap_options auch vor oder hinter der FROM-Klausel stehen. Im strikten Modus der Syntaxprüfung ab Release 7.50 muss die INTO-Klausel die letzte Klausel sein.
Die INTO-Klausel als letzte Klausel der SELECT-Anweisung führt zum strikten Modus ab Release 7.40, SP08.
Außerhalb von Klassen ist noch eine obsolete Kurzform möglich, bei der die Angabe des Zielbereichs mit INTO bzw. APPENDING weggelassen werden kann, falls hinter FROM eine einzelne Datenbanktabelle oder klassische View statisch angegeben ist, falls alle Spalten mit * ausgelesen werden und falls mit der Anweisung TABLES ein Tabellenarbeitsbereich data_source für die entsprechende Datenbanktabelle bzw. klassische View deklariert ist. Das System ergänzt die SELECT-Anweisung in diesem Fall implizit um den Zusatz INTO source.

Beispiel

Das Beispiel zeigt zwei SELECT-Anweisungen, die sich nur in der Anordnung ihrer SELECT- und FROM-Klauseln unterscheiden. Das Ergebnis beider Anweisungen, die über einen INNER JOIN auf zwei Datenbanktabellen zugreifen, ist identisch.

DATA cityfrom TYPE spfli-cityfrom VALUE 'NEW YORK'.

SELECT c~carrname, p~connid, p~cityfrom, p~cityto
       FROM scarr AS c
            INNER JOIN spfli AS p
                  ON c~carrid = p~carrid
       WHERE p~cityfrom = @cityfrom
       ORDER BY c~carrname, p~connid, p~cityfrom, p~cityto
       INTO TABLE @DATA(result1)
       UP TO 10 ROWS.

SELECT FROM scarr AS c
            INNER JOIN spfli AS p
                  ON c~carrid = p~carrid
       FIELDS c~carrname, p~connid, p~cityfrom, p~cityto
       WHERE p~cityfrom = @cityfrom
       ORDER BY c~carrname, p~connid, p~cityfrom, p~cityto
       INTO TABLE @DATA(result2)
       UP TO 10 ROWS.

ASSERT result2 = result1.
cl_demo_output=>display( result1 ).

Weiterlesen
SELECT - mainquery_clauses
ENDSELECT
Example

SELECT, dynamische Token-Angabe