CALL METHOD - statischer Methodenaufruf (obsolet) - ABAP-Schlüsselwortdokumentation

ABAP - Schlüsselwortdokumentation → ABAP - Referenz → Obsolete Sprachelemente → Obsolete Aufrufe →

CALL METHOD - statischer Methodenaufruf (obsolet)

Obsolete Syntax

CALL METHOD { static_meth( )
            | static_meth( a )
            | static_meth( p1 = a1 p2 = a2 ... )
            | static_meth( [parameter_list] ) }.

CALL METHOD static_meth [parameter_list].

Wirkung

Beide Anweisungen sind gleichbedeutend und rufen die Methode auf, die statisch mit dem Bezeichner static_meth angegeben ist.

Die erste Anweisung stellt dem eigenständigen Methodenaufruf ein CALL METHOD voran.
Die zweite Anweisung hat keine runden Klammern für die Versorgung der Parameterschnittstelle. Statt dessen wird keine oder eine explizite Parameterliste aufgeführt.

Bei Verwendung von CALL METHOD für den eigenständigen Methodenaufruf sind keine verketteten Methodenaufrufe möglich und die Operatoren NEW und CAST können nicht für die Angabe der Methode verwendet werden.

Hinweis

Die Verwendung von CALL METHOD für den statischen Methodenaufruf wird nicht mehr empfohlen.

Ein Voranstellen von CALL METHOD vor die empfohlene Syntax ist überflüssig und macht Programme schwerer lesbar.
Die Syntax ohne runde Klammern ist dem Aufruf von Funktionsbausteinen nachempfunden und veraltet. Die Syntax mit runden Klammern vereinheitlicht dagegen eigenständige und funktionale Methodenaufrufe.

Die Verwendung der Anweisung CALL METHOD ist nur noch für dynamische Methodenaufrufe vorgesehen und unterscheidet diese damit klar vom statischen Aufruf.

Beispiel

Die drei Methodenaufrufe des folgenden Quelltextabschnitts sind gleichbedeutend. Die ersten beiden Aufrufe sind die obsoleten Varianten mit CALL METHOD, einmal ohne und einmal mit runden Klammern. Der dritte Aufruf ist die empfohlene Variante ohne CALL METHOD.

CLASS c1 DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS do_something IMPORTING p1 TYPE i
                                         p2 TYPE i
                               EXPORTING p3 TYPE i
                                       p4 TYPE i
                               RETURNING VALUE(r) TYPE i.
ENDCLASS.

CLASS c1 IMPLEMENTATION.
  METHOD do_something .
    ...
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.

  CALL METHOD
    c1=>do_something
    EXPORTING
      p1 = 333
      p2 = 444
    IMPORTING
      p3 = DATA(a1)
      p4 = DATA(a2)
    RECEIVING
      r  = DATA(a3).

  CALL METHOD
    c1=>do_something(
    EXPORTING
      p1 = 333
      p2 = 444
    IMPORTING
      p3 = DATA(b1)
      p4 = DATA(b2)
    RECEIVING
      r  = DATA(b3) ).

  c1=>do_something(
    EXPORTING
      p1 = 333
      p2 = 444
    IMPORTING
      p3 = DATA(c1)
      p4 = DATA(c2)
    RECEIVING
      r  = DATA(c3) ).