CALL TRANSACTION - USING - ABAP-Schlüsselwortdokumentation

ABAP - Schlüsselwortdokumentation → ABAP - Referenz → Programmeinheiten aufrufen und verlassen → Programme aufrufen → Transaktionen aufrufen → CALL TRANSACTION →

CALL TRANSACTION - USING

Kurzreferenz

Syntax

CALL TRANSACTION ta WITH|WITHOUT AUTHORITY-CHECK
                    USING bdc_tab { {[MODE mode] [UPDATE upd]}
                                  |  [OPTIONS FROM opt] }
                                     [MESSAGES INTO itab].

Zusätze:

1. ... MODE mode

2. ... UPDATE upd

3. ... OPTIONS FROM opt

4. ... MESSAGES INTO itab

Wirkung

In der Variante mit dem Zusatz USING wird die Transaktion über eine Batch-Input-Tabelle ausgeführt. Der Transaktionsaufruf erfolgt wie unter CALL TRANSACTION beschrieben. Mit den Zusätzen WITH|WITHOUT AUTHORITY-CHECK wird die Berechtigungsprüfung gesteuert.

Für bdc_tab muss eine interne Tabelle des Zeilentyps BDCDATA aus dem ABAP Dictionary angegeben werden. Die Zusätze steuern die Verarbeitung.

Wenn eine Transaktion mit dem Zusatz USING aufgerufen wird, wird das Systemfeld sy-binpt im aufgerufenen Programm auf den Wert "X" gesetzt und es darf während ihrer Verarbeitung keine weitere Transaktion mit diesem Zusatz aufgerufen werden.

Eine Batch-Input-Tabelle bdc_tab ist die programminterne Repräsentation einer Untermenge einer Batch-Input-Mappe und muss entsprechend gefüllt sein. Die Struktur BDCDATA hat die in der folgenden Tabelle gezeigten Komponenten.

Komponente	Bedeutung
PROGRAM	Name des Programms der aufgerufenen Transaktion
DYNPRO	Nummer des zu bearbeitenden Dynpros
DYNBEGIN	Markierung für den Beginn eines neuen Dynpros (mögliche Werte sind "X" und " ")
FNAM	Name eines zu füllenden Dynpro-Feldes oder Batch-Input-Steuerungsanweisungen, z.B. zur Cursor-Positionierung
FVAL	Wert, der dem Dynpro-Feld oder der Steuerungsanweisung übergeben wird

Mit dem Inhalt der internen Tabelle bdc_tab können beliebig viele Bildschirmbilder der aufgerufenen Transaktion mit Eingaben und Benutzeraktionen versorgt werden.

Systemfelder

sy-subrc	Bedeutung
0	Die Verarbeitung der aufgerufenen Transaktion war erfolgreich.
< 1000	Fehler in der aufgerufenen Transaktion. Falls in der Transaktion eine Nachricht gesendet wurde, kann diese mit dem Zusatz MESSAGES empfangen werden.
1001	Fehler in der Verarbeitung.

Hinweise

Der Aufruf einer Transaktion mit einer Batch-Input-Tabelle ist eigentlich nicht gleichbedeutend zu einer Ausführung von Batch-Input-Mappen im Batch-Input. Die Grenzen sind aber fließend, da auch Batch-Input-basierte Frameworks, wie z.B. CATT aber auch die Batch-Input-Verwaltung selbst, teilweise intern die Anweisung CALL TRANSACTION USING ausführen. Dadurch können sie bestimmte Optionen verwenden, die im echten Batch-Input nicht zur Verfügung stehen.
Die Steuerungsmöglichkeiten für eine Batch-Input-Tabelle umfassen die Steuerungsmöglichkeiten von Batch-Input-Mappen im echten Batch-Input und gehen teilweise über diese hinaus.

Beispiel

Aufruf der Transaktion SE24 im ausführbaren Beispielprogramm DEMO_CALL_TRANSACTION_BDC.

DATA: bdcdata_tab TYPE TABLE OF bdcdata,
      opt         TYPE ctu_params.
...
TRY.
    CALL TRANSACTION 'SE24' WITH AUTHORITY-CHECK
                            USING bdcdata_tab OPTIONS FROM opt.
  CATCH cx_sy_authorization_error.
    ...
ENDTRY.

Zusatz 1

... MODE mode

Wirkung

Der Zusatz MODE bestimmt den Abspielmodus der Verarbeitung. Als mode kann ein zeichenartiges Datenobjekt angegeben werden, dessen möglicher Inhalt und dessen Wirkung in der folgenden Tabelle gezeigt werden. Ohne Verwendung einer der Zusätze MODE oder OPTIONS FROM ist die Wirkung dieselbe, als hätte mode den Inhalt "A".

