SAP NetWeaver AS ABAP Release 750, ©Copyright 2016 SAP AG. Alle Rechte vorbehalten.

ABAP - Schlüsselwortdokumentation →  ABAP - Referenz →  Interne Daten verarbeiten →  Interne Tabellen →  Verarbeitungsanweisungen für interne Tabellen → 

SORT itab

Kurzreferenz

Syntax

SORT itab [STABLE]
          { { [ASCENDING|DESCENDING]
              [AS TEXT]
              [BY { comp1 [ASCENDING|DESCENDING] [AS TEXT]}
                  { comp2 [ASCENDING|DESCENDING] [AS TEXT]}
                  ... ] }
          | { [BY (otab)] }
          | { [BY expr] } }.

Zusätze:

1. ... STABLE

2. ... ASCENDING|DESCENDING

3. ... AS TEXT

4. ... BY compi [ASCENDING|DESCENDING] [AS TEXT]

5. ... BY (otab)

6. ... BY expr

Wirkung

Diese Anweisung sortiert eine interne Tabelle itab nach dem Inhalt ihrer Komponenten, wobei die Größenvergleiche standardmäßig nach den allgemeinen Vergleichsregeln für einzelne Operanden durchgeführt werden, d.h.:

• Numerische und byteartige Komponenten werden nach ihrem Wert sortiert.
  
  
• Zeichenartige Komponenten werden standardmäßig nach ihrer binären Darstellung (Codepage) sortiert. Eine textuelle Sortierung zeichenartiger Komponenten kann mit dem Zusatz AS TEXT erreicht werden.
  
  
• Der Größenvergleich anderer Komponententypen richtet sich nach den zugehörigen Regeln für Referenzvariablen, Strukturen und interne Tabellen.
  

Falls kein expliziter Sortierschlüssel mit dem Zusatz BY angegeben ist, wird die interne Tabelle itab nach dem primären Tabellenschlüssel sortiert. Die Priorität der Sortierung richtet sich dabei nach der Reihenfolge, in der die Schlüsselfelder bei der Tabellendefinition angegeben sind. Beim Standardschlüssel richtet sich die Priorität der Sortierung nach der Reihenfolge der Schlüsselfelder im Zeilentyp der Tabelle. Wenn der primäre Tabellenschlüssel einer Standardtabelle leer ist, findet keine Sortierung statt. Falls dies statisch erkennbar ist, kommt es zu einer Warnung von der Syntaxprüfung.

Die Sortierung ist standardmäßig instabil, d.h. die relative Reihenfolge von Zeilen, die sich im Sortierschlüssel nicht unterscheiden, bleibt beim Sortieren nicht erhalten. Sie kann sowohl plattformabhängig als auch bei mehrmaligem Sortieren unterschiedlich sein. Eine stabile Sortierung wird mit dem Zusatz STABLE erreicht.

Für itab wird eine Standardtabelle oder Hash-Tabelle erwartet.

• Bei Standardtabellen wir der primäre Tabellenindex entsprechend der Sortierung umgesetzt.
  
  
• Bei Hash-Tabellen wird die interne Reihenfolge geändert. Diese interne Reihenfolge wurde entweder beim Einfügen von Zeilen in die interne Tabelle oder durch eine vorhergehende Sortierung mit der Anweisung SORT festgelegt.
  

Bei beiden Tabellenarten bedingt die Sortierung mit SORT die Reihenfolge, in der eine nachfolgende LOOP-Schleife ohne den Zusatz USING KEY durchlaufen wird.

Sortierte Tabellen können nicht mit SORT sortiert werden und die Anwendung der Anweisung SORT auf sortierte Tabellen ist syntaktisch verboten. Wenn erst zur Laufzeit festgestellt wird, dass eine sortierte Tabelle sortiert werden soll, kommt es zu einer unbehandelbaren Ausnahme, falls sich dadurch die vorliegende Sortierung ändern kann. Letzteres geschieht in folgenden Fällen:

