LOOP AT itab - GROUP BY - ABAP-Schlüsselwortdokumentation

ABAP - Schlüsselwortdokumentation → ABAP - Referenz → Interne Daten verarbeiten → Interne Tabellen → Verarbeitungsanweisungen für interne Tabellen → LOOP AT itab →

LOOP AT itab - GROUP BY

Kurzreferenz

Syntax

LOOP AT itab result [ cond] GROUP BY group_key
                           [ASCENDING|DESCENDING [AS TEXT]]
                           [WITHOUT MEMBERS]
                           [group_result].
  ...
  [LOOP AT GROUP ...
    ...
  ENDLOOP.]
  ...
ENDLOOP.

Zusätze:

1. ... ASCENDING|DESCENDING [AS TEXT]

2. ... WITHOUT MEMBERS

Wirkung

Diese Variante der Anweisung LOOP AT itab gruppiert die Zeilen der internen Tabelle und führt eine Schleife über die Gruppen aus. Für die Syntax der Zusätze result und cond gilt das Gleiche wie bei einer Schleife über Zeilen mit der Ausnahme, dass der Zusatz TRANSPORTING NO FIELDS nicht angegeben werden kann.

Mit dem Zusatz GROUP BY erfolgt die Verarbeitung der LOOP-Schleife in zwei Phasen:

Gruppierung

In der ersten Phase werden alle durch die Bedingungen cond bestimmten Zeilen wie bei einer Schleife über Zeilen in der dort beschriebenen Verarbeitungsreihenfolge gelesen. Während dieses Vorgangs werden die Anweisungen des Anweisungsblocks zwischen LOOP und ENDLOOP nicht ausgeführt. Für jede gelesene Zeile wird statt dessen im Gruppenschlüsselausdruck group_key ein Gruppenschlüssel konstruiert. Jeder Gruppenschlüssel repräsentiert ein Gruppe. Jede Zeile wird genau einer Gruppe als Mitglied zugeordnet, und zwar der Gruppe aller Zeilen mit demselben Gruppenschlüssel. Wenn der Zusatz WITHOUT MEMBERS nicht verwendet wird, ist diese Zuordnung intern ausgeprägt und kann in der zweiten Phase für den Zugriff auf die Mitglieder einer Gruppe verwendet werden.
Gruppenschleife

In der zweiten Phase wird eine Schleife über alle Gruppen ausgeführt. Für jeden Schleifendurchgang werden die Anweisungen des Anweisungsblocks zwischen LOOP und ENDLOOP ausgeführt. In group_result ist das Ausgabeverhalten für die Gruppenschleife definiert und in der Schleife kann auf die entsprechenden Werte zugegriffen werden. Wenn die Zuordnung der Tabellenzeilen zu ihren Gruppen ausgeprägt ist, kann in der LOOP-Schleife eine Mitgliederschleife LOOP AT GROUP geschachtelt werden, um die Zeilen jeder Gruppe zu lesen.

Die standardmäßige Reihenfolge der Gruppen in der Gruppenschleife wie auch die Reihenfolge der Mitglieder innerhalb einer Gruppe wird durch die Verarbeitungsreihenfolge der LOOP-Schleife in der ersten Phase definiert:

Die standardmäßige Reihenfolge der Gruppen richtet sich nach dem Zeitpunkt der ersten Erzeugung ihres Gruppenschlüssels, was durch eine explizite Sortierung mit den Zusätze ASCENDING oder DESCENDING übersteuert werden kann.
Wenn die Zuordnung der Zeilen zu ihrer Gruppe ausgeprägt ist, richtet sich die Reihenfolge der Zeilen einer Gruppe nach dem Zeitpunkt der Zuordnung zur Gruppe. Dadurch wird insbesondere auch die erste Zeile jeder Gruppe definiert, die bei der Repräsentantenbindung als Repräsentant dient.

Die interne Tabelle itab darf in der Gruppenschleife nicht modifiziert werden, es sei denn es ist der Zusatz WITHOUT MEMBERS angegeben.

Systemfelder

Diese Variante der Anweisung LOOP AT mit dem Zusatz GROUP BY setzt den Wert des Systemfeldes sy-tabix in der Gruppenschleife wie folgt:

Wenn im Ausgabeverhalten Repräsentantenbindung definiert ist, wird sy-tabix auf den Wert gesetzt, der für die Zeile, welche die Gruppe repräsentiert, in der LOOP-Schleife ohne Gruppierung gesetzt würde.
Wenn im Ausgabeverhalten Gruppenschlüsselbindung definiert ist, werden die Gruppen in sy-tabix gezählt. Im ersten Schleifendurchgang wird sy-tabix auf 1 gesetzt und danach in jedem weiteren Schleifendurchgang um 1 erhöht.

Nach dem Verlassen der Schleife über ENDLOOP wird sy-tabix auf den Wert gesetzt, den es vor dem Eintritt in die Schleife hatte. Für sy-subrc gilt das Gleiche wie bei einer Schleife über Zeilen.

Hinweise