mode	Wirkung
"A"	Verarbeitung mit Anzeige der Bildschirmbilder
"E"	Anzeige der Bildschirmbilder nur dann, wenn ein Fehler auftritt
"N"	Verarbeitung ohne Anzeige der Bildschirmbilder. Wenn in der aufgerufenen Transaktion ein Breakpoint erreicht wird, wird die Verarbeitung mit sy-subrc gleich 1001 abgebrochen und das Feld sy-msgty enthält "S", sy-msgid enthält "00", sy-msgno enthält "344", sy-msgv1 enthält "SAPMSSY3" und sy-msgv2 enthält "0131".
"P"	Verarbeitung ohne Anzeige der Bildschirmbilder. Wenn in der aufgerufenen Transaktion ein Breakpoint erreicht wird, wird in den ABAP Debugger verzweigt.
sonstige	Wie "A".

Zusatz 2

... UPDATE upd

Wirkung

Der Zusatz UPDATE bestimmt den Verbuchungsmodus der Verarbeitung. Für upd kann ein zeichenartiges Datenobjekt angegeben werden, dessen möglicher Inhalt und dessen Wirkung in der folgenden Tabelle gezeigt werden. Ohne Verwendung einer der Zusätze UPDATE oder OPTIONS FROM ist die Wirkung dieselbe, als hätte upd den Inhalt "A".

upd	Wirkung
"A"	Asynchrone Verbuchung. Verbuchungen des aufgerufenen Programms werden so durchgeführt, als sei bei der Anweisung COMMIT WORK der Zusatz AND WAIT nicht angegeben.
"S"	Synchrone Verbuchung. Verbuchungen des aufgerufenen Programms werden so durchgeführt, als sei bei der Anweisung COMMIT WORK der Zusatz AND WAIT angegeben.
"L"	Lokale Verbuchung. Verbuchungen des aufgerufenen Programms werden durchgeführt, als sei in ihm die Anweisung SET UPDATE TASK LOCAL ausgeführt worden.
sonstige	Wie "A".

Hinweis

Diese Wahlmöglichkeit gibt es nicht bei der Ausführung von Batch-Input-Mappen im Batch Input. Dort ist die Verbuchung immer synchron.

Zusatz 3

... OPTIONS FROM opt

Wirkung

Der Zusatz OPTIONS umfasst die Funktionalität der Zusätze MODE und UPDATE und bietet weitere Möglichkeiten zur Steuerung der Verarbeitung der Batch-Input-Tabelle. Die Steuerungsparameter werden in einer Struktur opt vom Typ CTU_PARAMS aus dem ABAP Dictionary angegeben. Die Struktur CTU_PARAMS hat die in der folgenden Tabelle gezeigten Komponenten:

Komponente	Bedeutung
DISMODE	Abspielmodus der Verarbeitung. Werte wie beim Zusatz MODE.
UPMODE	Verbuchungsmodus der Verarbeitung. Werte wie beim Zusatz UPDATE.
CATTMODE	CATT-Modus der Verarbeitung. Während Batch-Input im Wesentlichen der Datenübernahme dient, sind CATT-Abläufe als wieder verwendbare Tests komplexer Transaktionen vorgesehen. Werte: " " (kein CATT-Modus), "N" (CATT ohne Einzelbildsteuerung), "A" (CATT mit Einzelbildsteuerung).
DEFSIZE	Markierung, ob die Bildschirmbilder der aufgerufenen Transaktion in der Standardfenstergröße angezeigt werden. Werte: "X" (Standardgröße), " " (aktuelle Größe).
RACOMMIT	Markierung, ob die Anweisung COMMIT WORK die Verarbeitung beendet oder nicht. Werte: " " (COMMIT WORK beendet die Verarbeitung), "X" ( COMMIT WORK beendet die Verarbeitung nicht).
NOBINPT	Markierung für das Systemfeld sy-binpt. Werte: " " (sy-binpt enthält in der aufgerufenen Transaktion "X"), "X" (sy-binpt enthält in der aufgerufenen Transaktion " ").
NOBIEND	Markierung für das Systemfeld sy-binpt. Werte: " " (sy-binpt enthält nach Ende der Daten aus der Batch-Input-Tabelle in der aufgerufenen Transaktion "X"), "X" (sy-binpt enthält nach Ende der Daten in der aufgerufenen Transaktion " ").

Ohne Verwendung des Zusatzes OPTIONS FROM gelten für DISMODE und UPMODE die durch die Zusätze MODE oder UPDATE gesetzten Werte bzw. die dort angegebenen Standardwerte "A". Die übrigen Komponenten werden auf den Wert " " gesetzt.

Zusatz 4

... MESSAGES INTO itab

Wirkung

Mit diesem Zusatz werden alle während der Verarbeitung gesendeten Nachrichten in einer internen Tabelle itab vom Typ BDCMSGCOLL aus dem ABAP Dictionary gespeichert.

Ausführbares Beispiel

Transaktionsaufruf, BDC-Tabelle

Weiterlesen
CALL TRANSACTION - Batch-Input-Tabelle