SAP NetWeaver AS ABAP Release 750, ©Copyright 2016 SAP AG. Alle Rechte vorbehalten.

ABAP - Schlüsselwortdokumentation →  ABAP - Referenz →  Interne Daten verarbeiten →  Zeichen- und Bytekettenverarbeitung →  Ausdrücke und Funktionen für die Zeichenkettenverarbeitung →  Zeichenkettenfunktionen →  Verarbeitungsfunktionen für zeichenartige Argumente → 

substring, substring_... - Teilfeldfunktionen

Syntaxformen

1. ... substring( val = text [ off = off] [len = len] ) ...

2. ... substring_from( val = text { sub = substring}|{ regex = regex}
                     [ case = case] [ occ = occ] [ len = len]  ) ...

3. ... substring_after( val = text { sub = substring}|{ regex = regex}
                      [case = case] [ occ = occ] [ len = len]  ) ...

4. ... substring_before( val = text { sub = substring}|{ regex = regex}
                       [case = case] [ occ = occ] [ len = len]  ) ...

5. ... substring_to( val = text { sub = substring}|{ regex = regex}
                   [ case = case] [ occ = occ] [ len = len]  ) ...

Wirkung

Die Teilfeldfunktionen bestimmen im Argument text ein Teilfeld und geben dieses zurück.

Das Teilfeld wird wie folgt bestimmt:

• Die Funktion substring gibt den durch den Offset off und die Länge len bestimmten Teilbereich zurück. Es muss mindestens eines der Argumente off oder len angegeben werden.

• Die Funktion substring_from durchsucht text nach dem in occ angegebenen Vorkommen der Übereinstimmung mit der in substring angegebenen Zeichenfolge bzw. mit einem in regex angegebenen regulären Ausdruck und gibt den Teilbereich der Länge len ab dem Offset der Fundstelle zurück. Wenn len nicht angegeben ist, wird die Teilfolge bis zum Ende der Zeichenkette zurückgegeben. Wenn substring leer ist, kommt es zur Ausnahme der Klasse CX_SY_STRG_PAR_VAL. Die Groß- und Kleinschreibung wird bei der Suche standardmäßig beachtet, was aber mit dem Parameter case übersteuert werden kann. Wenn keine Teilfolge gefunden wird, ist der Rückgabewert leer.

• Die Funktion substring_after funktioniert wie substring_from, der Teilbereich wird aber ab dem Offset der Fundstelle zuzüglich der Länge der gefundenen Teilfolge zurückgegeben.

• Die Funktion substring_before funktioniert wie substring_from, es wird aber der Teilbereich der Länge len vor dem Offset der Fundstelle zurückgegeben. Wenn len nicht angegeben ist, wird der Teilbereich ab dem Anfang der Zeichenkette gebildet.

• Die Funktion substring_to funktioniert wie substring_before, es wird aber der Teilbereich vor dem Offset der Fundstelle zuzüglich der Länge der gefundenen Teilfolge zurückgegeben.

Der Rückgabewert ist jeweils vom Typ string.

Hinweis

Die Teilfeldfunktionen sind nicht so performant wie ein direkter Teilfeldzugriff. Dafür erlauben sie aber die Verwendung von Ausdrücken an allen Operandenpositionen.

Beispiel

Die Rückgabewerte folgender Funktionsaufrufe sind: "CD", "CDEFGH"., "EFGH"., "AB". und "ABCD".

DATA result TYPE string.
...
result = substring( val = 'ABCDEFGH' off = 2 len = 2 ).
...
result = substring_from( val = 'ABCDEFGH' sub = 'CD' ).
...
result = substring_after( val = 'ABCDEFGH' sub = 'CD' ).
...
result = substring_before( val = 'ABCDEFGH' sub = 'CD' ).
...
result = substring_to( val = 'ABCDEFGH' sub = 'CD' ).
...

Ausnahmen

Behandelbare Ausnahmen

CX_SY_RANGE_OUT_OF_BOUNDS

• Ursache: Unzulässige Offset- oder Längenangabe in off und len.
  Laufzeitfehler: STRING_OFFSET_TOO_LARGE
  

CX_SY_REGEX_TOO_COMPLEX

• Ursache: Siehe Ausnahmen in regulären Ausdrücken.
  Laufzeitfehler: REGEX_TOO_COMPLEX
  

CX_SY_STRG_PAR_VAL

• Ursache: Unterfolge in sub bzw. regulärer Ausdruck in regex ist leer oder Vorkommen in occ ist 0.
  Laufzeitfehler: STRG_ILLEGAL_PAR