• wenn mit dem Zusatz BY ein anderer Sortierschlüssel als ein Anfangsstück des Tabellenschlüssels angegeben ist,
  
  
• wenn der Zusatz DESCENDING verwendet wird,
  
  
• wenn der Zusatz AS TEXT verwendet wird,
  
  
• wenn in mit dem Zusatz BY ein Attribut eines Objekts als Komponente angegeben ist.
  

Andernfalls wird die Anweisung SORT für sortierte Tabellen ignoriert.

Hinweise

• Es wird empfohlen, wenn möglich einen expliziten Sortierschlüssel hinter BY anzugeben. Die implizite Sortierung nach dem primären Tabellenschlüssel, der bei Standardtabellen selbst wieder implizit als Standardschlüssel definiert sein kann, macht ein Programm schwerer verständlich und sorgt unter Umständen für überraschendes Verhalten.
  
  
• Bei Verwendung des primären Tabellenschlüssels ist zu beachten, dass dies auch der Standardschlüssel sein kann, wodurch unerwartete Effekte auftreten können:
  

• Bei strukturiertem Zeilentyp wird nach allen zeichen- und byteartigen Komponenten sortiert.

• Der Standardschlüssel einer Standardtabelle kann leer sein.
  

• Die Angabe sekundärer Tabellenschlüssel als Sortierschlüssel wird nicht unterstützt.
  
  
• Eine Sortierung mit SORT hat keinen Einfluss auf die Zuordnung von Zeilen zu einem sekundären Tabellenindex.
  
  
• Der Zusatz GROUP BY der Anweisung LOOP AT itab oder eines FOR-Ausdrucks hat auch Zusätze ASCENDING und DESCENDING zur Sortierung von Gruppen. Diese können als Ergänzung zur Anweisung SORT verwendet werden, wenn deren Sortierkriterien nicht ausreichen (siehe Beispiel).
  
  
  

Zusatz 1

... STABLE

Wirkung

Mit STABLE wird eine stabile Sortierung erreicht, d.h., die relative Reihenfolge von Zeilen, die sich im Sortierschlüssel nicht unterscheiden, bleibt beim Sortieren unverändert. Ohne den Zusatz STABLE ist die Reihenfolge nicht stabil:

• Die Reihenfolge kann plattformabhängig sein.
  
  
• Mehrmaliges Sortieren einer Tabelle nach dem gleichen Sortierschlüssel kann bei jedem erneuten Sortieren eine andere Reihenfolge ergeben.
  
  
  

Zusatz 2

... ASCENDING|DESCENDING

Wirkung

Mit dem Zusatz ASCENDING bzw. DESCENDING kann die Sortierrichtung explizit als aufsteigend oder absteigend vorgegeben werden. Falls keiner der Zusätze angegeben ist, ist die aufsteigende Sortierung vorgegeben. Diese Sortierrichtung kann hinter dem Zusatz BY für dort einzeln aufgeführte Komponenten überschrieben werden.

Zusatz 3

... AS TEXT

Wirkung

Der Zusatz AS TEXT gibt vor, dass textartige Komponenten gemäß dem Locale der aktuellen Textumgebung sortiert werden. Falls AS TEXT nicht angegeben ist, werden textartige Komponenten nach der Codierung in der Codepage der aktuellen Textumgebung sortiert. Diese Vorgabe kann hinter dem Zusatz BY für dort einzeln aufgeführte Komponenten überschrieben werden. Die Textumgebung wird beim Öffnen einer internen Sitzung oder über die Anweisung SET LOCALE gesetzt.

Hinweise

