SELECT - FROM @itab - ABAP-Schlüsselwortdokumentation

ABAP - Schlüsselwortdokumentation → ABAP - Referenz → Externe Daten verarbeiten → ABAP-Datenbankzugriffe → Open SQL → Open SQL - Lesende Zugriffe → SELECT - clauses → SELECT - FROM → SELECT - data_source →

SELECT - FROM @itab

Kurzreferenz

Syntax

... @itab

Wirkung

Angabe einer internen Tabelle itab, deren Bezeichner das Zeichen @ vorangestellt sein muss, als Datenquelle einer Query. Die SELECT-Anweisung behandelt die interne Tabelle des Applikationsservers wie eine Datenbanktabelle auf der Datenbank. Die ABAP-Typen der Spalten der internen Tabelle werden auf passende eingebaute Datentypen des ABAP Dictionary abgebildet. Wenn eine Spalte mit Bezug auf einen Typ im ABAP Dictionary deklariert ist, wird direkt dieser Typ verwendet.

Es sind zwei Fälle zu unterscheiden:

Die Daten der internen Tabelle werden nicht auf der Datenbank benötigt:

In diesem Fall wird auf dem Applikationsserver auf die Daten der internen Tabelle zugegriffen, die dann wie eine Tabelle im Tabellenpuffer behandelt wird. Dies ist für alle Datenbankplattformen möglich.

Die Daten der internen Tabelle werden auf der Datenbank benötigt:

In diesem Fall müssen die Daten vor der eigentlichen Ausführung der Query an temporäre Tabellen der Datenbank übergeben werden. Diese Möglichkeit wird nicht von allen Datenbanken unterstützt. Wenn statisch erkennbar ist, dass die Daten auf der Datenbank benötigt werden, kommt es zu einer durch das Pragma ##db_feature_mode[itabs_in_from_clause] ausblendbaren Warnung von der Syntaxprüfung. Wenn versucht wird, zur Laufzeit Daten der internen Tabelle an eine Datenbank zu übergeben, die dies nicht unterstützt, kommt es zu einer behandelbaren Ausnahme der Klasse CX_SY_SQL_UNSUPPORTED_FEATURE.

Die Daten der internen Tabelle müssen genau dann nicht an die Datenbank übergeben werden, bzw. die Anweisung kann dann auf dem Applikationsserver ausgeführt werden, wenn die SELECT-Anweisung die gleichen Bedingungen wie für einen Zugriff auf den Tabellenpuffer der Tabellenpufferung erfüllt.

Die ABAP-Typen der Spalten der internen Tabelle werden auf Typen des ABAP Dictionary abgebildet. Wenn eine Spalte mit Bezug auf einen Typ im ABAP Dictionary deklariert ist, wird direkt dieser Typ verwendet.

Es gelten folgende Voraussetzungen:

In einer Open-SQL-Anweisung darf nur eine einzige interne Tabelle angegeben werden.
Der internen Tabelle muss mit AS ein alternativer Tabellenname zugeordnet werden.
Der Zeilentyp der internen Tabelle kann elementar oder strukturiert sein.

Ein elementarer Zeilentyp stellt eine Spalte dar, die in den anderen Klauseln der Query über den Namen table_line oder einen in der SELECT-Liste hinter AS definierten alternativen Spaltennamen angesprochen werden kann.

Ein strukturierter Zeilentyp darf keine Unterstrukturen enthalten

