CLEAR - ABAP-Schlüsselwortdokumentation

ABAP - Schlüsselwortdokumentation → ABAP - Referenz → Interne Daten verarbeiten → Zuweisungen → Initialisierungen →

CLEAR

Syntax

CLEAR dobj [ {WITH val [IN {CHARACTER|BYTE} MODE] }
| {WITH NULL} ].

Zusatz:

Wirkung

Ohne die optionalen Zusätze bekommt dobj seinen typgerechtem Initialwert zugewiesen. Bei dobj handelt es sich um eine Ergebnisposition, d.h. es kann eine Variable oder ein schreibbarer Ausdruck angegeben werden.

Elementaren Datenobjekten werden die Initialwerte gemäß der Tabellen der eingebauten ABAP-Typen zugewiesen.
Aufzählungsvariablen werden Initialwerte gemäß des elementaren Basistyps zugewiesen.
Referenzvariablen wird die Null-Referenz zugewiesen.
Strukturen werden komponentenweise auf ihren Initialwert gesetzt.
Sämtliche Zeilen einer internen Tabelle werden gelöscht. Dabei wird der für die Tabelle benötigte Speicherplatz bis auf die initiale Speicheranforderung (siehe INITIAL SIZE) freigegeben. Für das Freigeben des gesamten durch Zeilen belegten Speicherplatzes einer internen Tabelle gibt es die Anweisung FREE.

Die optionalen Zusätze erlauben es, dobj statt mit dem Initialwert mit anderen Werten zu füllen.

Hinweise

Ist dobj eine interne Tabelle mit Kopfzeile, muss zum Löschen der Zeilen dobj[] angegeben werden, andernfalls wird nur die Kopfzeile gelöscht.
Dass die initiale Speicheranforderung bei CLEAR einer internen Tabelle nicht freigegeben wird, kann sich beim Einfügen neuer Zeilen in die interne Tabelle günstig auf die Performance auswirken. Die Anweisung FREE ist nur nötig, wenn tatsächlich möglichst viel Speicher freigegeben werden muss.

Beispiel

Nach der Initialisierung mit CLEAR enthält die interne Tabelle itab keine Zeilen mehr.

DATA itab TYPE STANDARD TABLE OF i WITH EMPTY KEY.

itab = VALUE #( FOR i = 1 UNTIL i > 10 ( i ) ).
ASSERT lines( itab ) = 10.

CLEAR itab.
ASSERT lines( itab ) = 0.

Zusatz

... WITH val [IN {CHARACTER|BYTE} MODE]

Wirkung

Mit dem Zusatz WITH val werden sämtliche Stellen in dobj je nach Angabe von CHARACTER oder BYTE MODE entweder durch das erste Zeichen oder das erste Byte in val ersetzt. Bei val handelt es sich um eine funktionale Operandenposition. Falls dobj vom Typ string oder xstring ist, wird der String in seiner aktuellen Länge bearbeitet.

Ohne die Angabe des MODE-Zusatzes gilt der Zusatz IN CHARACTER MODE. Je nach Zusatz muss das Datenobjekt dobj entweder zeichen- oder byteartig sein. Der Operand val muss je nach Zusatz zeichen- oder byteartig sein und die Länge 1 haben. Ansonsten kommt es zu einem Syntaxfehler oder einer unbehandelbaren Ausnahme.

Hinweis

Mit einem obsoleten Zusatz WITH NULL können außerhalb von Klassen auch noch sämtliche Bytes eines flachen Datenobjekts durch hexadezimal 0 ersetzt werden.

Beispiel

Dem Bytestring hexstring wird über die gesamte aktuelle Länge ein bestimmter Bytewert zugewiesen.

DATA: hexstring TYPE xstring,
hex TYPE x LENGTH 1 VALUE 'FF'.
...
hexstring = '00000000'.
...
CLEAR hexstring WITH hex IN BYTE MODE.

cl_demo_output=>display( hexstring ).

Ausnahmen

Unbehandelbare Ausnahmen

Ursache: Feld val hat bei Variante CLEAR fld WITH val IN BYTE MODE nicht die Länge 1.
Laufzeitfehler: CLEAR_VALUE_BYTEMODE_WRONG_LEN
Ursache: Feld val hat bei Variante CLEAR fld WITH val [IN CHARACTER MODE] nicht die Länge 1.
Laufzeitfehler: CLEAR_VALUE_WRONG_LENGTH