• Das Ergebnis einer Sortierung ohne den Zusatz AS TEXT ist abhängig vom Betriebssystem des Applikationsservers. Während die Abfolge der einzelnen Buchstaben, die der aktivierten Sprache zugehören, betriebssystemübergreifend gleich ist, gibt es Unterschiede bezüglich der Zeichen, die nicht zum Alphabet der aktivierten Sprache gehören. Bei der Sortierung ganzer Wörter treten auch bei der ausschließlichen Verwendung von Buchstaben aus dem Alphabet der aktivierten Sprache leichte Differenzen auf. Weiterhin ist die Reihenfolge von Groß- und Kleinbuchstaben betriebssystemabhängig.
  
  
• Die Verwendung des Zusatzes AS TEXT macht die Anweisung CONVERT TEXT im Zusammenhang mit internen Tabellen in der Regel überflüssig.
  
  
• Eine Sortierung ohne den Zusatz AS TEXT ist erheblich schneller als eine Sortierung mit dem Zusatz. Wenn sichergestellt werden kann, dass beide Sortierungen die gleiche Reihenfolge ergeben, ist der Zusatz AS TEXT nicht notwendig. Letzteres ist beispielsweise der Fall, wenn textartige Komponenten nur Zeichen des ASCII-Zeichensatzes und dabei ausschließlich Klein- bzw. Großbuchstaben enthalten.
  
  
  

Beispiel

Sortieren einer Hash-Tabelle text_tab nach Anordnung in der Codepage und gemäß dem Locale der aktuellen Textumgebung. Wenn eine westeuropäische Textumgebung eingestellt ist, ergeben die Sortierungen die Reihenfolgen Miller, Moller, Muller, Möller bzw. Miller, Moller, Möller, Muller (siehe auch das ausführbare Beispiel und das Beispiel zu SET LOCALE).

CLASS demo DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS main.
  PRIVATE SECTION.
    CLASS-DATA text_tab TYPE HASHED TABLE OF string
               WITH UNIQUE KEY table_line.
ENDCLASS.

