ABAP - Schlüsselwortdokumentation →  ABAP - Referenz →  Benutzerdialoge →  Selektionsbilder →  Selektionsbilder erstellen →  SELECTION-SCREEN →  SELECTION-SCREEN - screen_elements → 

SELECTION-SCREEN - PUSHBUTTON

Kurzreferenz

Syntax

SELECTION-SCREEN PUSHBUTTON [/][pos|POS_LOW|POS_HIGH](len) button_text
                            USER-COMMAND fcode
                            [VISIBLE LENGTH vlen]
                            [ MODIF ID modid]
                            [ldb_additions].


Zusätze:

1. ... [/][pos|POS_LOW|POS_HIGH](len)

2. ... USER-COMMAND fcode

3. ... VISIBLE LENGTH vlen

Wirkung

Diese Anweisung legt eine Drucktaste auf dem aktuellen Selektionsbild an. Der Text auf der Drucktaste wird durch den Inhalt von button_text bestimmt. Für button_text gilt das Gleiche wie für text beim Zusatz COMMENT. Der Zusatz MODIF ID ordnet die Drucktaste der Modifikationsgruppe modid zu.

Die Zusätze ldb_additions können nur im Selektions-Include einer logischen Datenbank verwendet werden.

Hinweise

Zusatz 1

... [/][pos|POS_LOW|POS_HIGH](len)

Wirkung

Mit diesem Zusatz muss die Position der Drucktaste angegeben werden. Syntax und Bedeutung sind dieselben wie bei der Erzeugung horizontaler Linien, wobei len hier die Länge der Drucktaste im Dynpro des Selektionsbildes definiert. Wenn eine Drucktaste über die Position 83 oder einen Block mit Rahmen hinausragt, wird sie auf der rechten Seite abgeschnitten.

Zusatz 2

... USER-COMMAND fcode

Wirkung

Mit dem Zusatz USER-COMMAND muss der Drucktaste ein Funktionscode fcode zugeordnet werden. Der Funktionscode fcode muss direkt angegeben werden und darf maximal 20 Zeichen lang sein.

Um mit der Drucktaste arbeiten zu können, muss mit der Anweisung TABLES ein Schnittstellen-Arbeitsbereich der Struktur SSCRFIELDS aus dem ABAP Dictionary deklariert werden.

Wenn der Benutzer die Drucktaste auf dem Selektionsbild auswählt, wird von der Laufzeitumgebung das Ereignis AT SELECTION-SCREEN ausgelöst und der Funktionscode fcode in die Komponente ucomm des Schnittstellen-Arbeitsbereichs sscrfields übertragen.

Hinweise

Zusatz 3

... VISIBLE LENGTH vlen

Wirkung

Der Zusatz VISIBLE LENGTH definiert die sichtbare Länge vlen der Drucktaste und ihres Textes. Syntax und Bedeutung sind dieselben wie bei der Erzeugung von Ausgabefeldern, wobei eine Drucktaste aber nie kürzer als der für sie definierte Text dargestellt wird.

Beispiel

Definition und Aufruf eines eigenständigen Selektionsbildes 500 mit zwei Drucktasten in einem ausführbaren Programm. Für die zweite Drucktaste werden eine Ikone und eine Quick-Info erzeugt.

TABLES sscrfields.

SELECTION-SCREEN:
  BEGIN OF SCREEN 500 AS WINDOW TITLE title,
    PUSHBUTTON 2(10)  but1 USER-COMMAND cli1,
    PUSHBUTTON 12(30) but2 USER-COMMAND cli2
                           VISIBLE LENGTH 10,
  END OF SCREEN 500.

AT SELECTION-SCREEN.
  CASE sscrfields.
    WHEN 'CLI1'.
      ...
    WHEN 'CLI2'.
      ...
  ENDCASE.

START-OF-SELECTION.
  title  = 'Push button'.
  but1 = 'Button 1'.

  CALL FUNCTION 'ICON_CREATE'
    EXPORTING
      name   = icon_information
      text   = 'Button 2'
      info   = 'My quick info'
    IMPORTING
      RESULT = but2
    EXCEPTIONS
      OTHERS = 0.

  CALL SELECTION-SCREEN '0500' STARTING AT 10 10.





Weiterlesen
Selektionsbilder, Drucktasten