RESUME - ABAP-Schlüsselwortdokumentation

ABAP - Schlüsselwortdokumentation → ABAP - Referenz → Programmablaufsteuerung → Ausnahmebehandlung → Klassenbasierte Ausnahmen → TRY →

RESUME

Kurzreferenz

Syntax

RESUME.

Wirkung

Diese Anweisung verlässt eine mit CATCH eingeleitete Behandlung einer wiederaufsetzbaren Ausnahme und setzt die Verarbeitung hinter der Anweisung fort, welche die Ausnahme ausgelöst hat. Diese Anweisung darf nur in einem CATCH-Block einer TRY-Kontrollstruktur aufgeführt werden, bei dem der Zusatz BEFORE UNWIND angegeben ist. Beim Verlassen der Ausnahmebehandlung mit RESUME wir der Kontext der Ausnahme nicht gelöscht und eventuelle CLEANUP-Blöcke werden nicht ausgeführt.

Voraussetzung für das Wiederaufsetzen ist,

dass die Ausnahme mit dem Zusatz RESUMABLE der Anweisung RAISE EXCEPTION oder dem Zusatz THROW in einem bedingten Ausdruck als wiederaufsetzbare Ausnahme ausgelöst wurde und
dass die Ausnahme in der Schnittstelle aller Prozeduren, aus denen sie propagiert wurde, mit dem Zusatz RESUMABLE zu RAISING deklariert wurde, falls es sich nicht um eine von CX_NO_CHECK abgeleitete Ausnahme handelt.

Andernfalls kommt es zu einer Ausnahme der Klasse CX_SY_ILLEGAL_HANDLER. Um zu überprüfen, dass die Voraussetzung erfüllt ist, kann das Instanzattribut IS_RESUMABLE vom Typ abap_bool des aktuellen Ausnahmeobjekts überprüft werden. Der Wert des Attributs wird bei Ausführung der Anweisungen CATCH und CLEANUP mit dem Zusatz INTO und bei der Wiederverwendung eines Ausnahmeobjekts mit der Anweisung RAISE gesetzt.

Hinweise

Wenn die wiederaufsetzbare Ausnahme nicht mit der Variante RAISE RESUMABLE EXCEPTION oref ausgelöst wurde, kann der Behandler Informationen an den Auslöser des Ereignisses schicken, indem er geeigneten Attributen des Ausnahmeobjekts Werte zuweist.
Das Wiederaufsetzen nach einer Ausnahme funktioniert insbesondere auch, wenn die Ausnahme während des Aufrufs einer speziellen Methode wie einem Konstruktor oder einer funktionalen Methode an einer Operandenposition auftritt.
Wenn ein CATCH-Block bei der Behandlung einer wiederaufsetzbaren Ausnahme nicht über RESUME verlassen wird, setzt der weitere Programmverlauf, wie unter Systemverhalten nach einer klassenbasierten Ausnahme beschrieben, nicht wieder im Kontext der auslösenden Anweisung auf. Der Kontext wird spätestens beim Verlassen des CATCH-Blocks gelöscht.

Beispiel

Verwendung der Anweisung RESUME während der Behandlung einer wiederaufsetzbaren Ausnahme cx_demo.

CLASS cx_demo DEFINITION INHERITING FROM cx_static_check.
ENDCLASS.

CLASS cls DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS meth RAISING RESUMABLE(cx_demo).
ENDCLASS.

CLASS cls IMPLEMENTATION.
  METHOD meth.
    ...
    RAISE RESUMABLE EXCEPTION TYPE cx_demo.
    cl_demo_output=>display( 'Resumed ...' ).
    ...
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  TRY.
      cls=>meth( ).
    CATCH BEFORE UNWIND cx_demo.
      RESUME.
  ENDTRY.

Ausnahmen

Behandelbare Ausnahmen

CX_SY_ILLEGAL_HANDLER

Ursache: Ausnahme ist nicht wiederaufsetzbar. Die Kennung des Ausnahmetexts ist NOT_RESUMABLE
Laufzeitfehler: UNCAUGHT_EXCEPTION