CLASS demo IMPLEMENTATION.
  METHOD main.
    text_tab = VALUE #(
      ( `Muller` )
      ( `Möller` )
      ( `Moller` )
      ( `Miller` ) ).
    SORT text_tab.
    cl_demo_output=>write_data( text_tab ).
    SORT text_tab AS TEXT.
    cl_demo_output=>display_data( text_tab ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  demo=>main( ).

Zusatz 4

... BY compi [ASCENDING|DESCENDING] [AS TEXT]

Wirkung

Mit dem Zusatz BY compi wird nicht nach dem primären Tabellenschlüssel, sondern nach den dahinter angegebenen Komponenten comp1 comp2 ... sortiert. Die Komponenten werden wie unter Angabe der Komponenten beschrieben angegeben. Falls dabei alle Komponenten über Variablen name angegeben werden und diese nur Leerzeichen enthalten, wird nicht sortiert. Die Priorität der Sortierung richtet sich nach der Reihenfolge in der die Komponenten comp1 comp2 ... von links nach rechts angegeben sind. Die angegebenen Komponenten können auch duplikativ oder überlappend sein. Die angegebenen Komponenten können einen beliebigen Datentyp haben. Für die Auswertung gelten die entsprechenden Vergleichsregeln.

Wenn hinter einer Komponente compi keiner der Zusätze ASCENDING oder DESCENDING angegeben ist, wird die durch Zusatz 2 definierte Sortierrichtung übernommen. Ist einer der Zusätze ASCENDING oder DESCENDING angegeben, überschreibt er die Vorgabe für diese Komponente.

Wenn hinter einer textartigen Komponente compi der Zusatz AS TEXT nicht angegeben ist, wird die durch Zusatz 3 festgelegte Vorgabe übernommen. Wenn hinter einer textartigen Komponente der Zusatz AS TEXT angegeben ist, überschreibt er die Vorgabe für diese Komponente. Bei nicht-textartigen Komponenten kann AS TEXT nicht angegeben werden, außer es wird eine strukturierte Komponente angegeben. In strukturierten Komponenten wirkt AS TEXT nur auf die textartigen Komponenten.

Hinweise

• Wenn der Zeilentyp der internen Tabelle nicht statisch erkennbar ist, können die Komponenten nicht direkt sondern nur dynamisch angegeben werden.
  
  
• Statt einzelnen dynamischen Komponenten kann eine interne Tabelle direkt als otab oder als Ergebnis eines Ausdrucks expr als dynamischer Sortierschlüssel angegeben werden (siehe Zusätze 5 und 6). Die Verwendung einer solchen Tabelle hat den Vorteil, dass eventuelle Ausnahmen behandelbar sind. Weiterhin ist bei Angabe einer Tabelle auch die Anzahl der Komponenten des Sortierschlüssels dynamisch. Bei Verwendung einzelner dynamischer Komponenten muss dagegen für jede eventuell benötigte Komponente ein zeichenartiges Datenobjekt angegeben werden, das nicht berücksichtigt wird, wenn es nur Leerzeichen enthält.
  
  
• In einer obsoleten Variante können außerhalb von Klassen bei Standardtabellen auch Feldsymbole für die Komponenten angegeben werden.
  
  
  

Zusatz 5

... BY (otab)

Wirkung

Mit dem Zusatz BY (otab) wird nicht nach dem primären Tabellenschlüssel, sondern nach den in der internen Tabelle otab dynamisch angegebenen Komponenten sortiert. Jede Zeile der Tabelle otab definiert eine Komponente des Sortierschlüssels. Die Priorität der Sortierung richtet sich nach der Reihenfolge der Zeilen in otab. Wenn die Tabelle otab initial ist, wird nicht sortiert.

Für otab muss eine Standardtabelle vom Tabellentyp ABAP_SORTORDER_TAB aus dem ABAP Dictionary angegeben werden. Der Zeilentyp dieser Tabelle ist die Dictionary-Struktur ABAP_SORTORDER mit folgenden Komponenten:

• NAME vom Typ SSTRING
  für die Angabe einer Komponente des Sortierschlüssels. Die Komponentenangabe wird in der Form "comp_name[+off(len)]" gemacht, wobei "comp_name" die Bezeichnung einer in itab vorhandenen Komponente in Großbuchstaben sein muss, an die eine Offset-/Längenangabe "+off(len)" angehängt werden kann, wobei "off" und "len" passende Zahlenwerte sein müssen.
  
  
• DESCENDING vom Typ CHAR der Länge 1
  für die Angabe der Sortierrichtung für die aktuelle Komponente. Wenn DESCENDING initial ist, wird aufsteigend, wenn DESCENDING den Wert "X" hat, wird absteigend sortiert.
  
  
• ASTEXT vom Typ CHAR der Länge 1
  für die textuelle Sortierung der aktuellen Komponente. Wenn ASTEXT den Wert "X" hat, wird wie mit dem Zusatz AS TEXT sortiert. Dies ist nur für zeichenartige Komponenten möglich. Wenn ASTEXT initial ist, werden zeichenartige Komponenten nach ihrer binären Darstellung sortiert.
  

Bei ungültigem Inhalt in einer Spalte von otab, d.h. NAME enthält den Namen einer nicht vorhandenen Komponente oder eine falsche Offset-/Längenangabe, DESCENDING oder ASTEXT enthalten nicht "X" oder den Initialwert, kommt es zu einer behandelbaren Ausnahme der Klasse CX_SY_DYN_TABLE_ILL_COMP_VAL.

Hinweise

• Der Zusatz BY (otab) kann nicht mit BY compi kombiniert werden.
  
  
• Beim Zusatz BY (otab) kann nicht explizit mit den Zusätzen DESCENDING oder AS TEXT eine absteigende Sortierrichtung bzw. eine textuelle Sortierung für alle Komponenten vorgegeben werden.
  
  
• Wenn hinter dem Zusatz BY ein einziges eingeklammertes Datenobjekt (dobj) angegeben ist, entscheidet sein Datentyp darüber, ob sein Inhalt als Angabe einer einzelnen Komponente oder mehrerer Komponenten dient. In beiden Fällen wird bei initialem dobj keine Sortierung durchgeführt.
  
  
  

Beispiel

Dynamisches Einlesen einer Datenbanktabelle in eine dynamische interne Tabelle und dynamisches Sortieren ihres Inhalts. Der Name der Datenbanktabelle und die Namen der Spalten, nach denen sortiert werden soll, können auf einem Selektionsbild eingegeben werden.

PARAMETERS dbtab TYPE c LENGTH 30.

SELECT-OPTIONS columns FOR dbtab NO INTERVALS.

DATA: otab  TYPE abap_sortorder_tab,
      oline TYPE abap_sortorder,
      dref  TYPE REF TO data.

FIELD-SYMBOLS: <column> LIKE LINE OF columns,
               <itab> TYPE STANDARD TABLE.

TRY.
    CREATE DATA dref TYPE STANDARD TABLE OF (dbtab).
    ASSIGN dref->* TO <itab>.
  CATCH cx_sy_create_data_error.
    MESSAGE 'Wrong data type!' TYPE 'I' DISPLAY LIKE 'E'.
    LEAVE PROGRAM.
ENDTRY.

TRY.
    SELECT *
           FROM (dbtab)
           INTO TABLE @<itab>.
  CATCH cx_sy_dynamic_osql_semantics.
    MESSAGE 'Wrong database table!' TYPE 'I' DISPLAY LIKE 'E'.
    LEAVE PROGRAM.
ENDTRY.

LOOP AT columns ASSIGNING <column>.
  oline-name = <column>-low.
  APPEND oline TO otab.
ENDLOOP.

TRY.
    SORT <itab> BY (otab).
  CATCH cx_sy_dyn_table_ill_comp_val.
    MESSAGE 'Wrong column name!' TYPE 'I' DISPLAY LIKE 'E'.
    LEAVE PROGRAM.
ENDTRY.

Zusatz 6

... BY expr

Wirkung

Mit dem Zusatz BY expr kann ein Ausdruck oder ein funktionaler Methodenaufruf expr angegeben werden, dessen Resultat eine interne Tabelle des gleichen Typs und Inhalts wie beim vorangehenden Zusatz BY (otab) ist. Bei expr handelt es sich um eine allgemeine Ausdrucksposition. Das Verhalten ist wie bei der direkten Angabe einer eingeklammerten internen Tabelle.

Hinweis

Um expr sind keine runden Klammern anzugeben.

Beispiel

Siehe Interne Tabellen dynamisch sortieren.

Ausnahmen

Behandelbare Ausnahmen

CX_SY_DYN_TABLE_ILL_LINE_TYPE

• Ursache: Die Tabelle otab hat einen unzulässigen Zeilentyp.
  Laufzeitfehler: DYN_TABLE_ILL_LINE_TYPE
  

CX_SY_DYN_TABLE_ILL_COMP_VAL

• Ursache: Die Tabelle otab hat in einer Spalte einen unzulässigen Wert.
  Laufzeitfehler: DYN_TABLE_ILL_COMP_VAL
  

Unbehandelbare Ausnahmen

• Ursache: Ein in der Form (name) dynamisch angegebenes Sortierkriterium mit explizitem Zusatz AS TEXT ist nicht textartig.
  Laufzeitfehler: SORT_AS_TEXT_BAD_DYN_TYPE
  
  
• Ursache: Ein als dynamisches Sortierkriterium verwendetes Feldsymbol mit explizitem Zusatz AS TEXT ist nicht textartig.
  Laufzeitfehler: SORT_AS_TEXT_BAD_FS_TYPE
  
  
• Ursache: Ein als dynamisches Sortierkriterium verwendetes Feldsymbol zeigt nicht in die Kopfzeile der zu sortierenden internen Tabelle.
  Laufzeitfehler: SORT_ITAB_FIELD_INVALID
  
  
• Ursache: Für eine Tabelle vom Typ SORTED TABLE stimmt der Sortierschlüssel nicht mit einem Anfangsstück des Tabellenschlüssels überein.
  Laufzeitfehler: SORT_SORT_ILL_KEY_ORDER
  
  
• Ursache: Für Tabellen vom Typ SORTED TABLE sind die Zusätze DESCENDING und AS TEXT nicht erlaubt.
  Laufzeitfehler: SORT_SORT_ILLEGAL
  
  
• Ursache: Sortierungsart weder 'E'(xternal) noch'I'(nternal)
  Laufzeitfehler: SORT_ILLEGAL_MODE
  
  
  

Weiterlesen
Interne Tabellen sortieren
Interne Tabellen alphabetisch sortieren
Interne Tabellen mit Sekundärschlüssel sortieren
Interne Tabellen dynamisch sortieren