Unicode Conversion of View Clusters with Global Parameters
Unicode Conversion of View Clusters with Global Parameters
Global parameters in the view cluster maintenance
All global parameters of a view cluster are available in the view cluster events.
View Cluster Maintenance Events in the "Global Variables" section lists all global parameters. The "Administration and DataTables per Subobject" section explains the field symbols <VCL_HEADER>, <VCL_NAMTAB>, <VCL_DBA_SELLIST>, <VCL_DPL_SELLIST>, <VCL_TOTAL> and <VCL_EXTRACT>.The global parameters are not changed by the Unicode conversion; you only have to edit the access to the data containers <VCL_TOTAL> and <VCL_EXTRACT>, and the work areas VCL_REDUCTION_AREA and VCL_OBJECT_AREA.
Global parameters <VCL_TOTAL> and <VCL_EXTRACT>
These two field symbols access the data of another maintenance dialog in the view cluster, from a view cluster event or a maintenance dialog. They are assigned by the form routine VCL_SET_TABLE_ACCESS_FOR_OBJ.
The internal tables to which the two field symbols point, have no header and the structure of a long character field. You get the same data as the internal tables TOTAL and EXTRACT, in the views maintenance dialog.
Before Unicode
<VCL_TOTAL> and <VCL_EXTRACT> have been used e.g. so:
INCLUDE: lsvcmcod.
...
FORM do_sth.
DATA: BEGIN OF view_wa, "Define working area for <VCL_TOTAL>
INCLUDE STRUCTURE viewname,
INCLUDE STRUCTURE vimflagtab,
END OF view_wa,
eflag TYPE vcl_flag_type.
...
* Assign <VCL_TOTAL> to desired data container.
PERFORM vcl_set_table_access_for_obj USING viewname
CHANGING eflag.
* Get field fieldname in all new datasets
LOOP AT <vcl_total> into view_wa.
CHECK action = īNī.
MOVE view_wa-fieldname to anywhere.
...
ENDLOOP.
ENDFORM.
The unstructured internal table <VCL_TOTAL> of type C is read into a structured work area VIEW_WA. This is no longer possible under Unicode.
Conversion
In a Unicode system you need a character field with the width of the Dictionary structure plus the width of the editing flags ACTION and MARK, as internal table work area:
INCLUDE: lsvcmcod.
...
FORM do_sth.
DATA: align type f, "TOT_WA needs to be aligned for assigning the
tot_wa(1000) TYPE c, "structured field symbol <TOT_WA_STRUC>
eflag TYPE vcl_flag_type.
FIELD-SYMBOLS: <tot_wa_struc> type viewname,
<fldval> TYPE ANY,
<tot_wax> TYPE x,
<tot_action> type vcl_flag_type,
<header_wa> TYPE vimdesc.
* Assign <VCL_TOTAL> to data container and <VCL_HEADER> header data of
* desired view.
PERFORM vcl_set_table_access_for_obj USING viewname
CHANGING eflag.
READ TABLE <vcl_header> INDEX 1 ASSIGNING <header_wa>.
* Assign structure and action-flag.
ASSIGN: tot_wa TO <tot_wa_struc> CASTING,
COMPONENT fieldname OF STRUCTURE <tot_wa_struc>
TO <fldval>,
tot_wa TO <tot_wax> CASTING,
<tot_wax>+<header_wa>-after_tabc TO <tot_action> CASTING.
* Get field fieldname in all new datasets
LOOP AT <vcl_total> into tot_wa.
CHECK <tot_action> = īNī.
MOVE <fldval> TO anywhere.
...
ENDLOOP.
ENDFORM.