Es sind keine tiefen Zeilentypen erlaubt. Ein elementarer Zeilentyp darf kein String und kein Referenztyp sein und ein strukturierter Zeilentyp darf keine Strings, Referenztypen oder internen Tabellen als Komponenten enthalten mit folgender Ausnahme: Ein elementarer Zeilentyp oder eine Komponente vom Typ string, die durch Bezug auf den eingebauten Dictionary-Typ SSTRING deklariert ist, ist erlaubt.
Falls der Zusatz ORDER BY PRIMARY KEY verwendet wird, muss die interne Tabelle einen primären Tabellenschlüssel haben.
Die Schlüsselfelder eines primären Tabellenschlüssels der internen Tabelle dürfen nur Spalten sein, die zusammenhängend und in der gleichen Reihenfolge am Anfang des Zeilentyps vorkommen.
Wenn die FROM-Klausel statisch angegeben ist, darf die interne Tabelle kein generisch typisierter Formalparameter oder ein generisch typisiertes Feldsymbol sein. Solche können nur in einer dynamischen FROM-Klausel angegeben werden und müssen zur Laufzeit eine passende interne Tabelle repräsentieren.
Die interne Tabelle darf keine Spalten enthalten, die mit Bezug auf die obsoleten Dictionary-Typen DF16_SCL und DF34_SCL deklariert sind.
Die interne Tabelle sollte einen explizit definierten Primärschlüssel haben, der auch leer sein kann. Ein generischer Primärschlüssel oder der Standardschlüssel werden beim Auslesen nicht ausgewertet und es kommt es zu einer Warnung von der Syntaxprüfung.

Die Daten der internen Tabelle werden auch ohne Transport zur Datenbank wie auf der Datenbank behandelt. Insbesondere werden Daten vom Typ string, die durch Bezug auf den eingebauten Dictionary-Typ SSTRING deklariert sind wie Textfelder fester Länge behandelt, bei denen schließende Leerzeichen nicht berücksichtigt werden.

Die interne Tabelle itab wird immer als mandantenunabhängige Tabelle betrachtet. Der Datentyp der ersten Spalte wird unabhängig von ihrem Datentyp nie als Mandantenspalte betrachtet.

Hinweise

Die Daten interner Tabellen sollten nur dann zum Datenbanksystem transportiert werden, wenn sie dort wirklich benötigt werden.
Die Verwendung einer internen Tabelle als Datenquelle von SELECT ist hauptsächlich für Joins mit Datenquellen der Datenbank vorgesehen. In diesem Fall findet ein Transport der Daten der internen Tabelle zur Datenbank statt.
Eine interne Tabelle als Datenquelle von SELECT kann aber auch eine Alternative zu den Anweisungen READ TABLE und LOOP AT sein, um Open-SQL-Syntax auszunutzen, die mit den Anweisungen für interne Tabellen nicht möglich ist. In diesem Fall sollte darauf geachtet werden, dass die Auswertung dann auf dem Applikationsserver erfolgen sollte und keine Daten zur Auswertung zum Datenbanksystem transportiert werden.
Dass die Daten der internen Tabelle bei einem Zugriff auf dem Applikationsserver ohne Datentransport wie eine Tabelle im Tabellenpuffer behandelt wird, bedeutet nicht, dass sie tatsächlich dort abgelegt ist. Dennoch gelten die entsprechenden Einschränkungen für die SELECT-Anweisung.
Mit der Methode USE_FEATURES der Klasse CL_ABAP_DBFEATURES kann in einem ABAP-Programm festgestellt werden, ob das aktuelle Datenbanksystem oder ein Datenbanksystem, auf das über eine Sekundärverbindung zugegriffen wird, den Zugriff auf interne Tabellen unterstützt. Hierzu muss die Konstante ITABS_IN_FROM_CLAUSE dieser Klasse in einer internen Tabelle an die Methode übergeben werden.
Der Zugriff auf eine interne Tabellen als Datenquelle von SELECT soll nicht als Alternative zu den Anweisungen READ TABLE und LOOP AT verstanden werden. Insbesondere sollte man Daten nur dann zur Datenbank transportieren, wenn sie dort wirklich benötigt werden.
Bei internen Tabellen mit elementarem Zeilentyp ist zu beachten, dass der Name der Pseudokomponente table_line nicht der Name einer Struktur in ABAP sein kann. Eine Inline-Deklaration in der INTO-Klausel ist nur möglich, wenn der Spalte table_line der Ergebnismenge mit AS ein alternativer Spaltenname zugeordnet ist.
Bei einem Zugriff auf eine interne Tabelle mit elementarem Zeilentyp in einem allgemeinen Tabellenausdruck hinter WITH darf die SELECT-Liste nicht * sein oder data_source~* enthalten.
Bei Verwendung einer internen Tabelle als Datenquelle wird die Syntaxprüfung im strikten Modus ab Release 7.52 ausgeführt.

