SAP NetWeaver AS ABAP Release 7.0, ©Copyright 2009 SAP AG. All rights reserved.

ABAP Keyword Documentation →  ABAP - Reference →  Processing External Data →  Data Clusters → 

DELETE FROM  Syntax Diagram

Short Reference

Syntax

DELETE FROM { {MEMORY ID id}
            | {DATABASE      dbtab(ar) [CLIENT cl] ID id}
            | {SHARED MEMORY dbtab(ar) [CLIENT cl] ID id}
            | {SHARED BUFFER dbtab(ar) [CLIENT cl] ID id} }.

Effect

This statement deletes a data cluster that was stored in the ABAP memory, in a database table, or in a cross-transactional application buffer of the application server by the statement EXPORT. The data cluster is identified by its ID id and, except in the case of the ABAP memory, by the name of a database table dbtab, a range ar, and an optional client cl. The same rules apply to dbtab, ar, cl, and id as apply when accessing the appropriate repository with the IMPORT statement.

System Fields

sy-subrc Meaning
0 The specified data cluster was found and deleted.
4 The specified data cluster was not found.

Note

See also Classes for Data Clusters.

Example

In this example, two fields are written to a data cluster in an application buffer of the application server, extracted, and then deleted. Accessing the same data cluster again sets sy-subrc to 4.

DATA: id    TYPE c LENGTH 4 VALUE 'TEXT',
      text1 TYPE string     VALUE 'Tina',
      text2 TYPE string     VALUE 'Mike'.

EXPORT p1 = text1
       p2 = text2 TO SHARED BUFFER indx(XY) ID id.

IMPORT p1 = text2
       p2 = text1 FROM SHARED BUFFER indx(XY) ID id.

...

DELETE FROM SHARED BUFFER indx(XY) ID id.

IMPORT p1 = text2
       p2 = text1 FROM SHARED BUFFER indx(XY) ID id.

Exceptions

Non-Catchable Exceptions