Eine Gruppierung, d.h. die Zuordnung von Zeilen zu einer Gruppe besteht nur innerhalb der Gruppenschleife und eine Gruppe kann nur dort hinter LOOP AT GROUP oder FOR ... IN GROUP adressiert werden.
Eine Mitgliederschleife LOOP AT GROUP ist nur in LOOP-Schleifen möglich für welche die interne Tabelle itab direkt als Datenobjekt und nicht als Ergebnis eines Aufrufs oder Ausdrucks angegeben ist. Wenn die Tabelle als Ergebnis eines Aufrufs oder Ausdrucks angegeben ist, sind in der Gruppenschleife nur die Gruppenschlüssel, aber nicht mehr die Gruppen selbst vorhanden.
Eine LOOP-Schleife mit dem Zusatz GROUP BY ist nicht für Mesh-Pfade möglich.
In einer LOOP-Schleife mit dem Zusatz GROUP BY ist keine Gruppenstufenverarbeitung mit der Anweisung AT möglich.
Im Gegensatz zur Gruppenstufenverarbeitung hängt eine Gruppierung mit GROUP BY nicht vom Aufbau der Zeilen und der Verarbeitungsreihenfolge der Schleife ab. Ein Gruppierung mit GROUP BY kann die Gruppenstufenverarbeitung in aller Regel in den Fällen ersetzen, in denen die interne Tabelle vor der Schleife gemäß des Gruppenschlüssels sortiert wird (siehe Beispiel).
Eine Gruppierung mit GROUP BY ersetzt selbst programmierte Gruppenschleifen (siehe Beispiel).
Ein Gruppierung interner Tabellen kann auch mit einem Ausdruck FOR GROUPS ... OF erwirkt werden.

Beispiel

Das Beispiel zeigt die einfachste Art der Gruppierung nach einer Spalte ohne explizite Angabe des Ausgabeverhaltens der Gruppenschleife. In der Schleife besteht Zugriff auf den Arbeitsbereich wa, insbesondere auf die zum Gruppieren verwendete Komponente wa-carrid. Der Arbeitsbereich wa enthält die erste Zeile jeder Gruppe und repräsentiert die Gruppe in der Schleife. Dies wird als Repräsentantenbindung bezeichnet.

SELECT *
       FROM spfli
       INTO TABLE @DATA(spfli_tab).

LOOP AT spfli_tab INTO DATA(wa)
                  GROUP BY wa-carrid.
  cl_demo_output=>write( wa-carrid ).
ENDLOOP.
cl_demo_output=>display( ).

Ausführbare Beispiele

Gruppierung interner Tabellen

Zusatz 1

... ASCENDING|DESCENDING [AS TEXT]

Wirkung

Diese Zusätze sortieren die Gruppen vor dem Ausführen der Gruppenschleife auf- bzw. absteigend nach dem Gruppenschlüssel. Die Sortierung erfolgt genau so wie wenn eine Anweisung SORT für eine interne Tabelle verwendet wird, deren primärer Tabellenschlüssel der Gruppenschlüssel ist und der Zusatz AS TEXT wirkt entsprechend.

Die Gruppenschleife wird in der Reihenfolge der Sortierung ausgeführt. Ohne die Zusätze ASCENDING bzw. DESCENDING liegen die Gruppen in der Reihenfolge vor, in welcher der Wert eines Gruppenschlüssels zum ersten Mal konstruiert wurde.

Hinweis

Die Sortierung von Gruppen kann als Ergänzung zur Anweisung SORT dienen, wenn die dort möglichen Sortierkriterien nicht ausreichen.

Beispiel

Wie obiges Beispiel aber mit absteigender Sortierung nach dem Gruppenschlüssel.

SELECT *
       FROM spfli
       INTO TABLE @DATA(spfli_tab).

LOOP AT spfli_tab INTO DATA(wa)
                  GROUP BY wa-carrid DESCENDING.
  cl_demo_output=>write( wa-carrid ).
ENDLOOP.
cl_demo_output=>display( ).

Ausführbares Beispiel

Gruppierung mit LOOP und Sortierung.

Zusatz 2

... WITHOUT MEMBERS

Wirkung

Der Zusatz WITHOUT MEMBERS schaltet die standardmäßige interne Ausprägung der Zuordnung jeder Tabellenzeile zu ihrer Gruppe ab. Mit dem Zusatz werden zwar Gruppen gebildet, in der Gruppenschleife besteht aber kein Zugriff auf die Zeilen der Gruppen. Wenn der Zusatz WITHOUT MEMBERS angegeben ist,

kann das Ausgabeverhalten nicht für eine Zeile der Gruppe als Repräsentanten definiert werden, es muss eine Gruppenschlüsselbindung definiert werden,
darf die Gruppenschleife keine geschachtelte Mitgliederschleife LOOP AT GROUP enthalten,
darf die interne Tabelle itab in der Gruppenschleife modifiziert werden.

Hinweis

Der Zusatz WITHOUT MEMBERS dient der Verbesserung der Performance in allen Fällen, in denen der Inhalt der Gruppen nicht benötigt wird.

Beispiel

Wie obiges Beispiel aber mit dem Zusatz WITHOUT MEMBERS, wofür mit INTO DATA(key) eine Gruppenschlüsselbindung definiert wird. In der Schleife besteht kein Zugriff auf die Zeilen der Gruppen.

SELECT *
       FROM spfli
       INTO TABLE @DATA(spfli_tab).

LOOP AT spfli_tab INTO DATA(wa)
                  GROUP BY wa-carrid WITHOUT MEMBERS
                  INTO DATA(key).
  cl_demo_output=>write( key ).
ENDLOOP.
cl_demo_output=>display( ).

Weiterlesen
LOOP AT itab - group_key
LOOP AT itab - group_result
LOOP AT GROUP
Beispiele zur Gruppierung mit LOOP