Beispiel

Verwendung einer Tabelle von Zufallszahlen als Datenquelle einer SELECT-Anweisung. Die Daten werden wegen der Sortierung zur Datenbank transportiert und die Anweisung kann nur auf Datenbanksystemen ausgeführt werden, welche dies unterstützen.

TYPES:
  BEGIN OF line,
    id     TYPE c LENGTH 1,
    number TYPE i,
  END OF line.

DATA itab TYPE HASHED TABLE OF line
          WITH UNIQUE KEY id.

IF NOT cl_abap_dbfeatures=>use_features(
         EXPORTING
           requested_features =
             VALUE #( ( cl_abap_dbfeatures=>itabs_in_from_clause ) ) ).
  cl_demo_output=>display(
    `System does not support internal tables as data source` ).
  RETURN.
ENDIF.

DATA(rnd) = cl_abap_random_int=>create(
  seed = CONV i( sy-uzeit ) min = 1 max = 100 ).
itab =  VALUE #(
  FOR i = 1 UNTIL i > 25
  ( id = substring( val = sy-abcde off = i len = 1 )
    number = rnd->get_next( ) ) ).

SELECT *
       FROM @itab AS numbers
       WHERE number > 50
       ORDER BY id
       INTO TABLE @DATA(result)
       ##db_feature_mode[itabs_in_from_clause].

cl_demo_output=>display( result ).

Beispiel

Verwendung einer internen Tabelle als Datenquelle eines inneren Joins einer SELECT-Anweisung. Die Daten werden wegen des Joins zur Datenbank transportiert und die Anweisung kann nur auf Datenbanksystemen ausgeführt werden, welche dies unterstützen.

DATA itab TYPE HASHED TABLE OF scarr
          WITH UNIQUE KEY mandt carrid.

IF NOT cl_abap_dbfeatures=>use_features(
         EXPORTING
           requested_features =
             VALUE #( ( cl_abap_dbfeatures=>itabs_in_from_clause ) ) ).
  cl_demo_output=>display(
    `System does not support internal tables as data source` ).
  RETURN.
ENDIF.

itab =  VALUE #( ( carrid = 'LH' carrname = 'L.H.' )
                 ( carrid = 'UA' carrname = 'U.A.' ) ).

SELECT scarr~carrid, scarr~carrname, spfli~connid
       FROM @itab AS scarr
         INNER JOIN spfli ON scarr~carrid = spfli~carrid
       INTO TABLE @DATA(result)
       ##db_feature_mode[itabs_in_from_clause].

cl_demo_output=>display( result ).

Beispiel

Verwendung einer Tabelle mit elementarem Datentyp als Datenquelle zweier SELECT-Anweisungen. Die Daten werden nicht auf der Datenbank benötigt und die SELECT-Anweisungen genügen den Anforderungen für eine Tabellenpufferung. Deshalb können die Anweisungen auf allen Datenbanksystemen ausgeführt werden. In der zweiten SELECT-Anweisung würde es ohne den alternativen Spaltennamen number zu einem Syntaxfehler kommen, da die Inline-Deklaration hinter INTO keine interne Tabelle mit dem Spaltennamen table_line anlegen darf. Wenn die Anweisungen so geändert würden, dass sie Anforderungen für eine Tabellenpufferung nicht erfüllen würden, beispielsweise durch Hinzufügen des Zusatzes DISTINCT, könnten sie nicht auf allen Datenbanksystemen ausgeführt werden.

DATA itab TYPE SORTED TABLE OF i WITH UNIQUE KEY table_line.
itab =  VALUE #( ( 1 )
                 ( 2 )
                 ( 3 ) ).

DATA result1 LIKE itab.
SELECT table_line
       FROM @itab AS numbers
       INTO TABLE @result1.
cl_demo_output=>write( result1 ).

SELECT table_line AS number
       FROM @itab AS numbers
       INTO TABLE @DATA(result2).
cl_demo_output=>display( result2 ).